Setting custom Baud Rate

[luizjanela]

Hi, I'm Luiz Janela.
First of all, thank you so much for such a well coded Library.

I'm working on a new project aiming to create a basic DAW Controller, so I can manage Start, stop, pause and some other features.
I own Arduino Mega 2560 and i have this basic code below, very close to the example present in the repo documentation.

#include <MIDI.h>

// Create and bind the MIDI interface to the default hardware Serial port
MIDI_CREATE_DEFAULT_INSTANCE();

void setup()
{
    MIDI.begin(MIDI_CHANNEL_OMNI);
    pinMode(LED_BUILTIN, OUTPUT);
}

void loop()
{
  digitalWrite(LED_BUILTIN, HIGH);
  MIDI.sendNoteOn(42, 127, 1);    // Send a Note (pitch 42, velo 127 on channel 1)
  delay(1000);                // Wait for a second
  MIDI.sendNoteOff(42, 0, 1);     // Stop the note
  digitalWrite(LED_BUILTIN, LOW);
}

I'm using Hairless Midi and loopMIDI to route everything into the DAW.
The main problem i'm facing is that it looks like no software in this workflow is understanding the note that i´m passing.

On Hairless Midi logs i see the message below:

+358.448 - Warning: got a status byte when we were expecting 1 more data bytes, sending possibly incomplete MIDI message 0xc0

And inside Studio One (my DAW) it comprehends that some not is being sent, but as he doesn't understands, he writes as C-2 (i think that is the lowest note, much like a 0).

I tried a different code, without your framework and got everything working just setting Baud Rate on Hairless Midi the same as my code. After this the DAW started playing the note i was sending with its VST.

Here's is the code:

byte NOTE_ON_CMD = 0x90;
byte NOTE_OFF_CMD = 0x80;

byte note = 36;
byte midiVelocity = 127;

void setup()
{
  Serial.begin(38400);   
}

void loop()
{
  Serial.write(NOTE_ON_CMD);
  Serial.write(note);
  Serial.write(midiVelocity);

  delay(1000);

  Serial.write(NOTE_OFF_CMD);
  Serial.write(note);
  Serial.write(midiVelocity);
}

On Hairless Midi i can see that the note is being recognized too:

+166.931 - Serial In: Ch 1: Note 36 on velocity 127

Is there a way to setup a custom Baud Rate in MIDI.h ?
Perhaps some parameter of MIDI_CREATE_DEFAULT_INSTANCE(); ?

Thank you so much for your library, great work!

[lathoub]

Hi @luizjanela

I believe the MEGA defaults to using Serial1 and not serial as in your 2 example above (see #65).
Try replacing MIDI_CREATE_DEFAULT_INSTANCE(); with MIDI_CREATE_INSTANCE(HardwareSerial, Serial, MIDI);

When going Hairless, please consider:

arduino_midi_library/src/serialMIDI.h

Lines 35 to 37 in d501f4b

	/*! Override the default MIDI baudrate to transmit over USB serial, to
	a decoding program such as Hairless MIDI (set baudrate to 115200)\n
	http://projectgus.github.io/hairless-midiserial/

As for the a custom BaudRate, you need to override the DefaultSerialSettings in SerialMIDI.h

arduino_midi_library/src/serialMIDI.h

Line 33 in 8f8c7cf

struct DefaultSerialSettings

Taken from #215 and modified to fit the above

#include <MIDI.h>

struct CustomBaudRate : public MIDI_NAMESPACE::DefaultSettings {
  static const long BaudRate = 38400;
};

MIDI_CREATE_CUSTOM_INSTANCE(HardwareSerial, Serial, MIDI, CustomBaudRate);

void setup() {
  // put your setup code here, to run once:
}

void loop() {
  // put your main code here, to run repeatedly:
}

Hope this helps

@franky47 : i will add the above to the examples

[lathoub]

@franky47 CustomBaudRate example pushed under PR #262

[lathoub]

Hold on, I should override DefaultSerialSettings, not the DefaultSettings! (tooEarly :-))

[lathoub]

@franky47 Please approve the latest changes in PR #262 (DefaultSerialSettings, not DefaultSettings)

[lathoub]

Also added to the wiki page

[lathoub]

@luizjanela

I was a bit too trigger happy, the above example was overriding DefaultSettings, whilst that should have been DefaultSerialSettings!

That results in:

#include <MIDI.h>

// Override the default MIDI baudrate to
// a decoding program such as Hairless MIDI (set baudrate to 115200)

struct CustomBaudRateSettings : public MIDI_NAMESPACE::DefaultSerialSettings {
  static const long BaudRate = 115200;
};

#if defined(ARDUINO_SAM_DUE) || defined(USBCON) || defined(__MK20DX128__) || defined(__MK20DX256__) || defined(__MKL26Z64__)
    // Leonardo, Due and other USB boards use Serial1 by default.
    MIDI_NAMESPACE::SerialMIDI<HardwareSerial, CustomBaudRateSettings> serialMIDI(Serial1);
    MIDI_NAMESPACE::MidiInterface<MIDI_NAMESPACE::SerialMIDI<HardwareSerial, CustomBaudRateSettings>> MIDI((MIDI_NAMESPACE::SerialMIDI<HardwareSerial, CustomBaudRateSettings>&)serialMIDI);
#else
    MIDI_NAMESPACE::SerialMIDI<HardwareSerial, CustomBaudRateSettings> serialMIDI(Serial);
    MIDI_NAMESPACE::MidiInterface<MIDI_NAMESPACE::SerialMIDI<HardwareSerial, CustomBaudRateSettings>> MIDI((MIDI_NAMESPACE::SerialMIDI<HardwareSerial, CustomBaudRateSettings>&)serialMIDI);
#endif

void setup() {
  pinMode(LED_BUILTIN, OUTPUT);
  MIDI.begin(MIDI_CHANNEL_OMNI);
}

void loop() {
  if (MIDI.read())                    // If we have received a message
  {
    digitalWrite(LED_BUILTIN, HIGH);
    MIDI.sendNoteOn(42, 127, 1);    // Send a Note (pitch 42, velo 127 on channel 1)
    delay(1000);                // Wait for a second
    MIDI.sendNoteOff(42, 0, 1);     // Stop the note
    digitalWrite(LED_BUILTIN, LOW);
  }
}

[luizjanela]

Thanks!
Worked perfectly!