-
Notifications
You must be signed in to change notification settings - Fork 4
/
flake.nix
148 lines (143 loc) · 4.8 KB
/
flake.nix
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
{
inputs = {
nixpkgs.url = "github:nixos/nixpkgs/nixpkgs-unstable";
flake-parts.url = "github:hercules-ci/flake-parts";
systems.url = "github:nix-systems/default";
flocken = {
url = "github:mirkolenz/flocken/v2";
inputs.nixpkgs.follows = "nixpkgs";
};
poetry2nix = {
url = "github:nix-community/poetry2nix";
inputs.nixpkgs.follows = "nixpkgs";
};
};
outputs =
inputs@{
self,
nixpkgs,
flake-parts,
systems,
flocken,
poetry2nix,
...
}:
flake-parts.lib.mkFlake { inherit inputs; } {
systems = import systems;
imports = [ inputs.flake-parts.flakeModules.easyOverlay ];
perSystem =
{
pkgs,
system,
lib,
self',
...
}:
let
python = pkgs.python311;
poetry = pkgs.poetry;
poetryAppArgs = {
inherit python;
projectDir = ./.;
preferWheels = true;
meta = {
mainProgram = "makejinja";
maintainers = with lib.maintainers; [ mirkolenz ];
license = lib.licenses.mit;
homepage = "https://github.com/mirkolenz/makejinja";
description = "Generate entire directory structures using Jinja templates with support for external data and custom plugins.";
platforms = lib.platforms.darwin ++ lib.platforms.linux;
};
};
in
{
_module.args.pkgs = import nixpkgs {
inherit system;
overlays = [ poetry2nix.overlays.default ];
};
overlayAttrs = {
inherit (self'.packages) makejinja;
};
checks = {
inherit (self'.packages) makejinja;
};
packages = {
default = pkgs.poetry2nix.mkPoetryApplication (poetryAppArgs // { checkPhase = "pytest"; });
makejinja = self'.packages.default;
docker = pkgs.dockerTools.buildLayeredImage {
name = "makejinja";
tag = "latest";
created = "now";
config = {
entrypoint = [ (lib.getExe self'.packages.default) ];
cmd = [ ];
};
};
releaseEnv = pkgs.buildEnv {
name = "release-env";
paths = [
poetry
python
];
};
docs =
let
app = pkgs.poetry2nix.mkPoetryApplication (poetryAppArgs // { groups = [ "docs" ]; });
env = app.dependencyEnv;
font = pkgs.jetbrains-mono;
in
pkgs.stdenv.mkDerivation {
name = "makejinja-docs";
src = ./.;
buildPhase = ''
mkdir -p "$out"
{
echo '```txt'
COLUMNS=120 ${lib.getExe app} --help
echo '```'
} > ./manpage.md
# remove everything before the first ---
# ${lib.getExe pkgs.gnused} -i '1,/^---$/d' ./README.md
# remove everything before the first header
${lib.getExe pkgs.gnused} -i '1,/^# /d' ./README.md
${lib.getExe pkgs.asciinema-scenario} ./assets/demo.scenario > ./assets/demo.cast
${lib.getExe pkgs.asciinema-agg} \
--font-dir "${font}/share/fonts/truetype" \
--font-family "JetBrains Mono" \
--theme monokai \
./assets/demo.cast ./assets/demo.gif
${lib.getExe' env "pdoc"} -d google -t pdoc-template --math \
--logo https://github.com/raw/mirkolenz/makejinja/main/assets/logo.png \
-o "$out" ./makejinja
mkdir "$out/assets"
cp -rf ./assets/{*.png,*.gif} "$out/assets/"
'';
dontInstall = true;
};
};
legacyPackages.dockerManifest = flocken.legacyPackages.${system}.mkDockerManifest {
github = {
enable = true;
token = "$GH_TOKEN";
};
version = builtins.getEnv "VERSION";
images = with self.packages; [
x86_64-linux.docker
aarch64-linux.docker
];
};
devShells.default = pkgs.mkShell {
packages = [
poetry
python
pkgs.vhs
];
POETRY_VIRTUALENVS_IN_PROJECT = true;
shellHook = ''
${lib.getExe poetry} env use ${lib.getExe python}
${lib.getExe poetry} install --sync --all-extras --no-root
'';
};
};
};
}