How do you repeat a pattern until the end of a file?

[meint52]

I was writing this Pattern and i was wondering if i can make the number of events in the struct DataSection dynamic so that it always stops at the end of the file, and doesn't overshoot (which would cause an error). Im a noob so if im asking a dumb question let me know.
This is what my code looks like so far:

#pragma description "FLP File Structure"

struct Header {
char magic[4] [[color("FFD700"), comment("FLP Header Magic Number 'FLhd'")]];
u32 size [[comment("Size of the header, typically 6")]];
s16 format [[comment("Internal file format")]];
u16 num_channels [[comment("Number of channels in channel rack")]];
u16 ppq [[comment("Pulses per quarter")]];
};

struct Event {
u8 ID [[color("FF0000"), comment("Event ID")]];
if (ID >= 0 && ID <= 63) {
u8 value[1] [[color("0000FF"), comment("1-byte value")]];
} else if (ID >= 64 && ID <= 127) {
u8 value[2] [[color("0000FF"), comment("2-byte value")]];
} else if (ID >= 128 && ID <= 191) {
u8 value[4] [[color("0000FF"),comment("4-byte value")]];
} else if (ID >= 192 && ID <= 255) {
u8 length [[color("00FF00"), comment("Length of the event value in bytes")]];
char value[length] [[color("0000FF")]];
}
};

struct DataSection {
char magic[4] [[color("FFD700"), comment("Data Section Magic Number 'FLdt'")]];
u32 size [[comment("Total combined size of events")]];
Event events[1000] [[comment("Array of events")]];
};

struct FLPFile {
Header header;
DataSection data;
};

FLPFile flpfile @0x00000000;

[paxcut]

Event events[while(!std::mem::eof())] [[comment("Array of events")]];

make sure to also #include "std/mem.pat"
If you prefer you can do a similar construct to use size and read only so many bytes. Left as exercise to reader but will post the answer if requested. (hint: use $ to calculate the number of bytes read so far).

[meint52]

This worked! thanks a lot for your time :)

p.s there is a small typo (double closing bracket)

[paxcut]

My bad. I edited the answer to fix it. Thanks for the feedback!