VL53L4CD does not work with ESP

[Hainer1]

Hi,

I am using the Arduino IDE with the VL53L4CD library 1.0.3.
I used the example code with a small modification due to the homemade PCB.

/* Includes ------------------------------------------------------------------*/
//#include <Arduino.h>
#include <Wire.h>
#include <vl53l4cd_class.h>
#include <string.h>
#include <stdlib.h>
#include <stdio.h>
#include <stdint.h>
#include <assert.h>
#include <stdlib.h>

#define DEV_I2C Wire
//#define SerialPort Serial

#ifndef LED_BUILTIN
#define LED_BUILTIN 13
#endif
#define LedPin LED_BUILTIN

// Components.
VL53L4CD sensor_vl53l4cd_sat(&DEV_I2C, A1);

/* Setup ---------------------------------------------------------------------*/

void setup() {
  unsigned char state;
  // Led.
  //pinMode(LedPin, OUTPUT);


  // Initialize serial for output.
  Serial.begin(115200);
  //Serial.setTimeout(10);
  delay(2000);
  Serial.println("Starting...");

  // Initialize I2C bus.
  // DEV_I2C.begin();
  DEV_I2C.begin(6, 7, 400000);
  

  // Configure VL53L4CD satellite component.
  sensor_vl53l4cd_sat.begin();

  // Switch off VL53L4CD satellite component.
  sensor_vl53l4cd_sat.VL53L4CD_Off();

  //Initialize VL53L4CD satellite component.
  state = sensor_vl53l4cd_sat.InitSensor();
  Serial.print("State: "); Serial.println(state);
  // Program the highest possible TimingBudget, without enabling the
  // low power mode. This should give the best accuracy
  sensor_vl53l4cd_sat.VL53L4CD_SetRangeTiming(200, 0);

  // Start Measurements
  sensor_vl53l4cd_sat.VL53L4CD_StartRanging();
}

void loop() {
  uint8_t NewDataReady = 0;
  VL53L4CD_Result_t results;
  uint8_t status;
  char report[64];

  do {
    status = sensor_vl53l4cd_sat.VL53L4CD_CheckForDataReady(&NewDataReady);
  } while (!NewDataReady);

  //Led on
  //digitalWrite(LedPin, HIGH);

  if ((!status) && (NewDataReady != 0)) {
    // (Mandatory) Clear HW interrupt to restart measurements
    sensor_vl53l4cd_sat.VL53L4CD_ClearInterrupt();

    // Read measured distance. RangeStatus = 0 means valid data
    sensor_vl53l4cd_sat.VL53L4CD_GetResult(&results);
    snprintf(report, sizeof(report), "Status = %3u, Distance = %5u mm, Signal = %6u kcps/spad\r\n",
             results.range_status,
             results.distance_mm,
             results.signal_per_spad_kcps);
    Serial.print(report);
  }

  //Led off
  //digitalWrite(LedPin, LOW);
}

I can see the I2C communication with onsciloskop and it looks realistic.
I have let InitSensor show me the status here, I always get the value 255.

Otherwise I have successfully run the code from the VL53L4CX and also got realistic values. So I assume there is no HW error.

Now I want to use the corresponding VL53L4CD code on my proprietary HW with the ESP32.
I suspect that the pin assignment is wrong. How can I change the pins for Xshut, Interrupt and GPIO?
What am I doing wrong or how can I solve the above problems with the correct pin assignment.
Thank you very much!

[fpistm]

@cparata
do you have some input for @Hainer1, please?

[cparata]

Hello @Hainer1 ,
the Xshut pin is the second parameter that you can pass in the constructor:

VL53L4CD sensor_vl53l4cd_sat(&DEV_I2C, A1);

So, please try to update it according your hardware setup replacing A1 with your actual pin. Regarding the interrupt pin, it can be configured in the application code but it is not mandatory if you use the library in polling mode.
Let me know if you are able to fix your issue.
Best Regards,
Carlo

[Hainer1]

Thanks for reply.
I have changed the line
VL53L4CD sensor_vl53l4cd_sat(&DEV_I2C, A1);
to
VL53L4CD sensor_vl53l4cd_sat(&DEV_I2C, 19);

Which in my case is the Xshut connection to the ESP32. But it still does not work.

in addition I tried to read out the sate, the result is 255.
//Initialize VL53L4CD satellite component. state = sensor_vl53l4cd_sat.InitSensor(); Serial.print("State: "); Serial.println(state);

I'm currently using the software VL53L4CX in parallel for commissioning tests, it works, I haven't had any problems so far, but I don't know yet if the driver will continue to work if I go into detail.
Regards Hainer

[cparata]

Hello @Hainer1 ,
I suppose that you have the Pull-Up resistors on SCL and SDA pins on your PCB, correct?.
Best Regards,
Carlo

[Hainer1]

Hi Carlo,
yes that is correct, the pull_ups are implemented. I have a 2nd device on the I2C bus, it also works fine. But I think there is something wrong with this wire configuration (I2C). On the VL53L4CX git page it says that there is an adaptation implemented for ESP32, maybe this is missing in the VL53L4CD library.
Regards Hainer

[cparata]

Hello @Hainer1 ,
this is really strange. Could you try to run an I2C scanner, just to see if the ToF device is able to answer on the bus. You can try this sketch:

// --------------------------------------
// i2c_scanner
//
// Modified from https://playground.arduino.cc/Main/I2cScanner/
// --------------------------------------

#include <Wire.h>

// Set I2C bus to use: Wire, Wire1, etc.
#define WIRE Wire

void setup() {
  // Set Xshut high to enable ToF sensor
  pinMode(19, OUTPUT);
  digitaWrite(19, HIGH);

  // Configure I2C bus according ESP32 I2C pins
  WIRE.begin(6, 7, 400000);

  Serial.begin(9600);
  while (!Serial)
     delay(10);
  Serial.println("\nI2C Scanner");
}


void loop() {
  byte error, address;
  int nDevices;

  Serial.println("Scanning...");

  nDevices = 0;
  for(address = 1; address < 127; address++ ) 
  {
    // The i2c_scanner uses the return value of
    // the Write.endTransmisstion to see if
    // a device did acknowledge to the address.
    WIRE.beginTransmission(address);
    error = WIRE.endTransmission();

    if (error == 0)
    {
      Serial.print("I2C device found at address 0x");
      if (address<16) 
        Serial.print("0");
      Serial.print(address,HEX);
      Serial.println("  !");

      nDevices++;
    }
    else if (error==4) 
    {
      Serial.print("Unknown error at address 0x");
      if (address<16) 
        Serial.print("0");
      Serial.println(address,HEX);
    }    
  }
  if (nDevices == 0)
    Serial.println("No I2C devices found\n");
  else
    Serial.println("done\n");

  delay(5000);           // wait 5 seconds for next scan
}

Let me know if you can get any response from the ToF sensor.
Best Regards,
Carlo

[Hainer1]

Hi Carlo,
Yes, I am getting a response. The two devices on the bus return the 0x51 and the 0x29. No change when I remove the 0x51 device, then I only have the 0x29 as ToF. Same behavior with code from VL53L4CX.
Best regards Hainer

[cparata]

Hello @Hainer1 ,
ok thanks so it means that the I2C bus is fine. Can you describe how did you connect all the pins of the VL53L4CD component? What is the value of AVDD and IOVDD in your hardware setup?
Best Regards,
Carlo

[Hainer1]

Hi Carlo,

sorry for the delay, here is the circuit.

What is the difference between the VL53L4CD and the VL53L4CX code? For me the current hardware is well implemented, so the VL53L4CX code runs well, in the next few days I will get deeper into the firmware of my project. Then I expect to have problems with the details of the VL53L4CX vs. VL53L4CD code...
Regards Hainer

[cparata]

Hello @Hainer1 ,
everything seems fine to me. It's really strange. Could you just put some serial prints in the Init function of the library, to understand exactly where you get the error? Then, I will talk with some ToF experts to understand where the issue could be.
Best Regards,
Carlo

[Hainer1]

Yes, of course, please let me know what kind of prints you would like to see an on which position of your code.

[cparata]

Hello @Hainer1 ,
basically, in all calls inside the "InitSensor" and the "VL53L4CD_SensorInit"APIs in order to understand where you get the "VL53L4CD_ERROR_TIMEOUT" error (equal to 255).
Best Regards,
Carlo