fopen fails, but why?

[Laserjones]

Hi all, after reading and trying to understand the examples, I tried to create and write to a file and read from it on the Raspberry Pico. The file system appears to be successfully mounted, but the file does not seem to be created. It's probably just a dumb C++ beginner's error, but after hours of pondering, I can't find the problem. Here's my code (reduced to the relevant parts):

#define _LFS_LOGLEVEL_          4
#include "Arduino.h"
#include "LittleFS_Mbed_RP2040.h"

LittleFS_MBED *amigoFS;
byte wave[8][128];

void setup() {
  Serial.begin(9600);
  amigoFS = new LittleFS_MBED();
  if (amigoFS->init()) {
    Serial.println("LittleFS mount succeeded"); 
  }  
  FILE *file;
  byte sample = 0;
  if (file = fopen("/wave1.dat", "w")) {          //   I also tried the file name without the "/" - didn't help.
    Serial.println("File opened for writing");
    for (byte i=0; i <= 127; i++) {
      fwrite(&i, 1, 1, file);
      Serial.print("Writing: ");
      Serial.println(i);
    }  
    fclose(file);
  }
  else {
    Serial.println("Writing failed");
  }
  if (file = fopen("/wave1.dat", "r")) {
    Serial.println("File opened for reading");
    for (byte i=0; i <= 127; i++) {
      fread(&sample, 1, 1, file);
      wave[0][i] = sample;
      Serial.print("Read: ");
      Serial.println(wave[0][i]);
    }
    fclose(file);
  }
  else {
    Serial.println("Reading failed");
  }  
}

The serial output I get is:

[LFS] LittleFS size (KB) = 64
[LFS] LittleFS Mount OK      
LittleFS mount succeeded     
Writing failed
Reading failed

So obviously the command file = fopen("/wave1.dat", "w") did not succeed, but why? As far as I understand, the file should automatically be created if it doesn't exist, right?

Any help is appreciated!

[khoih-prog]

The best way to learn is from the working example, such as LittleFS_Test. If your code fails to run, retest the example and compare what are the differences.

Then, you will see just a small change, by adding the MBED_LITTLEFS_FILE_PREFIX, will fix the issue.

LittleFS_Mbed_RP2040/examples/LittleFS_Test/LittleFS_Test.ino

Lines 303 to 304 in eb1a3a7

	char fileName1[] = MBED_LITTLEFS_FILE_PREFIX "/hello1.txt";
	char fileName2[] = MBED_LITTLEFS_FILE_PREFIX "/hello2.txt";

I've intentionally delayed to respond to see if you can fix the issue yourself, without surrendering so early. Persistence is always the most demanding and best virtue in programming, which requiring problem-solving continuously.

It's probably just a dumb C++ beginner's error, but after hours of pondering, I can't find the problem.

Don't ever think like that and surrender. Your code shows that you're very good, in researching and implementing, just lacking some the experience to solve the problem methodologically and confidence.

I'm sure thru this exercise, you'll be the much better programmer by just removing any doubt that you're noob

Don't be upset, as I can see my similar mistakes in the past and have learnt from them, all my life, and still learning everyday.

---

Code change

  if (file = fopen(MBED_LITTLEFS_FILE_PREFIX "/wave1.dat", "w")) {          //   I also tried the file name without the "/" - didn't help.
...
  if (file = fopen(MBED_LITTLEFS_FILE_PREFIX "/wave1.dat", "r")) {

Terminal

Start LittleFS_Test on RaspberryPi Pico[LFS] LittleFS size (KB) = 64
[LFS] LittleFS Mount OK
LittleFS mount succeeded
File opened for writing
Writing: 0
Writing: 1
Writing: 2
Writing: 3
...
Writing: 124
Writing: 125
Writing: 126
Writing: 127
File opened for reading
Read: 0
Read: 1
Read: 2
Read: 3
...
Read: 125
Read: 126
Read: 127

[Laserjones]

Hi and thank you so much for your quick help (it works perfectly now), as well as your encouragement and the time you took to write this comprehensive answer. I highly appreciate this. By the way, I perceived your reply as really quick and not at all delayed. ;-) It's not uncommon to get no reply at all when posting a problem on the web.

That MBED_LITTLEFS_FILE_PREFIX escaped me because it did not directly show up in your fopen calls, nor in the examples on cplusplus.com that I checked to understand the usage (I had no experience with file access in this language before). With your functions like writeFile, you introduced an additional abstraction layer that made it more challenging for me to implement a direct access without using your functions (my program will only require very little file access, so I wanted to keep this as direct as possible). Of course I had noticed the prefix in your fileName definitions, but my mind must have interpreted it as an optional subdirectory path, so I dismissed it and forgot about it. But you are right, if I had actually compiled your example and done a detailed comparison, I could have found the solution. I'll learn from this I hope.

What's the purpose of that prefix anyway? I assume it's prescribed by the MBED implementation that you built your library on?

Best regards and thanks again,
Joerg

[khoih-prog]

With a little search in the source code, you can see

LittleFS_Mbed_RP2040/src/LittleFS_Mbed_RP2040.h

Lines 102 to 103 in eb1a3a7

	#define MBED_LITTLEFS_FILE_NAME "littlefs"
	#define MBED_LITTLEFS_FILE_PREFIX "/" MBED_LITTLEFS_FILE_NAME

It's actually just a prefix of /littlefs, as required by the the core's LittleFS when you call

LittleFS_Mbed_RP2040/src/LittleFS_Mbed_RP2040.h

Line 108 in eb1a3a7

static mbed::LittleFileSystem fs(MBED_LITTLEFS_FILE_NAME);

For example, if in this library I used

static mbed::LittleFileSystem fs("your_littlefs");

then from that time, you have to use prefix as "/your_littlefs" to your filename, such as "/your_littlefs/your_filename", not "/littlefs/your_filename" anymore.

So, to hide all the not-interesting details, I have to create that new defininition MBED_LITTLEFS_FILE_PREFIX

I suggest next time, if you'd have trouble (nobody won't), try to have a quick look and search the library / core code to understand why they did that way and enrich your knowledge.