-
Notifications
You must be signed in to change notification settings - Fork 18
/
check_netscaler.pl
executable file
·1449 lines (1209 loc) · 50.8 KB
/
check_netscaler.pl
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
#!/usr/bin/env perl
##############################################################################
# check_netscaler.pl
# Nagios Plugin for Citrix NetScaler
# Simon Lauger <simon@lauger.name>
#
# https://github.com/slauger/check_netscaler
#
# Version: v1.6.2
#
# Copyright 2015-2020 Simon Lauger
#
# Contributor:
# bb-ricardo (github.com/bb-ricardo)
#
# Licensed under the Apache License, Version 2.0 (the "License");
# you may not use this file except in compliance with the License.
# You may obtain a copy of the License at
#
# http://www.apache.org/licenses/LICENSE-2.0
#
# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an "AS IS" BASIS,
# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
# See the License for the specific language governing permissions and
# limitations under the License.
##############################################################################
use strict;
use warnings;
use LWP;
use JSON;
use URI::Escape;
use MIME::Base64;
use Data::Dumper;
use Monitoring::Plugin;
use Time::Piece;
my $plugin = Monitoring::Plugin->new(
plugin => 'check_netscaler',
shortname => 'NetScaler',
version => 'v1.6.2',
url => 'https://github.com/slauger/check_netscaler',
blurb => 'Nagios Plugin for Citrix NetScaler Appliance (VPX/MPX/SDX/CPX)',
usage => 'Usage: %s
-H|--hostname=<hostname> -C|--command=<command>
[ -o|--objecttype=<objecttype> ] [ -n|--objectname=<objectname> ]
[ -u|--username=<username> ] [ -p|--password=<password> ]
[ -s|--ssl ] [ -a|--api=<version> ] [ -P|--port=<port> ]
[ -e|--endpoint=<endpoint> ] [ -w|--warning=<warning> ] [ -c|--critical=<critical> ]
[ -v|--verbose ] [ -t|--timeout=<timeout> ] [ -x|--urlopts=<urlopts> ]',
license => 'http://www.apache.org/licenses/LICENSE-2.0',
extra => '
This is a Nagios monitoring plugin for the Citrix NetScaler. The plugin works with
the Citrix NetScaler NITRO API. The goal of this plugin is to have a single plugin
for every important metric on the Citrix NetSaler.
This plugin works for NetScaler VPX, MPX, SDX and CPX appliances.
See https://github.com/slauger/check_netscaler for details.'
);
# default host
my $host;
if ( defined $ENV{NETSCALER_HOST} ) {
$host = $ENV{NETSCALER_HOST};
}
# default username
my $username;
if ( defined $ENV{NETSCALER_USERNAME} ) {
$username = $ENV{NETSCALER_USERNAME};
} else {
$username = 'nsroot';
}
# default password
my $password;
if ( defined $ENV{NETSCALER_PASSWORD} ) {
$password = $ENV{NETSCALER_PASSWORD};
} else {
$password = 'nsroot';
}
my @args = (
{
spec => 'hostname|H=s',
usage => '-H, --hostname=STRING',
desc => 'Hostname of the NetScaler appliance to connect to',
default => $host,
required => 1,
},
{
spec => 'username|u=s',
usage => '-u, --username=STRING',
desc => 'Username to log into box as (default: nsroot)',
default => $username,
required => 1,
},
{
spec => 'password|p=s',
usage => '-p, --password=STRING',
desc => 'Password for login username (default: nsroot)',
default => $password,
required => 1,
},
{
spec => 'ssl|s!',
usage => '-s, --ssl',
desc => 'Establish connection to NetScaler using SSL',
default => 0,
required => 0,
},
{
spec => 'port|P=i',
usage => '-P, --port=INTEGER',
desc => 'Establish connection to a alternate TCP Port',
default => 0,
required => 0,
},
{
spec => 'command|C=s',
usage => '-C, --command=STRING',
desc => 'Check to be executed on the appliance',
required => 1,
},
{
spec => 'objecttype|o=s',
usage => '-o, --objecttype=STRING',
desc => 'Objecttype (target) to for the check command',
required => 0,
},
{
spec => 'objectname|n=s',
usage => '-n, --objectname=STRING',
desc => 'Filter request to a specific objectname',
required => 0,
},
{
spec => 'endpoint|e=s',
usage => '-e, --endpoint=STRING',
desc => 'Override option for the API endpoint (stat or config)',
required => 0,
},
{
spec => 'warning|w=s',
usage => '-w, --warning=STRING',
desc => 'Value for warning',
required => 0,
},
{
spec => 'critical|c=s',
usage => '-c, --critical=STRING',
desc => 'Value for critical',
required => 0,
},
{
spec => 'urlopts|x=s',
usage => '-x, --urlopts=STRING',
desc => 'add additional url options',
required => 0,
},
{
spec => 'api|a=s',
usage => '-a, --api=STRING',
desc => 'version of the NITRO API to use (default: v1)',
required => 0,
default => 'v1',
},
{
spec => 'filter|f=s',
usage => '-f, --filter=STRING',
desc => 'filter out objects from the API response (regular expression syntax)',
required => 0,
},
{
spec => 'limit|l=s',
usage => '-l, --limit=STRING',
desc => 'limit check to objects matching this pattern (regular expression syntax)',
required => 0,
},
{
spec => 'label|L=s',
usage => '-L, --label=STRING',
desc => 'optional name of the field, which will be used as identifier when the response contians multiple items (default is to use the array index instead)',
required => 0,
},
{
spec => 'seperator|S=s',
usage => '--seperator=STRING',
desc => 'optional seperator for perfdata values (see #47 for details)',
required => 0,
default => '.',
}
);
foreach my $arg (@args) {
add_arg( $plugin, $arg );
}
$plugin->getopts;
if ( $plugin->opts->command eq 'state' ) {
# check for up/down state of vservers, service, servicegroup
check_state($plugin);
} elsif ( $plugin->opts->command eq 'above' ) {
# check if a response is above a threshold
check_threshold_and_get_perfdata( $plugin, $plugin->opts->command );
} elsif ( $plugin->opts->command eq 'below' ) {
# check if a response is below a threshold
check_threshold_and_get_perfdata( $plugin, $plugin->opts->command );
}
# be backwards compatible; also accept command 'string'
elsif ( $plugin->opts->command eq 'matches' || $plugin->opts->command eq 'string' ) {
# check if a response does contains a specific string
check_keyword( $plugin, 'matches' );
}
# be backwards compatible; also accept command 'string_not'
elsif ( $plugin->opts->command eq 'matches_not' || $plugin->opts->command eq 'string_not' ) {
# check if a response does not contains a specific string
check_keyword( $plugin, 'matches not' );
} elsif ( $plugin->opts->command eq 'sslcert' ) {
# check for the lifetime of installed certificates
check_sslcert($plugin);
} elsif ( $plugin->opts->command eq 'nsconfig' ) {
# check for unsaved configuration changes
check_nsconfig($plugin);
} elsif ( $plugin->opts->command eq 'staserver' ) {
# check the state of the staservers
check_staserver($plugin);
} elsif ( $plugin->opts->command eq 'hwinfo' ) {
# print infos about hardware and build version
get_hardware_info($plugin);
} elsif ( $plugin->opts->command eq 'perfdata' ) {
# print performance data of protocol stats
check_threshold_and_get_perfdata( $plugin, 'above' );
} elsif ( $plugin->opts->command eq 'interfaces' ) {
# check the state of all interfaces
check_interfaces($plugin);
} elsif ( $plugin->opts->command eq 'servicegroup' ) {
# check the state of a servicegroup and its members
check_servicegroup($plugin);
} elsif ( $plugin->opts->command eq 'license' ) {
# check a installed license file
check_license($plugin);
} elsif ( $plugin->opts->command eq 'hastatus' ) {
# check the HA status of a node
check_hastatus($plugin);
} elsif ( $plugin->opts->command eq 'ntp' ) {
# check NTP status
check_ntp($plugin);
} elsif ( $plugin->opts->command eq 'debug' ) {
# dump the full response of the nitro api
check_debug($plugin);
} else {
# error, unkown command given
$plugin->plugin_die( 'unkown command ' . $plugin->opts->command . ' given' );
}
sub add_arg {
my $plugin = shift;
my $arg = shift;
my $spec = $arg->{'spec'};
my $help = $arg->{'usage'};
my $default = $arg->{'default'};
my $required = $arg->{'required'};
if ( defined $arg->{'desc'} ) {
my @desc;
if ( ref( $arg->{'desc'} ) ) {
@desc = @{ $arg->{'desc'} };
} else {
@desc = ( $arg->{'desc'} );
}
foreach my $d (@desc) {
$help .= "\n $d";
}
}
$plugin->add_arg(
spec => $spec,
help => $help,
default => $default,
required => $required,
);
}
sub nitro_client {
my $plugin = shift;
my $params = shift;
my $lwp = LWP::UserAgent->new(
env_proxy => 1,
keep_alive => 1,
timeout => $plugin->opts->timeout,
ssl_opts => {
verify_hostname => 0,
SSL_verify_mode => 0
},
);
my $protocol = 'http://';
if ( $plugin->opts->ssl ) {
$protocol = 'https://';
}
my $port = '';
if ( $plugin->opts->port ) {
$port = ':' . $plugin->opts->port;
}
my $url = $protocol . $plugin->opts->hostname . $port . '/nitro/' . $plugin->opts->api . '/' . $params->{'endpoint'} . '/' . $params->{'objecttype'};
if ( $params->{'objectname'} && $params->{'objectname'} ne '' ) {
$url = $url . '/' . uri_escape( uri_escape( $params->{'objectname'} ) );
}
if ( $params->{'options'} && $params->{'options'} ne '' ) {
$url = $url . '?' . $params->{'options'};
}
if ( $plugin->opts->verbose ) {
print "debug: target url is $url\n";
}
my $request = HTTP::Request->new( GET => $url );
$request->header( 'X-NITRO-USER', $plugin->opts->username );
$request->header( 'X-NITRO-PASS', $plugin->opts->password );
$request->header( 'Content-Type', 'application/vnd.com.citrix.netscaler.' . $params->{'objecttype'} . '+json' );
my $response = $lwp->request($request);
if ( $plugin->opts->verbose > 1 ) {
print "debug: response of request is:\n";
print Dumper( $response->content );
}
if ( HTTP::Status::is_error( $response->code ) ) {
$plugin->plugin_die( $response->content );
} else {
$response = JSON->new->allow_blessed->convert_blessed->decode( $response->content );
}
if ( $plugin->opts->verbose > 2 ) {
print "debug: json decoded response of request is:\n";
print Dumper($response);
}
return $response;
}
sub check_state {
my $plugin = shift;
if ( !defined $plugin->opts->objecttype ) {
$plugin->plugin_die( $plugin->opts->command . ': command requires objecttype parameter' );
}
my %counter;
# special handling for objecttype server
if ( $plugin->opts->objecttype eq 'server' ) {
$counter{'ENABLED'} = 0;
$counter{'DISABLED'} = 0;
} else {
$counter{'UP'} = 0;
$counter{'DOWN'} = 0;
$counter{'OUT OF SERVICE'} = 0;
$counter{'UNKOWN'} = 0;
# for servicegroups: PARTIAL-UP (non critical event)
if ( $plugin->opts->objecttype eq 'servicegroup' ) {
$counter{'PARTIAL-UP'} = 0;
}
}
# performance data for service and vservers
# if you want some performance data for your service groups please use the check_servicegroup command
# see https://www.icinga.com/docs/icinga1/latest/de/perfdata.html
my %perfdata;
$perfdata{'totalrequests'} = 'c';
$perfdata{'requestsrate'} = undef;
$perfdata{'totalresponses'} = 'c';
$perfdata{'responsesrate'} = undef;
$perfdata{'totalrequestbytes'} = 'B';
$perfdata{'requestbytesrate'} = undef;
$perfdata{'totalresponsebytes'} = 'B';
$perfdata{'responsebytesrate'} = undef;
my %params;
my $field_name = 'name';
my $field_state = 'state';
my $enable_perfdata = 1;
# well, i guess the citrix api developers were drunk
if ( $plugin->opts->objecttype eq 'service' ) {
$params{'endpoint'} = $plugin->opts->endpoint || 'config';
$field_name = 'name';
$field_state = 'svrstate';
$enable_perfdata = 0;
} elsif ( $plugin->opts->objecttype eq 'servicegroup' ) {
$params{'endpoint'} = $plugin->opts->endpoint || 'config';
$field_name = 'servicegroupname';
$field_state = 'servicegroupeffectivestate';
$enable_perfdata = 0;
} elsif ( $plugin->opts->objecttype eq 'server' ) {
$params{'endpoint'} = $plugin->opts->endpoint || 'config';
$field_name = 'name';
$field_state = 'state';
$enable_perfdata = 0;
} else {
$params{'endpoint'} = $plugin->opts->endpoint || 'stat';
}
$params{'objecttype'} = $plugin->opts->objecttype;
$params{'objectname'} = $plugin->opts->objectname;
$params{'options'} = $plugin->opts->urlopts;
my $response = nitro_client( $plugin, \%params );
$response = $response->{ $plugin->opts->objecttype };
# handle an empty response
if ( !scalar($response) ) {
if ( $params{'objectname'} && $params{'objectname'} ne '' ) {
$plugin->plugin_exit( CRITICAL, $plugin->opts->command . ': no ' . $plugin->opts->objecttype . ' found in configuration' );
} else {
$plugin->plugin_exit( OK, $plugin->opts->command . ': no ' . $plugin->opts->objecttype . ' found in configuration' );
}
}
# loop around, check states and increment the counters
foreach my $response ( @{$response} ) {
if ( defined( $plugin->opts->filter ) && $response->{$field_name} =~ $plugin->opts->filter ) {
next;
}
# limit parameter set (see #56)?
if ( defined( $plugin->opts->limit ) && $response->{$field_name} !~ $plugin->opts->limit ) {
next;
}
if ( defined( $counter{ $response->{$field_state} } ) ) {
$counter{ $response->{$field_state} }++;
}
if ( $response->{$field_state} eq 'UP' || $response->{$field_state} eq 'ENABLED' ) {
$plugin->add_message( OK, $response->{$field_name} . ' ' . $response->{$field_state} . ';' );
} elsif ( $response->{$field_state} eq 'PARTIAL-UP' || $response->{$field_state} eq 'DISABLED' ) {
$plugin->add_message( WARNING, $response->{$field_name} . ' ' . $response->{$field_state} . ';' );
} else {
$plugin->add_message( CRITICAL, $response->{$field_name} . ' ' . $response->{$field_state} . ';' );
}
# add performance data only if we are dealing with a single object
if ( defined( $plugin->opts->objectname ) && $enable_perfdata ) {
foreach my $perfdata_field ( keys %perfdata ) {
$plugin->add_perfdata(
label => $response->{$field_name} . ' ' . $perfdata_field,
value => $response->{$perfdata_field},
uom => $perfdata{$perfdata_field},
min => 0,
max => undef,
);
}
}
}
# a global counter is pretty useless for a single object
if ( !defined( $plugin->opts->objectname ) ) {
foreach my $key ( keys %counter ) {
$plugin->add_message( OK, $counter{$key} . ' ' . $key . ';' );
$plugin->add_perfdata(
label => $key,
value => $counter{$key},
uom => undef,
min => 0,
max => undef,
);
}
}
my ( $code, $message ) = $plugin->check_messages;
$plugin->plugin_exit( $code, $plugin->opts->command . ' ' . $plugin->opts->objecttype . ': ' . $message );
}
sub check_keyword {
my $plugin = shift;
my $type_of_string_comparison = shift;
if ( !defined $plugin->opts->objecttype ) {
$plugin->plugin_die( $plugin->opts->command . ': command requires parameter for objecttype' );
}
if ( !defined $plugin->opts->objectname ) {
$plugin->plugin_die( $plugin->opts->command . ': command requires parameter for objectname' );
}
if ( !defined $plugin->opts->warning || !defined $plugin->opts->critical ) {
$plugin->plugin_die( $plugin->opts->command . ': command requires parameter for warning and critical' );
}
if ( $type_of_string_comparison ne 'matches' && $type_of_string_comparison ne 'matches not' ) {
$plugin->plugin_die( $plugin->opts->command . ': string can only be checked for "matches" and "matches not"' );
}
my %params;
$params{'endpoint'} = $plugin->opts->endpoint || 'stat';
$params{'objecttype'} = $plugin->opts->objecttype;
$params{'objectname'} = undef;
$params{'options'} = $plugin->opts->urlopts;
my $response = nitro_client( $plugin, \%params );
# handle and objecttype with an slash inside (e.g. nspartition/mypartition)
if ( $params{'objecttype'} =~ /\// ) {
my @objecttype_parts = split( '/', $params{'objecttype'}, 2 );
$response = $response->{ $objecttype_parts[0] }[0];
} else {
$response = $response->{ $params{'objecttype'} };
}
if ( ref $response eq 'ARRAY' ) {
my $response_id = 0;
foreach $response ( @{$response} ) {
foreach my $origin_objectname ( split( ',', $plugin->opts->objectname ) ) {
my $objectname;
my $objectname_id;
my $description;
my $label;
# handling of the dot notation for sdx appliances (see #33)
if ( $plugin->opts->objectname =~ /\./ ) {
( $objectname_id, $objectname ) = split( '.', $origin_objectname );
if ( not defined( $response->{$objectname_id} ) ) {
$plugin->nagios_die( $plugin->opts->command . ': object id "' . $objectname_id . '" not found in output.' );
}
$description = $params{'objecttype'} . $plugin->opts->seperator . $response->{$objectname_id} . $plugin->opts->seperator . $objectname;
} else {
$objectname = $origin_objectname;
# use a custom label from a field in the response as perfdata label (see #56)
if ( $plugin->opts->label ) {
$label = $response->{ $plugin->opts->label };
} else {
$label = $response_id;
}
$description = $params{'objecttype'} . $plugin->opts->seperator . $origin_objectname . '[' . $label . ']';
}
if ( not defined( $response->{$objectname} ) ) {
$plugin->plugin_die( $plugin->opts->command . ': object name "' . $objectname . '" not found in output.' );
}
# should we skip this label (see #56)?
if ( defined( $plugin->opts->filter ) && $label =~ $plugin->opts->filter ) {
next;
}
# limit parameter set (see #56)?
if ( defined( $plugin->opts->limit ) && $label !~ $plugin->opts->limit ) {
next;
}
if ( ( $type_of_string_comparison eq 'matches' && $response->{$objectname} eq $plugin->opts->critical )
|| ( $type_of_string_comparison eq 'matches not' && $response->{$objectname} ne $plugin->opts->critical ) )
{
$plugin->add_message( CRITICAL, $description . ': "' . $response->{$objectname} . '" ' . $type_of_string_comparison . ' keyword "' . $plugin->opts->critical . '"' );
} elsif ( ( $type_of_string_comparison eq 'matches' && $response->{$objectname} eq $plugin->opts->warning )
|| ( $type_of_string_comparison eq 'matches not' && $response->{$objectname} ne $plugin->opts->warning ) )
{
$plugin->add_message( WARNING, $description . ': "' . $response->{$objectname} . '" ' . $type_of_string_comparison . ' keyword "' . $plugin->opts->warning . '"' );
} else {
$plugin->add_message( OK, $description . ': "' . $response->{$objectname} . '"' );
}
$response_id++;
}
}
} elsif ( ref $response eq 'HASH' ) {
foreach ( split( ',', $plugin->opts->objectname ) ) {
if ( ( $type_of_string_comparison eq 'matches' && $response->{$_} eq $plugin->opts->critical ) || ( $type_of_string_comparison eq 'matches not' && $response->{$_} ne $plugin->opts->critical ) )
{
$plugin->add_message( CRITICAL, $plugin->opts->objecttype . '.' . $_ . ': "' . $response->{$_} . '" ' . $type_of_string_comparison . ' keyword "' . $plugin->opts->critical . '";' );
} elsif ( ( $type_of_string_comparison eq 'matches' && $response->{$_} eq $plugin->opts->warning )
|| ( $type_of_string_comparison eq 'matches not' && $response->{$_} ne $plugin->opts->warning ) )
{
$plugin->add_message( WARNING, $plugin->opts->objecttype . '.' . $_ . ': "' . $response->{$_} . '" ' . $type_of_string_comparison . ' keyword "' . $plugin->opts->warning . '";' );
} else {
$plugin->add_message( OK, $plugin->opts->objecttype . '.' . $_ . ': ' . $response->{$_} . ';' );
}
}
} else {
$plugin->plugin_die( $plugin->opts->command . ': unable to parse data. Returned data is not a HASH or ARRAY!' );
}
my ( $code, $message ) = $plugin->check_messages( join => "; ", join_all => "; " );
$plugin->plugin_exit( $code, 'keyword ' . $type_of_string_comparison . ': ' . $message );
}
sub check_sslcert {
my $plugin = shift;
# defaults for warning and critical
my $warning = $plugin->opts->warning || 30;
my $critical = $plugin->opts->critical || 10;
my %params;
$params{'endpoint'} = $plugin->opts->endpoint || 'config';
$params{'objecttype'} = $plugin->opts->objecttype || 'sslcertkey';
$params{'objectname'} = $plugin->opts->objectname;
$params{'options'} = $plugin->opts->urlopts;
my $response = nitro_client( $plugin, \%params );
$response = $response->{ $params{'objecttype'} };
foreach $response ( @{$response} ) {
if ( defined( $plugin->opts->filter ) && $response->{certkey} =~ $plugin->opts->filter ) {
next;
}
# limit parameter set (see #56)?
if ( defined( $plugin->opts->limit ) && $response->{certkey} !~ $plugin->opts->limit ) {
next;
}
if ( $response->{daystoexpiration} <= 0 ) {
$plugin->add_message( CRITICAL, $response->{certkey} . ' expired;' );
} elsif ( $response->{daystoexpiration} <= $critical ) {
$plugin->add_message( CRITICAL, $response->{certkey} . ' expires in ' . $response->{daystoexpiration} . ' days;' );
} elsif ( $response->{daystoexpiration} <= $warning ) {
$plugin->add_message( WARNING, $response->{certkey} . ' expires in ' . $response->{daystoexpiration} . ' days;' );
}
}
my ( $code, $message ) = $plugin->check_messages;
if ( $code == OK ) {
$plugin->plugin_exit( $code, $plugin->opts->command . ': certificate lifetime OK' );
} else {
$plugin->plugin_exit( $code, $plugin->opts->command . ': ' . $message );
}
}
sub check_staserver {
my $plugin = shift;
my %params;
$params{'endpoint'} = $plugin->opts->endpoint || 'config';
$params{'objectname'} = $plugin->opts->objectname || '';
$params{'options'} = $plugin->opts->urlopts;
if ( $params{'objectname'} eq '' ) {
$params{'objecttype'} = $plugin->opts->objecttype || 'vpnglobal_staserver_binding';
} else {
$params{'objecttype'} = $plugin->opts->objecttype || 'vpnvserver_staserver_binding';
}
my $response = nitro_client( $plugin, \%params );
$response = $response->{ $params{'objecttype'} };
if ( !scalar($response) ) {
$plugin->plugin_exit( CRITICAL, $plugin->opts->command . ': no staserver found in configuration' );
}
# return critical if all staservers are down at once
my $critical = 1;
# check if any stas are in down state
foreach $response ( @{$response} ) {
if ( defined( $plugin->opts->filter ) && $response->{'staserver'} =~ $plugin->opts->filter ) {
next;
}
# limit parameter set (see #56)?
if ( defined( $plugin->opts->limit ) && $response->{'staserver'} !~ $plugin->opts->limit ) {
next;
}
if ( $response->{'staauthid'} eq '' ) {
$plugin->add_message( WARNING, $response->{'staserver'} . ' unavailable;' );
} else {
$plugin->add_message( OK, $response->{'staserver'} . ' OK (' . $response->{'staauthid'} . ');' );
$critical = 0;
}
}
my ( $code, $message ) = $plugin->check_messages;
if ( $critical == 1 ) { $code = CRITICAL; }
$plugin->plugin_exit( $code, $plugin->opts->command . ': ' . $message );
}
sub check_nsconfig {
my $plugin = shift;
my %params;
$params{'endpoint'} = $plugin->opts->endpoint || 'config';
$params{'objecttype'} = $plugin->opts->objecttype || 'nsconfig';
$params{'objectname'} = undef;
$params{'options'} = $plugin->opts->urlopts;
my $response = nitro_client( $plugin, \%params );
$response = $response->{ $params{'objecttype'} };
if ( !defined $response->{'configchanged'} || $response->{'configchanged'} ) {
$plugin->plugin_exit( WARNING, $plugin->opts->command . ': unsaved configuration changes' );
} else {
$plugin->plugin_exit( OK, $plugin->opts->command . ': no unsaved configuration changes' );
}
}
sub get_hardware_info {
my $plugin = shift;
my %params;
$params{'endpoint'} = 'config';
$params{'objecttype'} = 'nshardware';
$params{'objectname'} = undef;
$params{'options'} = $plugin->opts->urlopts;
my $response = nitro_client( $plugin, \%params );
$response = $response->{ $params{'objecttype'} };
$plugin->add_message( OK, 'Platform: ' . $response->{'hwdescription'} . ' ' . $response->{'sysid'} . ';' );
$plugin->add_message( OK, 'Manufactured on: ' . $response->{'manufactureyear'} . '/' . $response->{'manufacturemonth'} . '/' . $response->{'manufactureday'} . ';' );
$plugin->add_message( OK, 'CPU: ' . $response->{'cpufrequncy'} . 'MHz;' );
$plugin->add_message( OK, 'Serial no: ' . $response->{'serialno'} . ';' );
$params{'objecttype'} = 'nsversion';
$response = nitro_client( $plugin, \%params );
$response = $response->{ $params{'objecttype'} };
$plugin->add_message( OK, 'Build Version: ' . $response->{'version'} . ';' );
my ( $code, $message ) = $plugin->check_messages;
$plugin->plugin_exit( $code, $plugin->opts->command . ': ' . $message );
}
sub check_threshold_and_get_perfdata {
my $plugin = shift;
my $direction = shift;
my %params;
$params{'endpoint'} = $plugin->opts->endpoint || 'stat';
$params{'objecttype'} = $plugin->opts->objecttype;
$params{'objectname'} = undef;
$params{'options'} = $plugin->opts->urlopts;
if ( !defined $plugin->opts->objecttype ) {
$plugin->plugin_die( $plugin->opts->command . ': command requires parameter for objecttype' );
}
if ( !defined $plugin->opts->objectname ) {
$plugin->plugin_die( $plugin->opts->command . ': command requires parameter for objectname' );
}
if ( $direction ne 'above' && $direction ne 'below' ) {
$plugin->plugin_die( $plugin->opts->command . ': threshold can only be checked for "above" and "below"' );
}
my $response = nitro_client( $plugin, \%params );
# handle and objecttype with an slash inside (e.g. nspartition/mypartition)
if ( $params{'objecttype'} =~ /\// ) {
my @objecttype_parts = split( '/', $params{'objecttype'}, 2 );
$response = $response->{ $objecttype_parts[0] }[0];
} else {
$response = $response->{ $params{'objecttype'} };
}
if ( ref $response eq 'ARRAY' ) {
my $response_id = 0;
foreach $response ( @{$response} ) {
foreach my $origin_objectname ( split( ',', $plugin->opts->objectname ) ) {
my $objectname;
my $objectname_id;
my $description;
my $label;
# handling of the dot notation for sdx appliances (see #33)
if ( $plugin->opts->objectname =~ /\./ ) {
( $objectname_id, $objectname ) = split( '.', $origin_objectname );
if ( not defined( $response->{$objectname_id} ) ) {
$plugin->nagios_die( $plugin->opts->command . ': object id "' . $objectname_id . '" not found in output.' );
}
$description = $params{'objecttype'} . '.' . $response->{$objectname_id} . '.' . $objectname;
} else {
$objectname = $origin_objectname;
# use a custom label from a field in the response as perfdata label (see #56)
if ( $plugin->opts->label ) {
$label = $response->{ $plugin->opts->label };
} else {
$label = $response_id;
}
$description = $params{'objecttype'} . $plugin->opts->seperator . $origin_objectname . '[' . $label . ']';
}
# should we skip this label (see #56)?
if ( defined( $plugin->opts->filter ) && $label =~ $plugin->opts->filter ) {
next;
}
# limit parameter set (see #56)?
if ( defined( $plugin->opts->limit ) && $label !~ $plugin->opts->limit ) {
next;
}
if ( not defined( $response->{$objectname} ) ) {
$plugin->plugin_die( $plugin->opts->command . ': object name "' . $objectname . '" not found in output.' );
}
# check thresholds
if ( defined $plugin->opts->critical && ( $direction eq 'above' && $response->{$objectname} >= $plugin->opts->critical )
|| ( $direction eq 'below' && $response->{$objectname} <= $plugin->opts->critical ) )
{
$plugin->add_message( CRITICAL, $description . ' is ' . $direction . ' threshold (current: ' . $response->{$objectname} . ', critical: ' . $plugin->opts->critical . ')' );
} elsif ( defined $plugin->opts->warning && ( $direction eq 'above' && $response->{$objectname} >= $plugin->opts->warning )
|| ( $direction eq 'below' && $response->{$objectname} <= $plugin->opts->warning ) )
{
$plugin->add_message( WARNING, $description . ' is ' . $direction . ' threshold (current: ' . $response->{$objectname} . ', warning: ' . $plugin->opts->warning . ')' );
} else {
$plugin->add_message( OK, $description . ': ' . $response->{$objectname} );
}
$plugin->add_perfdata(
label => "'" . $description . "'",
value => $response->{$objectname},
min => undef,
max => undef,
warning => $plugin->opts->warning,
critical => $plugin->opts->critical,
);
}
$response_id++;
}
} elsif ( ref $response eq 'HASH' ) {
foreach my $objectname ( split( ',', $plugin->opts->objectname ) ) {
if ( not defined( $response->{$objectname} ) ) {
$plugin->plugin_die( $plugin->opts->command . ': object name "' . $objectname . '" not found in output.' );
}
# check thresholds
if ( defined $plugin->opts->critical && ( $direction eq 'above' && $response->{$objectname} >= $plugin->opts->critical )
|| ( $direction eq 'below' && $response->{$objectname} <= $plugin->opts->critical ) )
{
$plugin->add_message( CRITICAL,
$params{'objecttype'} . '.' . $objectname . ' is ' . $direction . ' threshold (current: ' . $response->{$objectname} . ', critical: ' . $plugin->opts->critical . ')' );
} elsif ( defined $plugin->opts->warning && ( $direction eq 'above' && $response->{$objectname} >= $plugin->opts->warning )
|| ( $direction eq 'below' && $response->{$objectname} <= $plugin->opts->warning ) )
{
$plugin->add_message( WARNING,
$params{'objecttype'} . '.' . $objectname . ' is ' . $direction . ' threshold (current: ' . $response->{$objectname} . ', warning: ' . $plugin->opts->warning . ')' );
} else {
$plugin->add_message( OK, $params{'objecttype'} . '.' . $objectname . ': ' . $response->{$objectname} );
}
$plugin->add_perfdata(
label => "'" . $params{'objecttype'} . $plugin->opts->seperator . $objectname . "'",
value => $response->{$objectname},
min => undef,
max => undef,
warning => $plugin->opts->warning,
critical => $plugin->opts->critical,
);
}
} else {
$plugin->plugin_die( $plugin->opts->command . ': unable to parse data. Returned data is not a HASH or ARRAY!' );
}
my ( $code, $message ) = $plugin->check_messages( join => "; ", join_all => "; " );
$plugin->plugin_exit( $code, $plugin->opts->command . ': ' . $message );
}
sub check_interfaces {
my $plugin = shift;
my @interface_errors;
my %params;
$params{'endpoint'} = 'config';
$params{'objecttype'} = 'interface';
$params{'objectname'} = undef;
$params{'options'} = $plugin->opts->urlopts;
my $response = nitro_client( $plugin, \%params );
foreach my $interface ( @{ $response->{'Interface'} } ) {
if ( defined( $plugin->opts->filter ) && $interface->{'devicename'} =~ $plugin->opts->filter ) {
next;
}
# limit parameter set (see #56)?
if ( defined( $plugin->opts->limit ) && $interface->{'devicename'} !~ $plugin->opts->limit ) {
next;
}
my $interface_state = OK;
my $interface_speed = 'N/A';
if ( $interface->{'actspeed'} ) { $interface_speed = $interface->{'actspeed'}; }
if ( $interface->{'linkstate'} != 1 ) {
push( @interface_errors, 'interface ' . $interface->{'devicename'} . " has linkstate \"DOWN\"" );
$interface_state = CRITICAL;
}
if ( $interface->{'intfstate'} != 1 ) {
push( @interface_errors, 'interface ' . $interface->{'devicename'} . " has intstate \"DOWN\"" );
$interface_state = CRITICAL;
}
if ( $interface->{'state'} ne 'ENABLED' ) {
push( @interface_errors, 'interface ' . $interface->{'devicename'} . " has state \"" . $interface->{'state'} . "\"" );
$interface_state = CRITICAL;
}
$plugin->add_message( $interface_state,
'device: '
. $interface->{'devicename'}
. ' (speed: '
. $interface_speed
. ', MTU: '
. $interface->{'actualmtu'}
. ', VLAN: '
. $interface->{'vlan'}
. ', type: '
. $interface->{'intftype'} . ') '
. $interface->{'state'}
. ';' );
$plugin->add_perfdata(
label => "\'" . $interface->{'devicename'} . $plugin->opts->seperator . "rxbytes'",
value => $interface->{'rxbytes'} . 'B'
);
$plugin->add_perfdata(
label => "\'" . $interface->{'devicename'} . $plugin->opts->seperator . "txbytes'",
value => $interface->{'txbytes'} . 'B'
);
$plugin->add_perfdata(
label => "\'" . $interface->{'devicename'} . $plugin->opts->seperator . "rxerrors'",
value => $interface->{'rxerrors'} . 'c'
);
$plugin->add_perfdata(
label => "\'" . $interface->{'devicename'} . $plugin->opts->seperator . "txerrors'",
value => $interface->{'txerrors'} . 'c'
);
}
my ( $code, $message ) = $plugin->check_messages;
if ( scalar @interface_errors != 0 ) {
$message = join( ', ', @interface_errors ) . ' - ' . $message;
}
$plugin->plugin_exit( $code, $plugin->opts->command . ': ' . $message );
}
sub check_servicegroup {
my $plugin = shift;
my @servicegroup_errors;
# define quorum (in percent) of working servicegroup members
my $member_quorum_warning = $plugin->opts->warning || '90';
my $member_quorum_critical = $plugin->opts->critical || '50';
my %member_state;
my %params;
$params{'endpoint'} = 'config';