sendPitchBend

[RiNoize]

Hi Franky:
I have a problem with sendPitchBend in my sketch.
In MIDI-OX when I move the potentiometer it only shows hex messages in Data2, since PitchBend is 14 bit and would have to show messages in Data1 and Data2.
I share the sketch so you can see what I'm doing wrong, thanks
GeniusKeyAndProMicro.zip

[franky47]

From what I can see in potenciometros.cpp:78, you convert 7-bit values into 14-bit values by shifting them 7 bits to the left. This means that the other 7 bits (LSB) will be zero, the only data is in the MSB, which is sent in Data2 in a PitchBend message.

[RiNoize]

Ok Franky, I understand what you are saying, but I don't think I have the ability to fix this yet, I inserted some code that would work for sendPitchBend in another sketch, and I don't know if it would work in this sketch with banks.
And what do you think of it?
How would it have to be to insert pitchbend in the banks?
Could you correct the sketch? or would I have to do it differently?

[franky47]

I'm not exactly sure what happens in the code (it's hard to follow through and I don't speak Spanish), but the gist of it is that if you want more precision in your PitchBend, it has to come from a higher-precision source (sensor).

The ADC on Arduino has 10 bits of resolution, so that's the theoretical maximum you'll get.

I see what looks like some filtering code in potenciometros.cpp that reduces from 10 bits to 7 bits (which then are used as MSB for the 14 bits passed to sendPitchBend). Removing that filter would add a little precision, at the expense of added noise. You'll have to see what works best for you between stepping (low resolution) and instability (too much precision/noise).

[RiNoize]

Thanks for your answer but it seems to me that I have something wrong in my original sketch of using Pitchbend with a potentiometer. How would you do the simple sketch of using a potentiometer connected to an analog pin to control PitchBend?

[franky47]

Here's what a sketch that continuously sends PitchBend messages based on a potentiometer reading would look like:

#include <MIDI.h>

// User settings
static const int pitchBendPotPin            = A0;
static const int analogMaxResolutionBits    = 10; // max 10, reduce to filter out noise
static const byte midiOutputChannel         = 1;

// Computed settings
static const int analogFilterShift  = 10 - analogMaxResolutionBits;
static const int analogMaxValue     = (1 << analogMaxResolutionBits) - 1;

MIDI_CREATE_DEFAULT_INSTANCE();

void setup()
{
  MIDI.begin();
}

void loop()
{
  // Read the potentiometer value (10 bits of resolution)
  const int rawPitchBendPotValue = analogRead(pitchBendPotPin);

  // Reduce precision to filter out noise (may introduce stepping)
  const int filteredPitchBend = rawPitchBendPotValue >> analogFilterShift;
  
  // Convert the filtered value to pitch bend range
  const int pitchBendValue = map(
    filteredPitchBend, 
    0, analogMaxValue, 
    MIDI_PITCHBEND_MIN, MIDI_PITCHBEND_MAX
  );

  MIDI.sendPitchBend(pitchBendValue, midiOutputChannel);

  delay(10);
}

[franky47]

Note: a better way to remove noise would be to actually smooth out values, using a moving average buffer. This would filter out noise without losing too much precision, at the expense of a little latency in reactivity (but which should be imperceptible if the loop runs fast enough and using a small filter buffer size).

[RiNoize]

Thanks Franky, sorry I didn't answer you before, I was thinking of implementing it in my sketch and I was commenting there, but I didn't have time to do it, what I did is test your code, and yes, it works. Thanks again for your library and for answering quickly ...