Selection being automatically undone after command ends?

[okamsn]

I am trying to write a command that deletes the delimiters of a "thing" and then selects the inner contents of the "thing". When I run this command, I see that the delimiters are deleted and the selection is made, but the selection only lasts for a second before being undone.

On Emacs 28.1, without the call to message, I am not able to see that the selection was temporarily made active. The messaging seems to add enough time to see that the selection is being made. This does occur when loading Meow under emacs -Q.

Is this the wrong way to select a region during a command? Is it expected that the selection is undone when the command ends?

(defun my-meow-delete-surrounds (thing)
  "Delete what defines the chosen thing."
  (interactive (list (meow-thing-prompt "Thing: ")))
  (pcase-let* ((`(,bounds-beg . ,bounds-end) (meow--parse-bounds-of-thing-char thing))
               (`(,inner-beg . ,inner-end) (meow--parse-inner-of-thing-char thing))
               (beg-dist (- inner-beg bounds-beg)))
    (delete-region bounds-beg inner-beg)
    (delete-region (- inner-end  beg-dist)
                   (- bounds-end beg-dist))
    (message "Start: %d, end: %d" bounds-beg (- inner-end beg-dist))
    (meow--select-range nil (cons bounds-beg (- inner-end beg-dist)))))

[okamsn]

I've narrowed this down to something that delete-region is doing, though I'm still not sure how it's doing it, since the selection code is called after the regions are deleted.

The selection works fine if delete-region is not called before meow--select-range. delete-region also undoes later selections made by calling set-mark-command.

This happens in Emacs 28 and 29. I will ask about this to see if this is intentional.

[DogLooksGood]

I knew there's one variable affect this behavior, but couldn't remember it...

[okamsn]

Thank you for mentioning that it is variable. That helped me find that the variable is deactivate-mark. The manual says

All the primitives that change the buffer set deactivate-mark, to deactivate the mark when the command is finished. ... To write Lisp code that modifies the buffer without causing deactivation of the mark at the end of the command, bind deactivate-mark to nil around the code that does the modification.

So far, this definition for the command works as expected:

(defun my-meow-delete-surrounds (thing)
  "Delete the delimiters that define the chosen thing, then select what remains."
  (interactive (list (meow-thing-prompt "Thing: ")))
  (pcase-let* ((`(,bounds-beg . ,bounds-end) (meow--parse-bounds-of-thing-char thing))
               (`(,inner-beg . ,inner-end) (meow--parse-inner-of-thing-char thing))
               (beg-dist (- inner-beg bounds-beg)))
    (let ((deactivate-mark nil))
      (delete-region bounds-beg inner-beg)
      (delete-region (- inner-end  beg-dist)
                     (- bounds-end beg-dist)))
    (meow--select-range nil (cons bounds-beg (- inner-end beg-dist)))))

[okamsn]

Answer is to wrap modifications to the buffer with setting deactivate-mark to nil.

Example from other reply:

(defun my-meow-delete-surrounds (thing)
  "Delete the delimiters that define the chosen thing, then select what remains."
  (interactive (list (meow-thing-prompt "Thing: ")))
  (pcase-let* ((`(,bounds-beg . ,bounds-end) (meow--parse-bounds-of-thing-char thing))
               (`(,inner-beg . ,inner-end) (meow--parse-inner-of-thing-char thing))
               (beg-dist (- inner-beg bounds-beg)))
    (let ((deactivate-mark nil))
      (delete-region bounds-beg inner-beg)
      (delete-region (- inner-end  beg-dist)
                     (- bounds-end beg-dist)))
    (meow--select-range nil (cons bounds-beg (- inner-end beg-dist)))))