como eu arrumo os problemas desse codigo

[Xaavierl]

mano, alguém sabe explicar o que ta de errado e como eu corrijo

[WilCb]

Adaptando o seu código ficaria assim, funcionando tudo

programa
{
	
	funcao inicio()
	{
		real valormesa1, valormesa2, valormesa3

		escreva("Digite o valor da mesa 1: ")
		leia(valormesa1)

		escreva("Digite o valor da mesa 2: ")
		leia(valormesa2)

		escreva("Digite o valor da mesa 3: ")
		leia(valormesa3)

		limpa()
		
		se (valormesa1 <= 30.99) {
			escreva("Mesa 1 nada a pagar!\n")
		} senao se (valormesa1 > 30.99) {
			escreva("Mesa 1 precisa pagar R$", valormesa1 - 30.99, "\n")
		}

		se (valormesa2 <= 30.99) {
			escreva("Mesa 2 nada a pagar!\n")
		} senao se (valormesa2 > 30.99) {
			escreva("Mesa 2 precisa pagar R$", valormesa2 - 30.99, "\n")
		}

		se (valormesa3 <= 30.99) {
			escreva("Mesa 3 nada a pagar!\n")
		} senao se (valormesa3 > 30.99) {
			escreva("Mesa 3 precisa pagar R$", valormesa3 - 30.99, "\n")
		}
	}
}

Porem ele pede para você fazer em vetor(Array). Então o correto seria assim:

programa
{
	inclua biblioteca Matematica --> mat
	
	funcao inicio()
	{
		real mesa[4]
		real desc = 30.99

		escreva("Valor da mesa 1: ")
		leia(mesa[0])

		escreva("Valor da mesa 2: ")
		leia(mesa[1])

		escreva("Valor da mesa 3: ")
		leia(mesa[2])
		
		escreva("Valor da mesa 4: ")
		leia(mesa[3])
		
		se (mesa[0] <= desc) {
			escreva("Mesa 1 nada a pagar!\n")
		} senao se (mesa[0] > desc) {
			real valorTotal = mat.arredondar(mesa[0] - desc, 2)
			escreva("Mesa 1 precisa pagar R$", valorTotal, "\n")
		}

		se (mesa[1] <= desc) {
			escreva("Mesa 2 nada a pagar!\n")
		} senao se (mesa[1] > desc) {
			real valorTotal = mat.arredondar(mesa[1] - desc, 2)
			escreva("Mesa 2 precisa pagar R$", valorTotal, "\n")
		}

		se (mesa[2] <= desc) {
			escreva("Mesa 3 nada a pagar!\n")
		} senao se (mesa[2] > desc) {
			real valorTotal = mat.arredondar(mesa[2] - desc, 2)
			escreva("Mesa 3 precisa pagar R$", valorTotal, "\n")
		}

		se (mesa[3] <= desc) {
			escreva("Mesa 3 nada a pagar!\n")
		} senao se (mesa[3] > desc) {
			real valorTotal = mat.arredondar(mesa[3] - desc, 2)
			escreva("Mesa 4 precisa pagar R$", valorTotal, "\n")
		}
	}
}

Entretanto dá para melhorar um pouco mais o código utilizando o for(para) estrutura de repetição, assim só vai usar o se e o senao se uma vez evitando repetição de código, ficaria assim:

programa
{
	inclua biblioteca Matematica --> mat
	
	funcao inicio()
	{
		// define a quantidade de valores no array(vetor)
		real mesa[5]
		real desc = 30.99

		// para cada mesa você define o valor gasto, iniciando no indice 1 assim ele vai repetir 4 vezes
		para (inteiro i = 1; i < 5;i++) {
			escreva("Valor da mesa ", i, ": ")
			leia(mesa[i])
		}

		limpa()

		// verifica o valor de cada indice do vetor, também iniciando no 1 para que seja repetido 4 vezes
		para (inteiro v = 1; v < 5;v++) {

			// Verifica em quando condição será aplicado
			se (mesa[v] <= desc) {
			escreva("Mesa ", v, " nada a pagar!\n")
			} senao {
				real valorTotal = mat.arredondar(mesa[v] - desc, 2)
				escreva("Mesa ", v," precisa pagar R$", valorTotal, "\n")
			}
		}
	}
}

Outra melhoria que fiz foi colocar o desconto em uma variável, assim ajuda na manutenção de código, pois alterando o valor do desconto na variável você altera em todo o código de uma única vez, utilizei também a biblioteca Matematica onde contém a função arredondar para que fique somente com duas casas decimais depois da virgula, no primeiro parâmetro vc coloca o valor e no segundo quantas casa deseja depois da virgula.

Espero ter ajudado ;-)

Atualizando:

Basta usar apenas o "se" e o "senao" assim já é suficiente para fazer se um é verdadeiro.