r for replacing char in normal mode

[anhsirk0]

How do you guys replace single character in normal mode?

I hacked together this little code.

(defun replace-char ()
  (interactive)
  (setq mychar (read-char))
  ;; 27 is escape key
  (if (= 27 mychar)
      (message "Cancelled replace")
    (delete-char 1)
    (insert mychar)
    )
  )

(defun replace-char-or-meow-replace ()
  (interactive)
  ;; if there is selection run meow-replace else replace-char
  (if (use-region-p)
      (meow-replace)
    (replace-char)
    ))

;; meow config
   '("r" . replace-char-or-meow-replace)
;; meow config

Any improvement is highly appreciated.

[eshrh]

I believe you are looking for meow-change. If there is no selection, delete one character and enter insert mode. If there is a selection, delete it and enter insert mode.

The semantics are slightly different. In meow, the word replace tends to mean "replace text with yank (clipboard)", whereas the word change tends to mean "delete text and enter insert mode" similarly to vim

So, your replace-char-or-meow-replace is actually doing 2 different things in each case. If there is a region, it'll call meow-replace in which case it'll be replaced with whatever is in your clipboard (some nuance to emacs clipboards and kill rings). With no region, it calls your replace-char function which is similar to meow-change.

If you're looking to "replace" (meow definition) exactly one char, you can use the function meow-replace-char.

PS: in most lisp dialects, we typically put the closing parenthesis on the last line.

[anhsirk0]

I was going for functionality like in kakoune/vim with r
meow-replace-char replaces char with kill-ring content, not what i was looking for.

PS: in most lisp dialects, we typically put the closing parenthesis on the last line.
I don't know what you mean by this, I've never programmed in lisp.

[eshrh]

Yeah, so the closest built in would be meow-change-char to that. If you like the vi behavior of asking your for your replacement beforehand and returning you to normal mode after the edit, then I think your code is just fine.

I mean that you shouldn't have closing parenthesis on their own line, they should be on the last line with a complete s-expression (pair of parentheses with zero+ symbols inside). See the end of this

Read char takes a prompt, good for usability.

If you use setq like you did, then this creates a global variable that lives on after the function is over, unlike in properly scoped languages you might be familiar with. Use let instead (can be expressed as a macro in lisp), the variable will exist only inside the let s-exp.

Last change I'd make is to replace the hardcoded char code with read syntax. Note that escape in emacs is C-[.

(defun replace-char ()
  (interactive)
  (let ((mychar (read-char "replace with:")))
    (if (= ?\C-\[ mychar)
        (message "Cancelled replace")
      (delete-char 1)
      (insert mychar))))

(defun replace-char-or-meow-replace ()
  (interactive)
  (if (use-region-p)
      (meow-change)
    (replace-char)))

[anhsirk0]

Thanks a lot.