-
Notifications
You must be signed in to change notification settings - Fork 1
/
parser.l
1551 lines (1273 loc) · 35.3 KB
/
parser.l
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
/* Copyright 2009-2024
* Kaz Kylheku <kaz@kylheku.com>
* Vancouver, Canada
* All rights reserved.
*
* Redistribution and use in source and binary forms, with or without
* modification, are permitted provided that the following conditions are met:
*
* 1. Redistributions of source code must retain the above copyright notice,
* this list of conditions and the following disclaimer.
*
* 2. Redistributions in binary form must reproduce the above copyright notice,
* this list of conditions and the following disclaimer in the documentation
* and/or other materials provided with the distribution.
*
* THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS"
* AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
* IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
* ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT HOLDER OR CONTRIBUTORS BE
* LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR
* CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF
* SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS
* INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN
* CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
* ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
* POSSIBILITY OF SUCH DAMAGE.
*/
%{
#include <stdio.h>
#include <string.h>
#include <stdarg.h>
#include <stdlib.h>
#include <limits.h>
#include <wchar.h>
#include <signal.h>
#include "config.h"
#include "lib.h"
#include "gc.h"
#include "stream.h"
#include "utf8.h"
#include "signal.h"
#include "unwind.h"
#include "hash.h"
#include "y.tab.h"
#include "parser.h"
#include "txr.h"
#define YY_INPUT(buf, result, max_size) \
do { \
val self = lit("parser"); \
val n = get_bytes(self, yyextra->stream, \
coerce(mem_t *, buf), max_size); \
result = c_num(n, self); \
} while (0)
#define YY_DECL \
static int yylex_impl(YYSTYPE *yylval_param, yyscan_t yyscanner)
#define YY_FATAL_ERROR(msg) lex_irrecoverable_error(msg)
int opt_loglevel = 1; /* 0 - quiet; 1 - normal; 2 - verbose */
val form_to_ln_hash;
static int directive_tok(scanner_t *yyg, int tok, int state);
#define FLEX_NUM_VERSION 10000*YY_FLEX_MAJOR_VERSION + \
100*YY_FLEX_MINOR_VERSION + \
YY_FLEX_SUBMINOR_VERSION
#if FLEX_NUM_VERSION < 20509
int yylex_destroy(void)
{
return 0;
}
#endif
/* Missing prototypes not generated by flex. */
int yyget_column(yyscan_t);
void yyset_column (int column_no, yyscan_t yyscanner);
/* The following function is all that libflex provides.
By providing it here, we eliminate the need to link libflex. */
#define YY_SKIP_YYWRAP
INLINE int yywrap(yyscan_t scanner)
{
(void) scanner;
return 1;
}
void yyerror(scanner_t *scanner, parser_t *parser, const char *s)
{
yyerrorf(scanner, lit("~a"), string_utf8(s), nao);
if (parser->prepared_msg) {
yyerrorf(scanner, lit("~a"), parser->prepared_msg, nao);
parser->prepared_msg = nil;
}
}
void yyerrorf(scanner_t *scanner, val fmt, ...)
{
parser_t *parser = yyget_extra(scanner);
if (opt_loglevel >= 1) {
va_list vl;
va_start (vl, fmt);
if (opt_compat && opt_compat <= 114)
format(std_error, lit("~a: (~a:~d): "), prog_string,
parser->name, num(parser->lineno), nao);
else
format(std_error, lit("~a:~d: "),
parser->name, num(parser->lineno), nao);
vformat(std_error, fmt, vl);
put_char(chr('\n'), std_error);
va_end (vl);
}
parser->errors++;
}
static void yyerrprepf(scanner_t *scanner, val fmt, ...)
{
parser_t *parser = yyget_extra(scanner);
if (opt_loglevel >= 1) {
va_list vl;
va_start (vl, fmt);
set(mkloc(parser->prepared_msg, parser->parser),
vformat_to_string(fmt, vl));
va_end (vl);
}
}
static void lex_irrecoverable_error(const char *msg8)
{
val msg = string_utf8(msg8);
uw_throwf(error_s, lit("error in parser: ~a"), msg, nao);
}
static void out_of_range_float(scanner_t *scanner, const char *tok)
{
yyerrorf(scanner, lit("out-of-range floating-point literal: ~a"),
string_utf8(tok), nao);
}
static wchar_t char_esc(int letter)
{
switch (letter) {
case ' ': return L' ';
case 'a': return L'\a';
case 'b': return L'\b';
case 't': return L'\t';
case 'n': return L'\n';
case 'v': return L'\v';
case 'f': return L'\f';
case 'r': return L'\r';
case 'e': return 27;
case '"': return L'"';
case '\'': return L'\'';
case '`': return L'`';
case '/': return L'/';
case '@': return L'@';
case '\\': return L'\\';
}
internal_error("unhandled escape character");
}
static wchar_t num_esc(scanner_t *scn, char *num)
{
long val = 0;
if (num[0] == 'x' || num[0] == 'u') {
if (strlen(num) > 7)
yyerror(scn, yyget_extra(scn), "too many digits in hex character escape");
else
val = strtol(num + 1, 0, 16);
} else {
if (num[0] == 'o')
num++;
if (strlen(num) > 8)
yyerror(scn, yyget_extra(scn), "too many digits in octal character escape");
else
val = strtol(num, 0, 8);
}
if (val < 0 || val > 0x10FFFF || convert(wchar_t, val) != val) {
yyerror(scn, yyget_extra(scn), "numeric character escape out of range");
val = 0;
}
return val;
}
static wchar_t *unicode_ident(scanner_t *scn, const char *lex)
{
wchar_t *wlex = utf8_dup_from(lex), *ptr = wlex, wch;
while ((wch = *ptr++)) {
if (wch < 0x1680 || (wch >= 0x3000 && wch < 0xdc00))
continue;
if ((wch >= 0xdc00 && wch <= 0xdcff) ||
(wch >= 0xd800 && wch <= 0xdbff) ||
#if FULL_UNICODE
(wch >= 0xf0000 && wch <= 0xffffd) ||
(wch >= 0x100000 && wch <= 0x10fffd) ||
#endif
(wch >= 0xe000 && wch <= 0xf8ff) ||
(wch == 0xfffe) ||
(wch == 0xffff))
{
yyerror(scn, yyget_extra(scn),
"disallowed Unicode character in identifier");
break;
}
switch (wch) {
case 0x1680: case 0x180e: case 0x2000: case 0x2001: case 0x2002:
case 0x2003: case 0x2004: case 0x2005: case 0x2006: case 0x2007:
case 0x2008: case 0x2009: case 0x200a: case 0x2028: case 0x2029:
case 0x205f: case 0x3000:
yyerror(scn, yyget_extra(scn),
"Unicode space occurs in identifier");
break;
default:
continue;
}
break;
}
return wlex;
}
static char *remove_char(char *str, int c)
{
char *dst = str, *src = str;
while (*src) {
int ch = *src++;
if (ch != c)
*dst++ = ch;
}
*dst = 0;
return str;
}
%}
%option stack noinput reentrant bison-bridge extra-type="parser_t *"
%option never-interactive
TOK [a-zA-Z0-9_]+
SGN [+\-]
EXP [eE][+\-]?[0-9]+
DIG [0-9]
DIG19 [1-9]
DIGSEP {DIG}({DIG}|,)*{DIG}|{DIG}
XDIG [0-9A-Fa-f]
XDIGSEP {XDIG}({XDIG}|,)*{XDIG}|{XDIG}
NUM {SGN}?{DIG}+
NUMSEP {SGN}?{DIGSEP}
FLO {SGN}?({DIG}*[.]{DIG}+{EXP}?|{DIG}+[.]?{EXP})
FLOSEP {SGN}?({DIGSEP}*[.]{DIGSEP}+{EXP}?|{DIGSEP}+[.]?{EXP})
FLODOT {SGN}?{DIGSEP}+[.]
DOTFLO [.]{DIG}+
XNUM #x{SGN}?{XDIG}+
XNUMSEP #x{SGN}?{XDIGSEP}
ODIG [0-7]
ODIGSEP {ODIG}({ODIG}|,)*{ODIG}|{ODIG}
BDIG [01]
BDIGSEP {BDIG}({BDIG}|,)*{BDIG}|{BDIG}
ONUM #o{SGN}?{ODIG}+
ONUMSEP #o{SGN}?{ODIGSEP}
BNUM #b{SGN}?{BDIG}+
BNUMSEP #b{SGN}?{BDIGSEP}
BSCHR ([a-zA-Z0-9!$%&*+\-<=>?\\_~]|{UONLY})
NSCHR ([a-zA-Z0-9!$%&*+\-<=>?\\_~/]|{UONLY})
ID_END [^a-zA-Z0-9!$%&*+\-<=>?\\_~/]
EXTRA [#^]
BT0 {BSCHR}({BSCHR}|{EXTRA})*
BT1 @{BT0}+
BT2 ({BSCHR}|{EXTRA})+
BTREG ({BT0}|{BT1})?:{BT2}?|({BT0}|{BT1})(:{BT2})?
BTKWUN @?#?:{BT2}?
BTOK {BTREG}|{BTKWUN}
NT0 {NSCHR}({NSCHR}|{EXTRA})*
NT1 @{NT0}+
NT2 ({NSCHR}|{EXTRA})+
NTREG ({NT0}|{NT1})?:{NT2}?|({NT0}|{NT1})(:{NT2})?
NTKWUN @?#?:{NT2}?
NTOK {NTREG}|{NTKWUN}
WS [\t ]*
REQWS [\t ]+
NL (\n|\r|\r\n)
HEX [0-9A-Fa-f]
OCT [0-7]
REGOP [/()|.*?+~&%\[\]\-]
ASC [\x00-\x7f]
ASCN [\x00-\t\v-\x7f]
U [\x80-\xbf]
U2 [\xc2-\xdf]
U3 [\xe0-\xef]
U4 [\xf0-\xf4]
UANY {ASC}|{U2}{U}|{U3}{U}{U}|{U4}{U}{U}{U}
UANYN {ASCN}|{U2}{U}|{U3}{U}{U}|{U4}{U}{U}{U}
UONLY {U2}{U}|{U3}{U}{U}|{U4}{U}{U}{U}
JNUM -?(0|{DIG19}{DIG}*)([.]{DIG}+)?{EXP}?
JPUNC [(){},:\[\]"~*^]
NJPUNC [^(){},:\[\]"~*^ \t\r\n]
%x SPECIAL BRACED NESTED REGEX SREGEX STRLIT CHRLIT
%x QSILIT QSPECIAL WLIT QWLIT BUFLIT
%x JSON JLIT JMARKER
%%
<SPECIAL,QSPECIAL,NESTED,BRACED>{NUM} {
wchar_t *wtxt = utf8_dup_from(yytext);
if (yy_top_state(yyscanner) == INITIAL
|| yy_top_state(yyscanner) == QSILIT
|| yy_top_state(yyscanner) == QWLIT)
yy_pop_state(yyscanner);
yylval->val = int_str_wc(wtxt, num(10));
free(wtxt);
return NUMBER;
}
<SPECIAL,QSPECIAL,NESTED,BRACED>{NUMSEP} {
wchar_t *wtxt = utf8_dup_from(remove_char(yytext, ','));
if (yy_top_state(yyscanner) == INITIAL
|| yy_top_state(yyscanner) == QSILIT
|| yy_top_state(yyscanner) == QWLIT)
yy_pop_state(yyscanner);
yylval->val = int_str_wc(wtxt, num(10));
free(wtxt);
return NUMBER;
}
<SPECIAL,QSPECIAL,NESTED,BRACED>{XNUMSEP}|{ONUMSEP}|{BNUMSEP} {
wchar_t *wtxt = utf8_dup_from(remove_char(yytext + 2, ','));
int base;
switch (yytext[1]) {
case 'x': base = 16; break;
case 'o': base = 8; break;
case 'b': default: base = 2; break;
}
if (yy_top_state(yyscanner) == INITIAL
|| yy_top_state(yyscanner) == QSILIT
|| yy_top_state(yyscanner) == QWLIT)
yy_pop_state(yyscanner);
yylval->val = int_str_wc(wtxt, num_fast(base));
free(wtxt);
return NUMBER;
}
<SPECIAL,QSPECIAL,NESTED,BRACED>({BNUMSEP}|{ONUMSEP}|{XNUMSEP}){TOK} {
int base = 0;
val str = string_own(utf8_dup_from(yytext + 2));
switch (yytext[1]) {
case 'x': base = 16; break;
case 'o': base = 8; break;
case 'b': default: base = 2; break;
}
yyerrorf(yyg, lit("trailing junk in numeric literal: ~a~a~a"),
chr(yytext[0]), chr(yytext[1]), str, nao);
if (yy_top_state(yyscanner) == INITIAL
|| yy_top_state(yyscanner) == QSILIT
|| yy_top_state(yyscanner) == QWLIT)
yy_pop_state(yyscanner);
yylval->val = int_str(str, num_fast(base));
return NUMBER;
}
<SPECIAL,NESTED,BRACED>{WS}{FLO} {
if (yy_top_state(yyscanner) == INITIAL
|| yy_top_state(yyscanner) == QSILIT
|| yy_top_state(yyscanner) == QWLIT)
yy_pop_state(yyscanner);
if ((yylval->val = flo_str_utf8(yytext)) == nil)
out_of_range_float(yyg, yytext);
return NUMBER;
}
<SPECIAL,NESTED,BRACED>{WS}{FLOSEP} {
if (yy_top_state(yyscanner) == INITIAL
|| yy_top_state(yyscanner) == QSILIT
|| yy_top_state(yyscanner) == QWLIT)
yy_pop_state(yyscanner);
remove_char(yytext, ',');
if ((yylval->val = flo_str_utf8(yytext)) == nil)
out_of_range_float(yyg, yytext);
return NUMBER;
}
<SPECIAL>{WS}({FLOSEP}[.]?|{FLODOT}){TOK} |
<BRACED>{WS}({FLOSEP}[.]?|{FLODOT}){BTOK} |
<NESTED>{WS}({FLOSEP}[.]?|{FLODOT}){NTOK} {
val str = string_utf8(yytext);
yyerrorf(yyg, lit("trailing junk in floating-point literal: ~a"), str, nao);
if (yy_top_state(yyscanner) == INITIAL
|| yy_top_state(yyscanner) == QSILIT
|| yy_top_state(yyscanner) == QWLIT)
yy_pop_state(yyscanner);
if ((yylval->val = flo_str_utf8(yytext)) == nil)
out_of_range_float(yyg, yytext);
return NUMBER;
}
<SPECIAL,QSPECIAL,NESTED,BRACED>{FLODOT}/[^.] {
if (yy_top_state(yyscanner) == INITIAL
|| yy_top_state(yyscanner) == QSILIT
|| yy_top_state(yyscanner) == QWLIT)
yy_pop_state(yyscanner);
if ((yylval->val = flo_str_utf8(yytext)) == nil)
out_of_range_float(yyg, yytext);
return NUMBER;
}
<NESTED,BRACED,QSILIT,QWLIT>@{NUM} |
<QSPECIAL>{NUM} {
wchar_t *wtxt = utf8_dup_from(yytext + 1);
if (yy_top_state(yyscanner) == INITIAL
|| yy_top_state(yyscanner) == QSILIT
|| yy_top_state(yyscanner) == QWLIT)
yy_pop_state(yyscanner);
yylval->val = int_str_wc(wtxt, num(10));
free(wtxt);
return METANUM;
}
<NESTED,QSILIT,QWLIT>@{XNUM} |
<QSPECIAL>{XNUM} {
wchar_t *wtxt = utf8_dup_from(yytext + 3);
if (yy_top_state(yyscanner) == INITIAL
|| yy_top_state(yyscanner) == QSILIT
|| yy_top_state(yyscanner) == QWLIT)
yy_pop_state(yyscanner);
yylval->val = int_str_wc(wtxt, num(16));
free(wtxt);
return METANUM;
}
<NESTED,QSILIT,QWLIT>@{ONUM} |
<QSPECIAL>{ONUM} {
wchar_t *wtxt = utf8_dup_from(yytext + 3);
if (yy_top_state(yyscanner) == INITIAL
|| yy_top_state(yyscanner) == QSILIT
|| yy_top_state(yyscanner) == QWLIT)
yy_pop_state(yyscanner);
yylval->val = int_str_wc(wtxt, num(8));
free(wtxt);
return METANUM;
}
<NESTED,QSILIT,QWLIT,QSPECIAL>@{BNUM} {
wchar_t *wtxt = utf8_dup_from(yytext + 3);
if (yy_top_state(yyscanner) == INITIAL
|| yy_top_state(yyscanner) == QSILIT
|| yy_top_state(yyscanner) == QWLIT)
yy_pop_state(yyscanner);
yylval->val = int_str_wc(wtxt, num(2));
free(wtxt);
return METANUM;
}
<SPECIAL,QSPECIAL>{TOK}/{DOTFLO} |
<BRACED>{BTOK}/{DOTFLO} |
<NESTED>{NTOK}/{DOTFLO} {
yyerrorf(yyg, lit("cramped floating-point literal: "
"space needed between ~a and dot."),
string_own(utf8_dup_from(yytext)),
nao);
if (yy_top_state(yyscanner) == INITIAL
|| yy_top_state(yyscanner) == QSILIT
|| yy_top_state(yyscanner) == QWLIT)
yy_pop_state(yyscanner);
yylval->lexeme = unicode_ident(yyg, yytext);
return SYMTOK;
}
<SPECIAL,QSPECIAL>{TOK} |
<BRACED>{BTOK} |
<NESTED>{NTOK} {
if (yy_top_state(yyscanner) == INITIAL
|| yy_top_state(yyscanner) == QSILIT
|| yy_top_state(yyscanner) == QWLIT)
yy_pop_state(yyscanner);
yylval->lexeme = unicode_ident(yyg, yytext);
return SYMTOK;
}
<BRACED>{BTOK}{BTOK} |
<NESTED>{NTOK}{NTOK} {
if (yy_top_state(yyscanner) == INITIAL
|| yy_top_state(yyscanner) == QSILIT
|| yy_top_state(yyscanner) == QWLIT)
yy_pop_state(yyscanner);
yyerrorf(yyg, lit("bad token: ~a"),
string_own(utf8_dup_from(yytext)),
nao);
yylval->lexeme = unicode_ident(yyg, yytext);
return SYMTOK;
}
<SPECIAL>\({WS}({NT0}?:)?all{WS}\) {
return directive_tok(yyg, ALL, 0);
}
<SPECIAL>\({WS}({NT0}?:)?some/{ID_END} {
return directive_tok(yyg, SOME, NESTED);
}
<SPECIAL>\({WS}({NT0}?:)?none{WS}\) {
return directive_tok(yyg, NONE, 0);
}
<SPECIAL>\({WS}({NT0}?:)?maybe{WS}\) {
return directive_tok(yyg, MAYBE, 0);
}
<SPECIAL>\({WS}({NT0}?:)?cases{WS}\) {
return directive_tok(yyg, CASES, 0);
}
<SPECIAL>\({WS}({NT0}?:)?block/{ID_END} {
return directive_tok(yyg, BLOCK, NESTED);
}
<SPECIAL>\({WS}({NT0}?:)?choose/{ID_END} {
return directive_tok(yyg, CHOOSE, NESTED);
}
<SPECIAL>\({WS}({NT0}?:)?gather/{ID_END} {
return directive_tok(yyg, GATHER, NESTED);
}
<SPECIAL>\({WS}({NT0}?:)?and{WS}\) {
return directive_tok(yyg, AND, 0);
}
<SPECIAL>\({WS}({NT0}?:)?or{WS}\) {
return directive_tok(yyg, OR, 0);
}
<SPECIAL>\({WS}({NT0}?:)?end{WS}\) {
return directive_tok(yyg, END, 0);
}
<SPECIAL>\({WS}({NT0}?:)?collect/{ID_END} {
return directive_tok(yyg, COLLECT, NESTED);
}
<SPECIAL>\({WS}({NT0}?:)?coll/{ID_END} {
return directive_tok(yyg, COLL, NESTED);
}
<SPECIAL>\({WS}({NT0}?:)?until/{ID_END} {
return directive_tok(yyg, UNTIL, NESTED);
}
<SPECIAL>\({WS}({NT0}?:)?output/{ID_END} {
return directive_tok(yyg, OUTPUT, NESTED);
}
<SPECIAL>\({WS}({NT0}?:)?repeat/{ID_END} {
return directive_tok(yyg, REPEAT, NESTED);
}
<SPECIAL>\({WS}({NT0}?:)?push/{ID_END} {
return directive_tok(yyg, PUSH, NESTED);
}
<SPECIAL>\({WS}({NT0}?:)?rep/{ID_END} {
return directive_tok(yyg, REP, NESTED);
}
<SPECIAL>\({WS}({NT0}?:)?single{WS}\) {
return directive_tok(yyg, SINGLE, 0);
}
<SPECIAL>\({WS}({NT0}?:)?first{WS}\) {
return directive_tok(yyg, FIRST, 0);
}
<SPECIAL>\({WS}({NT0}?:)?last/{ID_END} {
return directive_tok(yyg, LAST, NESTED);
}
<SPECIAL>\({WS}({NT0}?:)?empty{WS}\) {
return directive_tok(yyg, EMPTY, 0);
}
<SPECIAL>\({WS}({NT0}?:)?mod/{ID_END} {
return directive_tok(yyg, MOD, NESTED);
}
<SPECIAL>\({WS}({NT0}?:)?modlast/{ID_END} {
return directive_tok(yyg, MODLAST, NESTED);
}
<SPECIAL>\({WS}({NT0}?:)?define/{ID_END} {
return directive_tok(yyg, DEFINE, NESTED);
}
<SPECIAL>\({WS}({NT0}?:)?try{WS}\) {
return directive_tok(yyg, TRY, 0);
}
<SPECIAL>\({WS}({NT0}?:)?catch/{ID_END} {
return directive_tok(yyg, CATCH, NESTED);
}
<SPECIAL>\({WS}({NT0}?:)?finally{WS}\) {
return directive_tok(yyg, FINALLY, 0);
}
<SPECIAL>\({WS}({NT0}?:)?if/{ID_END} {
return directive_tok(yyg, IF, NESTED);
}
<SPECIAL>\({WS}({NT0}?:)?elif/{ID_END} {
return directive_tok(yyg, ELIF, NESTED);
}
<SPECIAL>\({WS}({NT0}?:)?else{WS}\) {
return directive_tok(yyg, ELSE, 0);
}
<SPECIAL,QSPECIAL>[{] {
yy_push_state(BRACED, yyscanner);
yylval->lineno = yyextra->lineno;
return yytext[0];
}
<SPECIAL,QSPECIAL,NESTED,BRACED>[(\[] {
yy_push_state(NESTED, yyscanner);
yylval->lineno = yyextra->lineno;
return yytext[0];
}
<NESTED,BRACED,QSPECIAL>@ {
yylval->lineno = yyextra->lineno;
return (opt_compat && opt_compat <= 248) ? OLD_AT : '@';
}
<NESTED,QSPECIAL,BRACED>,[*] {
yylval->chr = '*';
return SPLICE;
}
<QSPECIAL,NESTED,BRACED>[,'^] {
yylval->chr = yytext[0];
return yytext[0];
}
<BRACED>[}] {
yy_pop_state(yyscanner);
if (yy_top_state(yyscanner) == INITIAL
|| yy_top_state(yyscanner) == QSILIT
|| yy_top_state(yyscanner) == QWLIT)
yy_pop_state(yyscanner);
return yytext[0];
}
<SPECIAL,QSPECIAL,NESTED>[)\]]/{DOTFLO} {
yyerrorf(yyg, lit("cramped floating-point literal: "
"space or 0 needed between ~a and dot."),
string_own(utf8_dup_from(yytext)),
nao);
yy_pop_state(yyscanner);
if (yy_top_state(yyscanner) == INITIAL
|| yy_top_state(yyscanner) == QSILIT
|| yy_top_state(yyscanner) == QWLIT)
yy_pop_state(yyscanner);
return yytext[0];
}
<SPECIAL,QSPECIAL,NESTED>[)\]}] {
yy_pop_state(yyscanner);
if (yy_top_state(yyscanner) == INITIAL
|| yy_top_state(yyscanner) == QSILIT
|| yy_top_state(yyscanner) == QWLIT)
yy_pop_state(yyscanner);
return yytext[0];
}
<SPECIAL,QSPECIAL,NESTED,BRACED>{WS} {
/* Eat whitespace in directive */
}
<SPECIAL,QSPECIAL,NESTED,BRACED>\" {
yy_push_state(STRLIT, yyscanner);
return '"';
}
<SPECIAL,QSPECIAL,NESTED,BRACED>#\\ {
yy_push_state(CHRLIT, yyscanner);
yylval->lineno = yyextra->lineno;
return HASH_BACKSLASH;
}
<SPECIAL,QSPECIAL,NESTED,BRACED>#b' {
yy_push_state(BUFLIT, yyscanner);
yylval->lineno = yyextra->lineno;
return HASH_B_QUOTE;
}
<SPECIAL,QSPECIAL,NESTED,BRACED>#[/] {
yy_push_state(REGEX, yyscanner);
yylval->lineno = yyextra->lineno;
return HASH_SLASH;
}
<SPECIAL,QSPECIAL,NESTED,BRACED>` {
yy_push_state(QSILIT, yyscanner);
return '`';
}
<SPECIAL,QSPECIAL,NESTED,BRACED>#\" {
yy_push_state(WLIT, yyscanner);
yylval->lineno = yyextra->lineno;
return WORDS;
}
<SPECIAL,QSPECIAL,NESTED,BRACED>#\*\" {
yy_push_state(WLIT, yyscanner);
yylval->lineno = yyextra->lineno;
return WSPLICE;
}
<SPECIAL,QSPECIAL,NESTED,BRACED>#\` {
yy_push_state(QWLIT, yyscanner);
yylval->lineno = yyextra->lineno;
return QWORDS;
}
<SPECIAL,QSPECIAL,NESTED,BRACED>#\*\` {
yy_push_state(QWLIT, yyscanner);
yylval->lineno = yyextra->lineno;
return QWSPLICE;
}
<NESTED,BRACED># {
return '#';
}
<NESTED,BRACED>#H {
yylval->lineno = yyextra->lineno;
return HASH_H;
}
<NESTED,BRACED>#S {
yylval->lineno = yyextra->lineno;
return HASH_S;
}
<NESTED,BRACED>#R {
yylval->lineno = yyextra->lineno;
return HASH_R;
}
<NESTED,BRACED>#N {
yylval->lineno = yyextra->lineno;
return HASH_N;
}
<NESTED,BRACED>#T {
yylval->lineno = yyextra->lineno;
return HASH_T;
}
<NESTED,BRACED>#J {
yylval->lineno = yyextra->lineno;
yy_push_state(JSON, yyscanner);
return HASH_J;
}
<NESTED,BRACED>#; {
yylval->lineno = yyextra->lineno;
return HASH_SEMI;
}
<NESTED,BRACED,JSON>#{DIG}+= {
wchar_t *wtxt = utf8_dup_from(yytext + 1);
yylval->val = int_str_wc(wtxt, num(10));
free(wtxt);
return HASH_N_EQUALS;
}
<NESTED,BRACED,JSON>#{DIG}+# {
wchar_t *wtxt = utf8_dup_from(yytext + 1);
yylval->val = int_str_wc(wtxt, num(10));
free(wtxt);
return HASH_N_HASH;
}
<NESTED>{WS}\.\. {
yylval->lineno = yyextra->lineno;
return (opt_compat && opt_compat <= 185) ? OLD_DOTDOT : DOTDOT;
}
<SPECIAL>@ {
yy_pop_state(yyscanner);
yylval->lexeme = chk_strdup(L"@");
return TEXT;
}
<SPECIAL,QSPECIAL,NESTED,BRACED>{NL} {
yyextra->lineno++;
}
<SPECIAL,BRACED>[/] {
yy_push_state(REGEX, yyscanner);
return '/';
}
<SPECIAL,QSPECIAL,NESTED>{REQWS}\.{REQWS} {
yylval->chr = '.';
return CONSDOT;
}
<SPECIAL,QSPECIAL,NESTED>\.{REQWS} {
yylval->chr = '.';
return LAMBDOT;
}
<SPECIAL,QSPECIAL,NESTED,BRACED>{REQWS}\. {
yylval->chr = '.';
return UREFDOT;
}
<SPECIAL,QSPECIAL,NESTED,BRACED>\. {
yylval->chr = '.';
return '.';
}
<SPECIAL,QSPECIAL,NESTED>\.\? {
yylval->chr = '.';
return OREFDOT;
}
<SPECIAL,QSPECIAL,NESTED,BRACED>{REQWS}\.\? {
yylval->chr = '.';
return UOREFDOT;
}
<SPECIAL,QSPECIAL,NESTED,BRACED>[\\]{NL}{WS} {
if (YYSTATE == SPECIAL)
yy_pop_state(yyscanner); /* @\ continuation */
yyextra->lineno++;
}
<SPECIAL>[\\][abtnvfre ] {
wchar_t lexeme[2];
lexeme[0] = char_esc(yytext[1]);
lexeme[1] = 0;
yylval->lexeme = chk_strdup(lexeme);
yy_pop_state(yyscanner);
return TEXT;
}
<SPECIAL>[\\](x{HEX}+|{OCT}+);? {
wchar_t lexeme[2];
lexeme[0] = num_esc(yyg, yytext + 1);
lexeme[1] = 0;
yylval->lexeme = chk_strdup(lexeme);
{
char lastchar = yytext[yyleng-1];
if (lastchar == ';' && opt_compat && opt_compat <= 109)
unput(lastchar);
}
yy_pop_state(yyscanner);
return TEXT;
}
<SPECIAL>[\\]x {
yyerrorf(yyg, lit("\\x escape without digits"), nao);
}
<SPECIAL>[\\]. {
yyerrorf(yyg, lit("unrecognized escape \\~a"), chr(yytext[1]), nao);
}
<SPECIAL,QSPECIAL,NESTED,BRACED,JSON>[;][^\n\r]* {
/* comment */
}
<SPECIAL,QSPECIAL,NESTED,BRACED>{UANYN} {
val ch = chr_str(string_utf8(yytext), zero);
if (chr_isspace(ch))
yyerrprepf(yyg, lit("unexpected whitespace character #\\x~,02x"),
ch, nao);
else if (chr_isunisp(ch))
yyerrprepf(yyg, lit("unexpected Unicode space character #\\x~,02x"),
ch, nao);
else if (chr_iscntrl(ch))
yyerrprepf(yyg, lit("unexpected control character #\\x~,02x"),
ch, nao);
else
yyerrprepf(yyg, lit("unexpected character #\\~a"),
ch, nao);
return ERRTOK;
}
<SPECIAL,QSPECIAL,NESTED,BRACED>. {
yyerrprepf(yyg, lit("non-UTF-8 byte #x~02x in directive"),
num(convert(unsigned char, yytext[0])), nao);
return ERRTOK;
}
<REGEX,SREGEX>[/] {
yylval->chr = '/';
return (YYSTATE == SREGEX) ? REGCHAR : '/';
}
<REGEX,SREGEX>[\\][abtnvfre\\ ] {
yylval->chr = char_esc(yytext[1]);
return REGCHAR;
}
<REGEX,SREGEX>[\\](x{HEX}+|{OCT}+);? {
yylval->chr = num_esc(yyg, yytext + 1);
return REGCHAR;
}
<REGEX,SREGEX>[\\][sSdDwW] {
yylval->chr = yytext[1];
return REGTOKEN;
}
<REGEX,SREGEX>{WS}[\\]{NL}{WS} {
yyextra->lineno++;
}
<REGEX>{NL} {
yyextra->lineno++;
yyerrprepf(yyg, lit("newline in regex"), nao);
return ERRTOK;
}
<SREGEX>{NL} {
yyextra->lineno++;
yylval->chr = yytext[0];
return REGCHAR;
}
<REGEX,SREGEX>{REGOP} {
yylval->chr = yytext[0];
return yytext[0];
}
<REGEX,SREGEX>[\\]{REGOP} {
yylval->chr = yytext[1];
return REGCHAR;