-
Notifications
You must be signed in to change notification settings - Fork 0
/
rand.ijs
948 lines (894 loc) · 30.3 KB
/
rand.ijs
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
NB. Random arrays
NB.
NB. trxxmat Adv. to make verb to make random square
NB. triangular matrix
NB. kmsmat Adv. to make monad to make random
NB. Kac-Murdock-Szego (KMS) matrix
NB. gemat Make random real array
NB. dimat Conj. to make monad to make random
NB. diagonalizable matrix
NB. hemat Adv. to make monad to make random Hermitian
NB. (symmetric) matrix
NB. pomat Adv. to make monad to make random Hermitian
NB. (symmetric) positive definite matrix
NB. ptmatx Adv. to make monad to make random Hermitian
NB. (symmetric) positive definite tridiagonal
NB. matrix
NB. unmat Adv. to make monad to make random unitary
NB. (orthogonal) matrix
NB. spmat Conj. to make monad to make random sparse
NB. array
NB.
NB. testtrmat Test trxxmat by matrix size given
NB. testgemat Test gemat by matrix shape given
NB. testdimat Test dimat by matrix size given
NB. testhemat Test hemat by matrix size given
NB. testpomat Test pomat by matrix size given
NB. testptmat Test ptmatx by matrix size given
NB. testunmat Test unmat by matrix size given
NB. testspmat Test spmat by matrix shape given
NB. testrand Test xxxxmatx by matrix shape given
NB.
NB. Copyright 2010,2011,2013,2017,2018,2020,2021,2023,2024
NB. Igor Zhuravlov
NB.
NB. This file is part of mt
NB.
NB. mt is free software: you can redistribute it and/or
NB. modify it under the terms of the GNU Lesser General
NB. Public License as published by the Free Software
NB. Foundation, either version 3 of the License, or (at your
NB. option) any later version.
NB.
NB. mt is distributed in the hope that it will be useful, but
NB. WITHOUT ANY WARRANTY; without even the implied warranty
NB. of MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
NB. See the GNU Lesser General Public License for more
NB. details.
NB.
NB. You should have received a copy of the GNU Lesser General
NB. Public License along with mt. If not, see
NB. <http://www.gnu.org/licenses/>.
NB. =========================================================
NB. Configuration
coclass 'mt'
NB. =========================================================
NB. Local definitions
NB. ---------------------------------------------------------
NB. randu
NB.
NB. Description:
NB. Uniform distribution U(a,b) with support (a,b)
NB.
NB. Syntax:
NB. S=. [supp] randu sh
NB. where
NB. sh - rnk-vector of non-negative integers, the shape
NB. of S
NB. supp - optional 2-vector (a,b), a<b, support of
NB. distribution, open interval, default is (0 1)
NB. S - sh-array of values s ~ U(a,b)
NB. rnk ≥ 0, the rank of S
NB.
NB. Formula:
NB. s ← a + (b-a)*u
NB. where
NB. u ~ U(0,1)
NB. s ~ U(a,b)
NB.
NB. Application:
NB. - verb to model LAPACK's DLARNV(2)
NB. x ~ U(-1,1)
NB. NB. x=. dlarnv2 n
NB. dlarnv2=: _1 1&randu
NB. - verb to model LAPACK's ZLARNV(1)
NB. Re(x) ~ U(0,1), Im(x) ~ U(0,1)
NB. NB. x=. zlarnv1 n
NB. zlarnv1=: randu j. randu
NB. - verb to model LAPACK's ZLARNV(2)
NB. Re(x) ~ U(-1,1), Im(x) ~ U(-1,1)
NB. NB. x=. zlarnv2 n
NB. zlarnv2=: _1 1&(randu j. randu)
NB. - verb to model LAPACK's ZLARNV(4)
NB. x ~ U(|x| < 1) [1, pg.236]
NB. NB. x=. zlarnv4 n
NB. zlarnv4=: %:@randu r. 0 2p1&randu
NB. - verb to model LAPACK's ZLARNV(5)
NB. x ~ U(|x| = 1)
NB. NB. x=. zlarnv5 n
NB. zlarnv5=: r.@(0 2p1&randu)
NB.
NB. Notes:
NB. - for rnk=1 models LAPACK's DLARNV(1)
NB.
NB. References:
NB. [1] Non-Uniform Random Variate Generation. Luc Devroye,
NB. 2003. School of Computer Science, McGill University.
NB. http://luc.devroye.org/rnbookindex.html
randu=: (?@$&0) :((p.~ -~/\)~ $:)
NB. ---------------------------------------------------------
NB. rande
NB.
NB. Description:
NB. Exponential distribution E(μ) with mean μ
NB.
NB. Syntax:
NB. S=. [μ] rande sh
NB. where
NB. sh - vector of non-negative integers, the shape of S
NB. μ > 0, optional mean, default is 1
NB. S - sh-array of values s ~ E(μ)
NB.
NB. Formula:
NB. s ← -μ*log(1-u)
NB. where
NB. u ~ U(0,1)
NB. s ~ E(μ)
NB.
NB. Application:
NB. - verb to make complex matrix S with elements s having:
NB. Re(s) ~ E(1)
NB. Im(s) ~ E(2)
NB. :
NB. exprand=: rande j. 2&rande
NB.
NB. Notes:
NB. - randu is used instead of (1-randu) since they are
NB. equivalent under following assumptions:
NB. - randu's support is open interval (0,1)
NB. - randu's values aren't used outside elsewhere
rande=: -@^.@randu : (* $:)
NB. ---------------------------------------------------------
NB. randnr
NB. randnc
NB. randnq
NB.
NB. Description:
NB. Normal distribution N(μ,σ^2) with mean μ and variance
NB. σ^2
NB.
NB. Syntax:
NB. R=. [par] randnr sh
NB. C=. [par] randnc sh
NB. Q=. [par] randnq sh
NB. where
NB. sh - rnk-vector of non-negative integers, the shape of
NB. R, C and Q
NB. par - optional 2-vector (μ,σ), σ>0, parameters of
NB. distribution, default is (0 1)
NB. R - sh-array of real values r ~ N(μ,σ^2)
NB. C - sh-array of complex values c ~ N(μ,σ^2)
NB. Q - sh-array of quaternion values q ~ N(μ,σ^2)
NB. represented as (sh,2)-array of complex numbers
NB. rnk ≥ 0, the rank of R, C and Q
NB.
NB. Formula:
NB. nr1r ← sqrt(e1)*cos(u1) NB. see...
NB. nr1i ← sqrt(e1)*sin(u1) NB. ...[1]
NB. nr2r ← sqrt(e2)*cos(u2)
NB. nr2i ← sqrt(e2)*sin(u2)
NB. nc1 ← (nr1r + i*nr1i)/sqrt(2) NB. see [2]
NB. nc2 ← (nr2r + i*nr2i)/sqrt(2)
NB. nq ← (nc1 + j*nc2 )/sqrt(2) NB. see [3]
NB. n3 ← σ*nxxx + μ
NB. where
NB. u1,u2 ~ U(0,2*π)
NB. e1,e2 ~ E(2)
NB. nr1r,nr1i,nr2r,nr2i,nc1,nc2,nq ~ N(0,1)
NB. n3 ~ N(μ,σ^2)
NB.
NB. Algorithm for monadic randnr:
NB. In: sh
NB. Out: R
NB. 0) calc ceiled half of elements quantity in R:
NB. n := ⌈Π{sh[i],i=0:rnk-1}/2⌉
NB. 1) make random complex n-vector with elements
NB. having real and imagine parts both independently
NB. distributed normally:
NB. Re(v[i]) := nr1r[i], i=0:n-1
NB. Im(v[i]) := nr1i[i], i=0:n-1
NB. 2) form n×2-array with separated real and imagine
NB. parts:
NB. R[i,0] := Re(v[i])
NB. R[i,1] := Im(v[i])
NB. 3) re-shape R to shape sh (special code is involved):
NB. R=. sh ($,) R
NB.
NB. Application:
NB. - verb to make real matrix R with elements r having:
NB. r ~ N(1,3^2)
NB. :
NB. normrand=: 1 3&randnr
NB. - verb to make complex matrix C with elements c having:
NB. c ~ N(4+i*5,3^2)
NB. :
NB. normrand=: 4j5 3&randnc
NB. - verb to make quaternion matrix Q with elements q
NB. having:
NB. q ~ N(4+i*5+j*6+k*7,3^2)
NB. :
NB. normrand=: (4j5 6j7 3)&randnq
NB. - verb to model LAPACK's ZLARNV(3)
NB. Re(x) ~ N(0,1), Im(x) ~ N(0,1)
NB. NB. x=. zlarnv5 n
NB. zlarnv5=: randnr j. randnr
NB.
NB. Notes:
NB. - randnr requests only ⌈Π{sh[:]}/2⌉ numbers from RNG
NB. - for rnk=1 randnr models LAPACK's DLARNV(3)
NB. - randnc generates C-gaussian complex numbers [3]
NB. - randnq generates Q-gaussian quaternion numbers [3]
NB.
NB. References:
NB. [1] G. E. P. Box, Mervin E. Muller. A Note on the
NB. Generation of Random Normal Deviates. The Annals of
NB. Mathematical Statistics, 1958, Vol. 29, No. 2, pp.
NB. 610-611.
NB. [2] D. R. Brillinger. Time series. Data analysis and
NB. theory. The University of California, Berkeley, 1975
NB. (Д. Бриллинджер. Временные ряды. Обработка данных и
NB. теория. Изд-во "Мир". М. 1980, стр. 98).
NB. [3] N. N. Vakhania, "Random vectors with values in
NB. quaternion Hilbert spaces", Theory of Probability &
NB. Its Applications, 1999, Vol. 43, No. 1 : pp. 99-115
NB. https://doi.org/10.1137/S0040585X97976696
NB. (Н. Н. Вахания, "Случайные векторы со значениями в
NB. кватернионных гильбертовых пространствах", Теория
NB. вероятн. и ее примен., 43:1 (1998), 18-40
NB. https://doi.org/10.4213/tvp821 )
randnr=: (($,) +.@:(%:@(2 &rande) r. 0 2p1&randu)@>.@-:@(*/)) : (p. $:)
randnc=: (%:@ rande r. 0 2p1&randu) : (p. $:)
randnq=: (%:@(0.5&rande) r. 0 2p1&randu)@(,&2) : (((* {:)~ (+"1 }:) [) $:)
NB. ---------------------------------------------------------
NB. randtnr
NB.
NB. Description:
NB. Truncated normal distribution TN(μ,σ^2,a,b) of real
NB. numbers in range [a,b] with mean μ and variance σ^2
NB.
NB. Syntax:
NB. R=. [par] randtnr sh
NB. where
NB. sh - vector of non-negative integers, the shape of R
NB. par - optional 4-vector (μ,σ,a,b), σ>0, a≤b, (μ,σ) are
NB. normal distribution parameters, [a,b] is range,
NB. default is (0 1 -∞ +∞)
NB. R - sh-array of values r ~ N(μ,σ^2), a ≤ r ≤ b
NB.
NB. Application:
NB. - verb to make complex matrix R with elements r having
NB. left-side truncated normal distribution:
NB. r ~ TN(1,3^2,4,+∞)
NB. :
NB. tnormrand=: 1 3 4 _&randtnr
randtnr=: 0 1 __ _&$: :(4 : 0)
'mu sigma a b'=. x
mrandnr=. (mu,sigma)&randnr
NB. replace out-bounded elements recursively
rober=. I.@(a&> +. b&<) $:@mrandnr@#@[`[`]}^:(0 < #@[) ]
($ rober@mrandnr@(*/)) y
)
NB. ---------------------------------------------------------
NB. kmsmatrho
NB.
NB. Description:
NB. Adv. to make nilad to generate rho parameter for
NB. rho-parametrized KMS matrix K(rho)
NB.
NB. Syntax:
NB. rho=. (randx kmsmatrho) any_noun
NB. where
NB. randx - monad to generate random numbers; is called as:
NB. A=. randx sh
NB. sh - size or shape of A
NB.
NB. Notes:
NB. - randx is used to acquire datatype only
NB. - datatypes supported: floating, complex
kmsmat121=: 1 : '{.@u@1'
kmsmatrho=: 1 : '((0.5 1&randu_mt_ r. 0 2p1&randu_mt_) kmsmat121_mt_)`(0.5 1&randu_mt_ kmsmat121_mt_)@.(0 -: 11&o.)@(u kmsmat121_mt_)'
NB. =========================================================
NB. Interface
NB. ---------------------------------------------------------
NB. Verb Syntax
NB. trl1mat L1=. (randx trl1mat) sh
NB. trlmat L=. (randx trlmat ) sh
NB. tru1mat U1=. (randx tru1mat) sh
NB. trumat U=. (randx trumat ) sh
NB.
NB. Description:
NB. Adv. to make monad to make random square triangular
NB. matrix
NB. where
NB. randx - monad to make random y-array; is called as:
NB. A=. randx y
NB. sh - size or shape, which is either n or
NB. (n,any_number)
NB. L1 - n×n-matrix, random unit lower triangular
NB. L - n×n-matrix, random lower triangular
NB. U1 - n×n-matrix, random unit upper triangular
NB. U - n×n-matrix, random upper triangular
NB.
NB. Algorithm for basic adverb trlmat:
NB. In: n randx
NB. Out: L
NB. 0) count non-zero elements in lower triangle:
NB. ne := n*(n+1)/2
NB. 1) make random ne-vector:
NB. ve=. randx ne
NB. 2) prepare fret:
NB. 2.0) make zero ne-vector:
NB. f=. ne $ 0
NB. 2.1) make lISO for start of an interval marks:
NB. liso=. +/\ i. ne
NB. 2.2) write in marks:
NB. f=. 1 liso} f
NB. 3) cut ve on pieces of length (1 2 3 ... n) and stack
NB. them into lower triangular matrix:
NB. L=. f ];.1 ve
NB.
NB. Application:
NB. - make real lower triangular 4×4-matrix L with elements l
NB. having:
NB. mantissa(l) ~ U(-1,1)
NB. exponent(l) ~ TN(0,3^2,-6,4)
NB. :
NB. L=. _1 1 0 3 _6 4&gemat trlmat 4 4
NB. - make complex lower triangular 4×4-matrix L with
NB. elements l having:
NB. mantissa(Re(l)),mantissa(Im(l)) ~ U(-1,1)
NB. exponent(Re(l)),exponent(Im(l)) ~ TN(0,3^2,-6,4)
NB. :
NB. L=. _1 1 0 3 _6 4&(gemat j. gemat) trlmat 4
NB. - make complex lower triangular 4×4-matrix L with
NB. elements l having:
NB. mantissa(Re(l)) ~ U(0,1)
NB. exponent(Re(l)) ~ TN(0,1,-∞,+∞)
NB. mantissa(Im(l)) ~ U(-1,1)
NB. exponent(Im(l)) ~ TN(0,3^2,-6,4)
NB. :
NB. L=. ((0 1 0 1 , FP_EMIN , FP_EMAX)&gemat j. _1 1 0 3 _6 4&gemat) trlmat 4
NB.
NB. Notes:
NB. - only n*(n+1)/2 numbers from RNG are requested
NB.
NB. TODO:
NB. - fret would be sparse
trlmat=: 1 : '1&([`(+/\@i.@{.@])`(0 $~ -:@(* >:)@{.@])}) ];.1 u@-:@(* >:)@{.'
trl1mat=: 1 : '(1;a:)&setdiag_mt_@(u trlmat_mt_)'
trumat=: 1 : '|:@(u trlmat_mt_)'
tru1mat=: 1 : '|:@(u trl1mat_mt_)'
NB. ---------------------------------------------------------
NB. kmsmat
NB.
NB. Description:
NB. Adv. to make monad to make random Kac-Murdock-Szego
NB. (KMS) matrix [1].
NB.
NB. Syntax:
NB. K=. (randx kmsmat) sh
NB. where
NB. randx - nilad to make rho; is called as:
NB. rho=. randx any_noun
NB. sh - size or shape, which is either n or
NB. (n,any_number)
NB. rho - scalar number, the KMS matrix parameter
NB. K - n×n-matrix, random KMS matrix
NB.
NB. Notes:
NB. - KMS matrix is defined as:
NB. K ≡ K(rho,i,j) := { rho ^(j-i), i ≤ j
NB. { conj(rho)^(i-j), i > j
NB. - KMS matrix is Toeplitz
NB. KMS matrix is symmetric for real rho and is Hermitian
NB. for complex rho
NB. - a factorization:
NB. L1 * D * L1^H = K
NB. exists for KMS matrix, where
NB. L1 - unit lower triangular matrix
NB. D - diagonal matrix
NB. - KMS matrix is positive definite iif:
NB. 0 < abs(rho) < 1
NB. and is well conditioned for large n (>400) if:
NB. 0.5 < abs(rho) < 1
NB. - K^_1 is tridiagonal
NB.
NB. Assertions (with appropriate comparison tolerance):
NB. K -: D (] mp (mp ct)) L1 NB. verify factorization: L1 * D * L1^H = K
NB. K -: (mp ct) L NB. K is positive definite, i.e. Cholesky factorization exists
NB. iK -: gtpick iK NB. K^_1 is tridiagonal
NB. where
NB. n=. 7 NB. matrix size, any
NB. rho=. 0.5j0.5 NB. matrix parameter, any, adhere (0 < abs(rho) < 1) to force K to be positive definite
NB. mkrho=. rho"_ NB. we must know rho value a priori to define L1 and D
NB. K=. mkrho kmsmat n
NB. L1=. trl1pick %. ((+ - rho) ; _1) setdiag idmat n
NB. D=. diagmat (1) 0} n $ 1 - *: | rho
NB. L=. potrfl K NB. try Cholesky factorization: L * L^H = K
NB. iK=. %. K
NB.
NB. Application:
NB. - make random real positive definite KMS 4×4-matrix:
NB. K=. {.@randu@1 kmsmat 4 4
NB. - make random complex positive definite KMS 4×4-matrix:
NB. K=. {.@(randu r. 0 2p1&randu)@1 kmsmat 4
NB.
NB. References:
NB. [1] W.F. Trench, "Numerical solution of the eigenvalue
NB. problem for Hermitian Toeplitz matrices", SIAM J.
NB. Matrix Analysis and Appl., 10 (1989), pp. 135-146.
kmsmat=: 1 : 'he4gel_mt_@(+@u ^ -/~@i.@{.)'
NB. ---------------------------------------------------------
NB. gemat
NB.
NB. Description:
NB. Make random real array
NB.
NB. Syntax:
NB. G=. [par] gemat sh
NB. where
NB. sh - vector of non-negative integers, the shape of G
NB. par - optional 6-vector (ma,mb,μ,σ,ea,eb), σ>0, where
NB. (ma,mb) are mantissa's uniform distribution
NB. parameters, and (μ,σ,ea,eb) are exponent's
NB. truncated normal distribution parameters, default
NB. is: (-1 1 0 (FP_FLEN/2) FP_EMIN FP_EMAX)
NB. G - sh-array, random
NB.
NB. Formula:
NB. g ← mantissa * 2 ^ exponent
NB. where
NB. mantissa ~ U(ma,mb)
NB. exponent ~ TN(μ,σ,ea,eb)
NB.
NB. Application:
NB. - make real 4×4-matrix G with elements g having:
NB. mantissa(g) ~ U(-1,1)
NB. exponent(g) ~ TN(0,3^2,-6,4)
NB. :
NB. G=. _1 1 0 3 _6 4 gemat 4 4
NB. - make complex 4×4-matrix G with elements g having:
NB. mantissa(Re(g)),mantissa(Im(g)) ~ U(-1,1)
NB. exponent(Re(g)),exponent(Im(g)) ~ TN(0,3^2,-6,4)
NB. :
NB. G=. _1 1 0 3 _6 4 (gemat j. gemat) 4 4
NB. - make complex 4×4-matrix G with elements g having:
NB. mantissa(Re(g)) ~ U(0,1)
NB. exponent(Re(g)) ~ TN(0,1,-∞,+∞)
NB. mantissa(Im(g)) ~ U(-1,1)
NB. exponent(Im(g)) ~ TN(0,3^2,-6,4)
NB. :
NB. G=. ((0 1 0 1 , FP_EMIN , FP_EMAX)&gemat j. _1 1 0 3 _6 4&gemat) 4 4
NB.
NB. Notes:
NB. - default par provides about 95% of g numbers falls into
NB. the range [-1/FP_EPS,-FP_EPS]U[FP_EPS,1/FP_EPS]
NB. ("68-95-99.7 rule")
gemat=: (_1 1 0 , (-: FP_FLEN) , FP_EMIN , FP_EMAX)&$: :(((randu~ 2&{.) * 2 ^ (randtnr~ 2&}.))~)
NB. ---------------------------------------------------------
NB. dimat
NB.
NB. Description:
NB. Conj. to make verb to make random diagonalizable
NB. matrix
NB.
NB. Syntax:
NB. A=. (randx dimat randq) sh
NB. where
NB. randq - monad to make Q; is called as:
NB. Q=. randq sh
NB. randx - monad to make d; is called as:
NB. d=. randx n
NB. sh - size or shape, which is either n or (n,n)
NB. Q - n×n-matrix, random unitary (orthogonal):
NB. I = Q^H * Q
NB. d - n-vector of distinct or real (non-complex)
NB. numbers
NB. A - n×n-matrix, random diagonalizable square, which
NB. is defined as:
NB. A := Q * D * Q^H
NB. D - n×n-matrix, diagonal, which is defined as:
NB. D := diagmat d
NB.
NB. Application:
NB. - make real diagonalizable 4×4-matrix A with eigenvalues
NB. d having:
NB. mantissa(d) ~ U(1,3)
NB. exponent(d) ~ TN(0,4^2,-5,6)
NB. and eigenvectors Q derived via QR-factorization from
NB. real matrix B:
NB. A=. 1 3 0 4 _5 6&gemat dimat (randnr unmat) 4 4
NB. - make complex diagonalizable Hermitian 4×4-matrix A with
NB. eigenvalues d having:
NB. mantissa(d) ~ U(1,3)
NB. exponent(d) ~ TN(0,4^2,-5,6)
NB. and eigenvectors Q derived via QR-factorization from
NB. complex matrix B:
NB. A=. 1 3 0 4 _5 6&gemat dimat (randnc unmat) 4
NB. - make complex diagonalizable 4×4-matrix A with
NB. eigenvalues d having:
NB. mantissa(Re(d)),mantissa(Im(d)) ~ U(1,3)
NB. exponent(Re(d)),exponent(Im(d)) ~ TN(0,4^2,-5,6)
NB. and eigenvectors Q derived via QR-factorization from
NB. complex matrix B:
NB. A=. 1 3 0 4 _5 6&(gemat j. gemat) dimat (randnc unmat) 4
NB.
NB. Notes:
NB. - A will be Hermitian (symmetric) if randx produces real
NB. (non-complex), possibly non-distinct numbers
NB. - A is diagonalizable iif A is normal (A^H * A = A * A^H)
dimat=: 2 : 'u@{. (] mp_mt_ (* ct_mt_)) v'
NB. ---------------------------------------------------------
NB. hemat
NB.
NB. Description:
NB. Adv. to make verb to make random Hermitian (symmetric)
NB. matrix
NB.
NB. Syntax:
NB. H=. (randx hemat) sh
NB. where
NB. randx - monad to make random y-array; is called as:
NB. A=. randx y
NB. sh - size or shape, which is either n or
NB. (n,any_number)
NB. H - n×n-matrix, random Hermitian (symmetric)
NB.
NB. Assertions:
NB. (-: ct) H
NB. where
NB. H=. randx hemat n
NB.
NB. Application:
NB. - make real symmetric 4×4-matrix H with elements h
NB. having:
NB. mantissa(h) ~ U(-1,1)
NB. exponent(h) ~ TN(0,3^2,-6,4)
NB. :
NB. H=. _1 1 0 3 _6 4&gemat hemat 4 4
NB. - make complex Hermitian 4×4-matrix L with elements h
NB. having:
NB. mantissa(Re(h)),mantissa(Im(h)) ~ U(-1,1)
NB. exponent(Re(h)),exponent(Im(h)) ~ TN(0,3^2,-6,4)
NB. :
NB. H=. _1 1 0 3 _6 4&(gemat j. gemat) hemat 4
NB. - make complex Hermitian 4×4-matrix L with elements h
NB. having:
NB. mantissa(Re(h)) ~ U(0,1)
NB. exponent(Re(h)) ~ TN(0,1,-∞,+∞)
NB. mantissa(Im(h)) ~ U(-1,1)
NB. exponent(Im(h)) ~ TN(0,3^2,-6,4)
NB. :
NB. H=. ((0 1 0 1 , FP_EMIN , FP_EMAX)&gemat j. _1 1 0 3 _6 4&gemat) hemat 4
NB.
NB. Notes:
NB. - only n*(n+1)/2 numbers from RNG are requested
hemat=: 1 : 'he4gel_mt_@(u trlmat_mt_)@(2&$)'
NB. ---------------------------------------------------------
NB. pomat
NB.
NB. Description:
NB. Adv. to make verb to make random Hermitian (symmetric)
NB. positive definite matrix
NB.
NB. Syntax:
NB. P=. (randx pomat) sh
NB. where
NB. randx - monad to make A; is called as:
NB. A=. randx y
NB. sh - size or shape, which is either n or
NB. (n,any_number)
NB. A - n×n-matrix, random square invertible
NB. P - n×n-matrix, random Hermitian (symmetric)
NB. positive definite; is defined as:
NB. P := A * A^H
NB.
NB. Application:
NB. - make real symmetric positive definite 4×4-matrix P with
NB. elements p having:
NB. mantissa(p) ~ U(1,3)
NB. exponent(p) ~ TN(0,4^2,-5,6)
NB. :
NB. P=. 1 3 0 4 _5 6&gemat pomat 4 4
NB. - make complex Hermitian positive definite 4×4-matrix P
NB. with elements p having:
NB. mantissa(Re(p)),mantissa(Im(p)) ~ U(1,3)
NB. exponent(Re(p)),exponent(Im(p)) ~ TN(0,4^2,-5,6)
NB. :
NB. P=. 1 3 0 4 _5 6&(gemat j. gemat) pomat 4
NB. - make complex Hermitian positive definite 4×4-matrix P
NB. with elements p having:
NB. mantissa(Re(p)) ~ U(1,2)
NB. exponent(Re(p)) ~ TN(0,1,-∞,+∞)
NB. mantissa(Im(p)) ~ U(1,3)
NB. exponent(Im(p)) ~ TN(0,4^2,-5,6)
NB. :
NB. P=. ((1 2 0 1 , FP_EMIN , FP_EMAX)&gemat j. 1 3 0 4 _5 6&gemat) pomat 4
NB. - make real symmetric negative definite 4×4-matrix P
NB. with elements p having:
NB. mantissa(p) ~ U(1,3)
NB. exponent(p) ~ TN(0,4^2,-5,6)
NB. :
NB. P=. -@(1 3 0 4 _5 6&gemat pomat) 4 4
pomat=: 1 : 'po_mt_@u@(2&$)'
NB. ---------------------------------------------------------
NB. ptmat
NB. ptmat2
NB.
NB. Description:
NB. Adv. to make monad to make random Hermitian (symmetric)
NB. positive definite tridiagonal matrix
NB.
NB. Syntax:
NB. T=. (randx ptmat ) sh
NB. T2=. (randx ptmat2) sh
NB. where
NB. randx - monad to make random y-array A; is called as:
NB. A=. randx y
NB. T - n×n-matrix, random Hermitian (symmetric)
NB. positive definite tridiagonal, which is defined
NB. as:
NB. T := L * L^H
NB. T2 - n×n-matrix, random Hermitian (symmetric)
NB. positive definite tridiagonal, which is defined
NB. as:
NB. T := K^_1
NB. sh - size or shape, which is either n or
NB. (n,any_number)
NB. L - n×n-matrix, random lower bidiagonal with
NB. positive diagonal entries
NB. K - n×n-matrix, random K(rho) generated from rho
NB. parameter derived from randx such that
NB. 0.5 < abs(rho) < 1
NB.
NB. Application:
NB. - make real symmetric positive definite tridiagonal
NB. 4×4-matrix T with elements d and e having:
NB. mantissa(d),mantissa(e) ~ U(1,3)
NB. mantissa(d),exponent(e) ~ TN(0,4^2,-5,6)
NB. :
NB. T=. 1 3 0 4 _5 6&gemat ptmat 4 4
NB. - make complex Hermitian positive definite tridiagonal
NB. 4×4-matrix T with elements d and e having:
NB. mantissa(d),mantissa(Re(e)),mantissa(Im(e)) ~ U(1,3)
NB. exponent(d),exponent(Re(e)),exponent(Im(e)) ~ TN(0,4^2,-5,6)
NB. :
NB. T=. 1 3 0 4 _5 6&(gemat j. gemat) ptmat 4
NB. - make complex Hermitian positive definite tridiagonal
NB. 4×4-matrix T with elements d and e having:
NB. mantissa(d),mantissa(Re(e)) ~ U(0,1)
NB. mantissa(d),exponent(Re(e)) ~ TN(0,1,-∞,+∞)
NB. mantissa(Im(e)) ~ U(1,3)
NB. exponent(Im(e)) ~ TN(0,4^2,-5,6)
NB. :
NB. T=. gemat j. 1 3 0 4 _5 6&gemat ptmat 4
NB.
NB. Notes:
NB. - ptmat2 produces well-conditioned matrices for big n
NB. (>400)
NB.
NB. TODO:
NB. - T would be sparse
ptmat=: 1 : 'po_mt_@(>:@| upddiag_mt_)@(((setdiag_mt_ diagmat_mt_)~ (}: ; _1:))/)@:u@(2,{.)'
ptmat2=: 1 : '(9&o. upddiag_mt_)@gtpick_mt_@potril_mt_@potrfl_mt_@(u kmsmatrho_mt_ kmsmat_mt_)'
NB. ---------------------------------------------------------
NB. unmat
NB.
NB. Description:
NB. Adv. to make monad to make random unitary (orthogonal)
NB. matrix with distribution given by Haar measure
NB.
NB. Syntax:
NB. Q=. (randnx unmat) sh
NB. where
NB. randnx - monad to make A, it is either randnr or
NB. randnc; is called as:
NB. A=. randnx y
NB. sh - size or shape, which is either n or (n,n)
NB. A - n×n-matrix, non-singular, with elements
NB. distributed as N(0,1)
NB. Q - n×n-matrix, random unitary (orthogonal)
NB.
NB. Formula:
NB. A := randnx(n,n)
NB. (Q,R) := QR(A)
NB. d := diag(R)
NB. Λ := diagmat(d/|d|)
NB. Q := Q*Λ
NB. where
NB. n - size of output matrix Q
NB.
NB. Assertions (with appropriate comparison tolerance):
NB. I -: clean (mp ct) Q
NB. I -: clean (mp~ct) Q
NB. where
NB. I=. idmat n
NB. Q=. randnr unmat n
NB.
NB. Application:
NB. - make real orthogonal 4×4-matrix Q, where Q is derived
NB. via QR-factorization from real matrix B:
NB. Q=. randnr unmat 4 4
NB. - make complex unitary 4×4-matrix U, where U is derived
NB. via QR-factorization from complex matrix B:
NB. U=. randnc unmat 4
NB.
NB. References:
NB. [1] Francesco Mezzadri. How to generate random matrices
NB. from the classical compact groups. Notices of the
NB. AMS, 2007, Vol. 54, pp. 592-604.
NB. http://arxiv.org/abs/math-ph/0609050v2
unmat=: 1 : '(ungqr_mt_*"1*@diag_mt_)@geqrf_mt_@:u@(2&$)'
NB. ---------------------------------------------------------
NB. spmat
NB.
NB. Description:
NB. Conj. to make monad to make random sparse array
NB.
NB. Syntax:
NB. S=. (randx spmat ratio) sh
NB. where
NB. randx - monad to make random y-array A; is called as:
NB. A=. randx y
NB. ratio - scalar in range [0,1], specifies desired
NB. portion of non-zero elements
NB. S - sh-array, sparsed randomly, being is zero
NB. sh-array inhabited with values from A
NB. sh - vector of non-negative integers, the shape of S
NB.
NB. Application:
NB. - make random real sparse 3×4-matrix S:
NB. S=. (randnr spmat 0.25) 3 4
NB.
NB. TODO:
NB. - S would be sparse
spmat=: 2 : 'u@<.@(n * */) ((?@$~ #)~ (*/@$))} $&0'
NB. =========================================================
NB. Test suite
NB. ---------------------------------------------------------
NB. testtrmat
NB.
NB. Description:
NB. Test trxxmat by matrix size given
NB.
NB. Syntax:
NB. log=. testtrmat sz
NB. where
NB. sz - size or shape, which is either n or
NB. (n,any_number)
NB. log - 6-vector of boxes, test log
testtrmat=: 3 : 0
log=. (' randu trl1mat' tmonad (]`]`nan`nan`nan)) y
log=. log lcat (' randu trlmat ' tmonad (]`]`nan`nan`nan)) y
log=. log lcat (' randu tru1mat' tmonad (]`]`nan`nan`nan)) y
log=. log lcat (' randu trumat ' tmonad (]`]`nan`nan`nan)) y
log=. log lcat ('(randu j. randu) trl1mat' tmonad (]`]`nan`nan`nan)) y
log=. log lcat ('(randu j. randu) trlmat ' tmonad (]`]`nan`nan`nan)) y
log=. log lcat ('(randu j. randu) tru1mat' tmonad (]`]`nan`nan`nan)) y
log=. log lcat ('(randu j. randu) trumat ' tmonad (]`]`nan`nan`nan)) y
)
NB. ---------------------------------------------------------
NB. testgemat
NB.
NB. Description:
NB. Test gemat by matrix shape given
NB.
NB. Syntax:
NB. log=. testgemat sh
NB. where
NB. sh - vector of non-negative integers, the shape of
NB. matrix
NB. log - 6-vector of boxes, test log
testgemat=: 'gemat' tmonad (]`]`nan`nan`nan)
NB. ---------------------------------------------------------
NB. testdimat
NB.
NB. Description:
NB. Test dimat by matrix size given
NB.
NB. Syntax:
NB. log=. testdimat sz
NB. where
NB. sz - size or shape, which is either n or (n,n)
NB. log - 6-vector of boxes, test log
testdimat=: 3 : 0
log=. (' gemat dimat (randnr unmat)' tmonad (]`]`nan`nan`nan)) y
log=. log lcat (' gemat dimat (randnc unmat)' tmonad (]`]`nan`nan`nan)) y
log=. log lcat ('(gemat j. gemat) dimat (randnr unmat)' tmonad (]`]`nan`nan`nan)) y
log=. log lcat ('(gemat j. gemat) dimat (randnc unmat)' tmonad (]`]`nan`nan`nan)) y
)
NB. ---------------------------------------------------------
NB. testhemat
NB.
NB. Description:
NB. Test hemat by matrix size given
NB.
NB. Syntax:
NB. log=. testhemat sz
NB. where
NB. sz - size or shape, which is either n or
NB. (n,any_number)
NB. log - 6-vector of boxes, test log
testhemat=: 3 : 0
log=. (' randu hemat' tmonad (]`]`nan`nan`nan)) y
log=. log lcat ('(randu j. randu) hemat' tmonad (]`]`nan`nan`nan)) y
)
NB. ---------------------------------------------------------
NB. testpomat
NB.
NB. Description:
NB. Test pomat by matrix size given
NB.
NB. Syntax:
NB. log=. testpomat sz
NB. where
NB. sz - size or shape, which is either n or
NB. (n,any_number)
NB. log - 6-vector of boxes, test log
testpomat=: 3 : 0
log=. (' randu pomat' tmonad (]`]`nan`nan`nan)) y
log=. log lcat ('(randu j. randu) pomat' tmonad (]`]`nan`nan`nan)) y
)
NB. ---------------------------------------------------------
NB. testptmat
NB.
NB. Description:
NB. Test ptmatx by matrix size given
NB.
NB. Syntax:
NB. log=. testptmat sz
NB. where
NB. sz - size or shape, which is either n or
NB. (n,any_number)
NB. log - 6-vector of boxes, test log
testptmat=: 3 : 0
log=. (' randu ptmat ' tmonad (]`]`nan`nan`nan)) y
log=. log lcat ('(randu j. randu) ptmat ' tmonad (]`]`nan`nan`nan)) y
log=. log lcat (' randu ptmat2' tmonad (]`]`nan`nan`nan)) y
log=. log lcat ('(randu j. randu) ptmat2' tmonad (]`]`nan`nan`nan)) y
)
NB. ---------------------------------------------------------
NB. testunmat
NB.
NB. Description:
NB. Test unmat by matrix size given
NB.
NB. Syntax:
NB. log=. testunmat sz
NB. where
NB. sz - size or shape, which is either n or
NB. (n,any_number)
NB. log - 6-vector of boxes, test log
testunmat=: 3 : 0
log=. ('randnr unmat' tmonad (]`]`nan`nan`nan)) y
log=. log lcat ('randnc unmat' tmonad (]`]`nan`nan`nan)) y
)
NB. ---------------------------------------------------------
NB. testspmat
NB.
NB. Description:
NB. Test spmat by matrix shape given
NB.
NB. Syntax:
NB. log=. testspmat sh
NB. where
NB. sh - vector of non-negative integers, the shape of
NB. matrix
NB. log - 6-vector of boxes, test log
testspmat=: 3 : 0
log=. (' randu spmat 0.25' tmonad (]`]`nan`nan`nan)) y
log=. log lcat ('(randu j. randu) spmat 0.25' tmonad (]`]`nan`nan`nan)) y
)
NB. ---------------------------------------------------------
NB. testrand
NB.
NB. Description:
NB. Test xxxxmatx by matrix shape given
NB.
NB. Syntax:
NB. log=. testrand sh
NB. where
NB. sh - vector of non-negative integers, the shape of
NB. matrix
NB. log - 6-vector of boxes, test log
testrand=: lcat@(testtrmat`testgemat`(nolog_mt_`(lcat@(testdimat`testunmat`:0))@.(=/))`testhemat`testpomat`testptmat`testspmat`:0)