-
Notifications
You must be signed in to change notification settings - Fork 1
/
OBD.MatrixDisplay.pas
1558 lines (1458 loc) · 46.8 KB
/
OBD.MatrixDisplay.pas
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
//------------------------------------------------------------------------------
// UNIT : OBD.MatrixDisplay.pas
// CONTENTS : Matrix display component
// VERSION : 1.0
// TARGET : Embarcadero Delphi 11 or higher
// AUTHOR : Ernst Reidinga (ERDesigns)
// STATUS : Open source under Apache 2.0 library
// COMPATIBILITY : Windows 7, 8/8.1, 10, 11
// RELEASE DATE : 23/03/2024
//------------------------------------------------------------------------------
unit OBD.MatrixDisplay;
interface
uses
System.SysUtils, System.Classes, Vcl.Controls, WinApi.Windows, Winapi.Messages,
Vcl.Graphics, Vcl.Themes,
OBD.CustomControl, OBD.CustomControl.Common;
//------------------------------------------------------------------------------
// CONSTANTS
//------------------------------------------------------------------------------
const
/// <summary>
/// Margin from the border (Otherwise the display border is flattened on the side)
/// </summary>
MARGIN_FROM_BORDER = 2;
/// <summary>
/// Default cell size
/// </summary>
DEFAULT_CELL_SIZE = 2;
/// <summary>
/// Default cell spacing
/// </summary>
DEFAULT_CELL_SPACING = 1;
/// <summary>
/// Default rows
/// </summary>
DEFAULT_ROWS = 30;
/// <summary>
/// Default columns
/// </summary>
DEFAULT_COLS = 125;
/// <summary>
/// Default background from color
/// </summary>
DEFAULT_BACKGROUND_FROM = $00FBF5F7;
/// <summary>
/// Default background to color
/// </summary>
DEFAULT_BACKGROUND_TO = $00BBAEAC;
/// <summary>
/// Default border from color
/// </summary>
DEFAULT_BORDER_FROM = $00918888;
/// <summary>
/// Default border to color
/// </summary>
DEFAULT_BORDER_TO = $00776F6F;
/// <summary>
/// Default border width
/// </summary>
DEFAULT_BORDER_WIDTH = 3;
/// <summary>
/// Default border width
/// </summary>
DEFAULT_BORDER_CORNER = 25;
/// <summary>
/// Default cell on color
/// </summary>
DEFAULT_CELL_ON_COLOR = $00DF7000;
/// <summary>
/// Default cell off color
/// </summary>
DEFAULT_CELL_OFF_COLOR = $00F9F9F9;
/// <summary>
/// Default animation enabled
/// </summary>
DEFAULT_ANIMATION_ENABLED = False;
/// <summary>
/// Default animation duration
/// </summary>
DEFAULT_ANIMATION_DURATION = 1000;
//------------------------------------------------------------------------------
// TYPES
//------------------------------------------------------------------------------
type
/// <summary>
/// Matrix Display cell (Is a simple boolean: On/Off)
/// </summary>
TOBDMatrixDisplayCell = Boolean;
/// <summary>
/// Matrix Display row (Array of cells)
/// </summary>
TOBDMatrixDisplayRow = TArray<TOBDMatrixDisplayCell>;
/// <summary>
/// Matrix Display cells (Array of rows)
/// </summary>
TOBDMatrixDisplayCells = TArray<TOBDMatrixDisplayRow>;
/// <summary>
/// Matrix Display Animation types
/// </summary>
TOBDMatrixDisplayAnimationType = (atScrollLeft, atScrollRight, atScrollUp, atScrollDown, atInvert);
//------------------------------------------------------------------------------
// CLASSES
//------------------------------------------------------------------------------
type
/// <summary>
/// Matrix Display background properties
/// </summary>
TOBDMatrixDisplayBackground = class(TPersistent)
private
/// <summary>
/// Gradient from color
/// </summary>
FFromColor: TColor;
/// <summary>
/// Gradient to color
/// </summary>
FToColor: TColor;
/// <summary>
/// Set gradient from color
/// </summary
procedure SetFromColor(Value: TColor);
/// <summary>
/// Set gradient to color
/// </summary
procedure SetToColor(Value: TColor);
private
/// <summary>
/// On change event
/// </summary>
FOnChange: TNotifyEvent;
public
/// <summary>
/// Constructor
/// </summary>
constructor Create; virtual;
/// <summary>
/// Override assign method
/// </summary>
procedure Assign(Source: TPersistent); override;
published
/// <summary>
/// Gradient from color
/// </summary>
property FromColor: TColor read FFromColor write SetFromColor default DEFAULT_BACKGROUND_FROM;
/// <summary>
/// Gradient to color
/// </summary>
property ToColor: TColor read FToColor write SetToColor default DEFAULT_BACKGROUND_TO;
/// <summary>
/// On change event
/// </summary>
property OnChange: TNotifyEvent read FOnChange write FOnChange;
end;
/// <summary>
/// Matrix Display border properties
/// </summary>
TOBDMatrixDisplayBorder = class(TPersistent)
private
/// <summary>
/// Gradient from color
/// </summary>
FFromColor: TColor;
/// <summary>
/// Gradient to color
/// </summary>
FToColor: TColor;
/// <summary>
/// Border width
/// </summary>
FWidth: Integer;
/// <summary>
/// Border corner size
/// </summary>
FCorner: Single;
/// <summary>
/// Set gradient from color
/// </summary
procedure SetFromColor(Value: TColor);
/// <summary>
/// Set gradient to color
/// </summary
procedure SetToColor(Value: TColor);
/// <summary>
/// Set border width
/// </summary>
procedure SetWidth(Value: Integer);
/// <summary>
/// Set corner size
/// </summary>
procedure SetCorner(Value: Single);
private
/// <summary>
/// On change event
/// </summary>
FOnChange: TNotifyEvent;
public
/// <summary>
/// Constructor
/// </summary>
constructor Create; virtual;
/// <summary>
/// Override assign method
/// </summary>
procedure Assign(Source: TPersistent); override;
published
/// <summary>
/// Gradient from color
/// </summary>
property FromColor: TColor read FFromColor write SetFromColor default DEFAULT_BORDER_FROM;
/// <summary>
/// Gradient to color
/// </summary>
property ToColor: TColor read FToColor write SetToColor default DEFAULT_BORDER_TO;
/// <summary>
/// Border width
/// </summary>
property Width: Integer read FWidth write SetWidth default DEFAULT_BORDER_WIDTH;
/// <summary>
/// Border corner size
/// </summary>
property Corner: Single read FCorner write SetCorner;
/// <summary>
/// On change event
/// </summary>
property OnChange: TNotifyEvent read FOnChange write FOnChange;
end;
/// <summary>
/// Matrix Display Animation
/// </summary>
TOBDMatrixDisplayAnimation = class(TPersistent)
private
/// <summary>
/// Is animation enabled
/// </summary>
FEnabled: Boolean;
/// <summary>
/// Duration of the animation
/// </summary>
FDuration: Cardinal;
/// <summary>
/// Animation type
/// </summary>
FType: TOBDMatrixDisplayAnimationType;
/// <summary>
/// Set enabled
/// </summary>
procedure SetEnabled(Value: Boolean);
/// <summary>
/// Set duration
/// </summary>
procedure SetDuration(Value: Cardinal);
private
/// <summary>
/// On change event
/// </summary>
FOnChange: TNotifyEvent;
public
/// <summary>
/// Constructor
/// </summary>
constructor Create; virtual;
/// <summary>
/// Override assign method
/// </summary>
procedure Assign(Source: TPersistent); override;
published
/// <summary>
/// Is animation enabled
/// </summary>
property Enabled: Boolean read FEnabled write SetEnabled default DEFAULT_ANIMATION_ENABLED;
/// <summary>
/// Animation duration
/// </summary>
property Duration: Cardinal read FDuration write SetDuration default DEFAULT_ANIMATION_DURATION;
/// <summary>
/// Type of animation
/// </summary>
property &Type: TOBDMatrixDisplayAnimationType read FType write FType default atScrollLeft;
/// <summary>
/// On change event
/// </summary>
property OnChange: TNotifyEvent read FOnChange write FOnChange;
end;
/// <summary>
/// Circular Gauge Component
/// </summary>
TOBDMatrixDisplay = class(TOBDCustomControl)
private
/// <summary>
/// Background Buffer
/// </summary>
FBackgroundBuffer: TBitmap;
/// <summary>
/// Window handle needed for the timer
/// </summary>
FWindowHandle: THandle;
/// <summary>
/// Handle of the animation timer
/// </summary>
FTimerHandle: THandle;
private
/// <summary>
/// Cells
/// </summary>
FCells: TOBDMatrixDisplayCells;
/// <summary>
/// Cell size
/// </summary>
FCellSize: Integer;
/// <summary>
/// Cell spacing (Space between cells)
/// </summary>
FCellSpacing: Integer;
/// <summary>
/// Rows
/// </summary>
FRows: Integer;
/// <summary>
/// Columns
/// </summary>
FCols: Integer;
/// <summary>
/// Display background
/// </summary>
FBackground: TOBDMatrixDisplayBackground;
/// <summary>
/// Display border
/// </summary>
FBorder: TOBDMatrixDisplayBorder;
/// <summary>
/// Cell on color
/// </summary>
FOnColor: TColor;
/// <summary>
/// Cell off color
/// </summary>
FOffColor: TColor;
/// <summary>
/// Animation
/// </summary>
FAnimation: TOBDMatrixDisplayAnimation;
/// <summary>
/// Set cell size
/// </summary>
procedure SetCellSize(Value: Integer);
/// <summary>
/// Set cell spacing
/// </summary>
procedure SetCellSpacing(Value: Integer);
/// <summary>
/// Set rows
/// </summary>
procedure SetRows(Value: Integer);
/// <summary>
/// Set cols
/// </summary>
procedure SetCols(Value: Integer);
/// <summary>
/// Set display background
/// </summary>
procedure SetBackground(Value: TOBDMatrixDisplayBackground);
/// <summary>
/// Set display border
/// </summary>
procedure SetBorder(Value: TOBDMatrixDisplayBorder);
/// <summary>
/// Set cell on color
/// </summary>
procedure SetOnColor(Value: TColor);
/// <summary>
/// Set cell off color
/// </summary>
procedure SetOffColor(Value: TColor);
/// <summary>
/// Set animation
/// </summary>
procedure SetAnimation(Value: TOBDMatrixDisplayAnimation);
/// <summary>
/// Initialize cells
/// </summary>
procedure InitializeCells;
protected
/// <summary>
/// Invalidate background (Repaint background buffer)
/// </summary>
procedure InvalidateBackground; virtual;
/// <summary>
/// Paint matrix cells
/// </summary>
procedure PaintMatrix; virtual;
/// <summary>
/// Paint buffer
/// </summary>
procedure PaintBuffer; override;
/// <summary>
/// On change handler
/// </summary>
procedure SettingsChanged(Sender: TObject);
/// <summary>
/// On animation changed handler
/// </summary>
procedure AnimationChanged(Sender: TObject);
/// <summary>
/// Timer proc handler
/// </summary>
procedure AnimationTimerProc(var Msg: TMessage);
/// <summary>
/// Get cell at specified row/col
/// </summary>
function GetCell(Row, Col: Integer): TOBDMatrixDisplayCell;
/// <summary>
/// Set cell at specified row/col
/// </summary>
procedure SetCell(Row, Col: Integer; Value: TOBDMatrixDisplayCell);
protected
/// <summary>
/// Override Resize method
/// </summary>
procedure Resize; override;
/// <summary>
/// Override Loaded method
/// </summary>
procedure Loaded; override;
/// <summary>
/// Override WndProc method
/// </summary>
procedure WndProc(var Message: TMessage); override;
public
/// <summary>
/// Constructor
/// </summary>
constructor Create(AOwner: TComponent); override;
/// <summary>
/// Destructor
/// </summary>
destructor Destroy; override;
/// <summary>
/// Override assign method
/// </summary>
procedure Assign(Source: TPersistent); override;
/// <summary>
/// Clear display (Set all cells to false)
/// </summary>
procedure Clear;
/// <summary>
/// Invert display (Set all on cells off, and off cells on)
/// </summary>
procedure Invert;
/// <summary>
/// Scroll up
/// </summary>
procedure ScrollUp(const Loop: Boolean = True; const Step: Integer = 1);
/// <summary>
/// Scroll down
/// </summary>
procedure ScrollDown(const Loop: Boolean = True; const Step: Integer = 1);
/// <summary>
/// Scroll left
/// </summary>
procedure ScrollLeft(const Loop: Boolean = True; const Step: Integer = 1);
/// <summary>
/// Scroll right
/// </summary>
procedure ScrollRight(const Loop: Boolean = True; const Step: Integer = 1);
/// <summary>
/// Load a bitmap mask in the display
/// </summary>
procedure LoadMask(const Value: TBitmap; const Row: Integer = 0; const Col: Integer = 0; const Inversed: Boolean = false);
/// <summary>
/// Load a bitmap mask centered in the display
/// </summary>
procedure LoadMaskCenterd(const Value: TBitmap; const Horizontal: Boolean = True; const Vertical: Boolean = True; const Inversed: Boolean = False);
/// <summary>
/// Load text in the display
/// </summary>
procedure LoadText(const Value: string; const Row: Integer = 0; const Col: Integer = 0; const Inversed: Boolean = False);
/// <summary>
/// Load text centered in the display
/// </summary>
procedure LoadTextCentered(const Value: string; const Horizontal: Boolean = True; const Vertical: Boolean = True; const Inversed: Boolean = False);
published
/// <summary>
/// Cell size
/// </summary>
property CellSize: Integer read FCellSize write SetCellSize default DEFAULT_CELL_SIZE;
/// <summary>
/// Cell spacing (Space between cells)
/// </summary>
property CellSpacing: Integer read FCellSpacing write SetCellSpacing default DEFAULT_CELL_SPACING;
/// <summary>
/// Rows
/// </summary>
property Rows: Integer read FRows write SetRows default DEFAULT_ROWS;
/// <summary>
/// Columns
/// </summary>
property Cols: Integer read FCols write SetCols default DEFAULT_COLS;
/// <summary>
/// Display background
/// </summary>
property Background: TOBDMatrixDisplayBackground read FBackground write SetBackground;
/// <summary>
/// Display border
/// </summary>
property Border: TOBDMatrixDisplayBorder read FBorder write SetBorder;
/// <summary>
/// Cell on color
/// </summary>
property CellOnColor: TColor read FOnColor write SetOnColor default DEFAULT_CELL_ON_COLOR;
/// <summary>
/// Cell off color
/// </summary>
property CellOffColor: TColor read FOffColor write SetOffColor default DEFAULT_CELL_OFF_COLOR;
/// <summary>
/// Animation
/// </summary>
property Animation: TOBDMatrixDisplayAnimation read FAnimation write SetAnimation;
published
/// <summary>
/// Inherited Font
/// </summary>
property Font;
/// <summary>
/// Inherited Text
/// </summary>
property Text;
end;
implementation
uses
Winapi.GDIPOBJ, Winapi.GDIPAPI, System.Math;
//------------------------------------------------------------------------------
// SET FROM COLOR
//------------------------------------------------------------------------------
procedure TOBDMatrixDisplayBackground.SetFromColor(Value: TColor);
begin
if (FFromColor <> Value) then
begin
// Set the new from color
FFromColor := Value;
// Notify the change
if Assigned(OnChange) then OnChange(Self);
end;
end;
//------------------------------------------------------------------------------
// SET TO COLOR
//------------------------------------------------------------------------------
procedure TOBDMatrixDisplayBackground.SetToColor(Value: TColor);
begin
if (FToColor <> Value) then
begin
// Set the new to color
FToColor := Value;
// Notify the change
if Assigned(OnChange) then OnChange(Self);
end;
end;
//------------------------------------------------------------------------------
// CONSTRUCTOR
//------------------------------------------------------------------------------
constructor TOBDMatrixDisplayBackground.Create;
begin
// Call inherited constructor
inherited Create;
// Set defaults
FFromColor := DEFAULT_BACKGROUND_FROM;
FToColor := DEFAULT_BACKGROUND_TO;
end;
//------------------------------------------------------------------------------
// ASSIGN
//------------------------------------------------------------------------------
procedure TOBDMatrixDisplayBackground.Assign(Source: TPersistent);
begin
// Assign properties
if (Source is TOBDMatrixDisplayBackground) then
begin
FFromColor := (Source as TOBDMatrixDisplayBackground).FromColor;
FToColor := (Source as TOBDMatrixDisplayBackground).ToColor;
// Notify change
if Assigned(OnChange) then OnChange(Self);
end else
// Call inherited assign
inherited;
end;
//------------------------------------------------------------------------------
// SET FROM COLOR
//------------------------------------------------------------------------------
procedure TOBDMatrixDisplayBorder.SetFromColor(Value: TColor);
begin
if (FFromColor <> Value) then
begin
// Set the new from color
FFromColor := Value;
// Notify the change
if Assigned(OnChange) then OnChange(Self);
end;
end;
//------------------------------------------------------------------------------
// SET TO COLOR
//------------------------------------------------------------------------------
procedure TOBDMatrixDisplayBorder.SetToColor(Value: TColor);
begin
if (FToColor <> Value) then
begin
// Set the new to color
FToColor := Value;
// Notify the change
if Assigned(OnChange) then OnChange(Self);
end;
end;
//------------------------------------------------------------------------------
// SET WIDTH
//------------------------------------------------------------------------------
procedure TOBDMatrixDisplayBorder.SetWidth(Value: Integer);
begin
if (FWidth <> Value) and (Value >= 0) then
begin
// Set the new width
FWidth := Value;
// Notify the change
if Assigned(OnChange) then OnChange(Self);
end;
end;
//------------------------------------------------------------------------------
// SET CORNER
//------------------------------------------------------------------------------
procedure TOBDMatrixDisplayBorder.SetCorner(Value: Single);
begin
if (FCorner <> Value) and (Value >= 0) then
begin
// Set the nex corner size
FCorner := Value;
// Notify the change
if Assigned(OnChange) then OnChange(Self);
end;
end;
//------------------------------------------------------------------------------
// CONSTRUCTOR
//------------------------------------------------------------------------------
constructor TOBDMatrixDisplayBorder.Create;
begin
// Call inherited constructor
inherited Create;
// Set defaults
FFromColor := DEFAULT_BORDER_FROM;
FToColor := DEFAULT_BORDER_TO;
FWidth := DEFAULT_BORDER_WIDTH;
FCorner := DEFAULT_BORDER_CORNER;
end;
//------------------------------------------------------------------------------
// ASSIGN
//------------------------------------------------------------------------------
procedure TOBDMatrixDisplayBorder.Assign(Source: TPersistent);
begin
// Assign properties
if (Source is TOBDMatrixDisplayBorder) then
begin
FFromColor := (Source as TOBDMatrixDisplayBorder).FromColor;
FToColor := (Source as TOBDMatrixDisplayBorder).ToColor;
FWidth := (Source as TOBDMatrixDisplayBorder).Width;
FCorner := (Source as TOBDMatrixDisplayBorder).Corner;
// Notify change
if Assigned(OnChange) then OnChange(Self);
end else
// Call inherited assign
inherited;
end;
//------------------------------------------------------------------------------
// SET ENABLED
//------------------------------------------------------------------------------
procedure TOBDMatrixDisplayAnimation.SetEnabled(Value: Boolean);
begin
if (FEnabled <> Value) then
begin
// Set enabled
FEnabled := Value;
// Notify change
if Assigned(OnChange) then OnChange(Self);
end;
end;
//------------------------------------------------------------------------------
// SET DURATION
//------------------------------------------------------------------------------
procedure TOBDMatrixDisplayAnimation.SetDuration(Value: Cardinal);
begin
if (FDuration <> Value) and (Value >= 10) then
begin
// Set duration
FDuration := Value;
// Notify change
if Assigned(OnChange) then OnChange(Self);
end;
end;
//------------------------------------------------------------------------------
// CONSTRUCTOR
//------------------------------------------------------------------------------
constructor TOBDMatrixDisplayAnimation.Create;
begin
// Call inherited constructor
inherited Create;
// Set defaults
FEnabled := DEFAULT_ANIMATION_ENABLED;
FDuration := DEFAULT_ANIMATION_DURATION;
FType := atScrollLeft;
end;
//------------------------------------------------------------------------------
// ASSIGN
//------------------------------------------------------------------------------
procedure TOBDMatrixDisplayAnimation.Assign(Source: TPersistent);
begin
if (Source is TOBDMatrixDisplayAnimation) then
begin
FEnabled := (Source as TOBDMatrixDisplayAnimation).Enabled;
FDuration := (Source as TOBDMatrixDisplayAnimation).Duration;
end else
// Call inherited assign
inherited;
end;
//------------------------------------------------------------------------------
// SET CELL SIZE
//------------------------------------------------------------------------------
procedure TOBDMatrixDisplay.SetCellSize(Value: Integer);
begin
if (FCellSize <> Value) then
begin
// Set new cell size
FCellSize := Value;
// Invalidate buffer
InvalidateBuffer;
end;
end;
//------------------------------------------------------------------------------
// SET CELL SPACING
//------------------------------------------------------------------------------
procedure TOBDMatrixDisplay.SetCellSpacing(Value: Integer);
begin
if (FCellSpacing <> Value) then
begin
// Set new cell spacing
FCellSpacing := Value;
// Invalidate buffer
InvalidateBuffer;
end;
end;
//------------------------------------------------------------------------------
// SET ROWS
//------------------------------------------------------------------------------
procedure TOBDMatrixDisplay.SetRows(Value: Integer);
begin
if (FRows <> Value) and (Value >= 0) then
begin
// Set new row count
FRows := Value;
// Initialize cells
InitializeCells;
// Invalidate the buffer
InvalidateBuffer;
end;
end;
//------------------------------------------------------------------------------
// SET COLUMNS
//------------------------------------------------------------------------------
procedure TOBDMatrixDisplay.SetCols(Value: Integer);
begin
if (FCols <> Value) and (Value >= 0) then
begin
// Set new column count
FCols := Value;
// Initialize cells
InitializeCells;
// Invalidate buffer
InvalidateBuffer;
end;
end;
//------------------------------------------------------------------------------
// SET BACKGROUND
//------------------------------------------------------------------------------
procedure TOBDMatrixDisplay.SetBackground(Value: TOBDMatrixDisplayBackground);
begin
FBackground.Assign(Value);
end;
//------------------------------------------------------------------------------
// SET BORDER
//------------------------------------------------------------------------------
procedure TOBDMatrixDisplay.SetBorder(Value: TOBDMatrixDisplayBorder);
begin
FBorder.Assign(Value);
end;
//------------------------------------------------------------------------------
// SET ON COLOR
//------------------------------------------------------------------------------
procedure TOBDMatrixDisplay.SetOnColor(Value: TColor);
begin
if (FOnColor <> Value) and (Value <> clNone) then
begin
// Set new on color
FOnColor := Value;
// Invalidate buffer
InvalidateBuffer;
end;
end;
//------------------------------------------------------------------------------
// SET OFF COLOR
//------------------------------------------------------------------------------
procedure TOBDMatrixDisplay.SetOffColor(Value: TColor);
begin
if (FOffColor <> Value) and (Value <> clNone) then
begin
// Set new off color
FOffColor := Value;
// Invalidate buffer
InvalidateBuffer;
end;
end;
//------------------------------------------------------------------------------
// SET ANIMATION
//------------------------------------------------------------------------------
procedure TOBDMatrixDisplay.SetAnimation(Value: TOBDMatrixDisplayAnimation);
begin
FAnimation.Assign(Value);
end;
//------------------------------------------------------------------------------
// INITIALIZE CELLS
//------------------------------------------------------------------------------
procedure TOBDMatrixDisplay.InitializeCells;
var
R, C: Integer;
begin
// Set the length of the cells
SetLength(FCells, FRows, FCols);
// Initialize cells
for R := 0 to FRows -1 do
for C := 0 to FCols -1 do
FCells[R, C] := False;
end;
//------------------------------------------------------------------------------
// INVALIDATE BACKGROUND
//------------------------------------------------------------------------------
procedure TOBDMatrixDisplay.InvalidateBackground;
var
SS: TCustomStyleServices;
Graphics: TGPGraphics;
BackgroundRect, BorderRect, GlareRect: TGPRectF;
Brush, GlareBrush: TGPBrush;
Pen: TGPPen;
Path, GlarePath: TGPGraphicsPath;
begin
// Update the size of the background buffer
FBackgroundBuffer.SetSize(Width, Height);
// If VCL styles is available and enabled, then draw the VCL Style background
// so it matches the active style background like on the Form or a Panel.
if TStyleManager.IsCustomStyleActive then
begin
SS := StyleServices;
// Draw the styled background
SS.DrawElement(FBackgroundBuffer.Canvas.Handle, SS.GetElementDetails(twWindowRoot), Rect(0, 0, Width, Height));
end else
// Otherwise fill the background with the color.
with FBackgroundBuffer.Canvas do
begin
// Use the component color
Brush.Color := Self.Color;
// Use a solid brush
Brush.Style := bsSolid;
// Fill the background with the component color
FillRect(Rect(0, 0, Width, Height));
end;
// Initialize GDI+ Graphics object
Graphics := TGPGraphics.Create(FBackgroundBuffer.Canvas.Handle);
try
// Set smoothing mode to high-quality
Graphics.SetSmoothingMode(SmoothingModeHighQuality);
// Set compositing quality to high-quality
Graphics.SetCompositingQuality(CompositingQualityHighQuality);
// Draw the backround
if (Background.FromColor <> clNone) and (Background.ToColor <> clNone) then
begin
// Get the rectangle for the background
BackgroundRect := MakeRect(Border.Width + 0.0, Border.Width, Width - (Border.Width * 2), Height - (Border.Width * 2));
// Create the background brush
Brush := TGPLinearGradientBrush.Create(BackgroundRect, SafeColorRefToARGB(Background.FromColor), SafeColorRefToARGB(Background.ToColor), LinearGradientModeVertical);
// Get the background path
Path := CreateRoundRectPath(BackgroundRect, Border.Corner);
try
// Fill the background
Graphics.FillPath(Brush, Path);
finally
// Free the background brush object
Brush.Free;
// Free the background path
Path.Free;
end;
end;
// Draw the glare
GlareRect := MakeRect(Border.Width + 0.0, Border.Width, Width - (Border.Width * 2), Height - (Border.Width * 2));
GlarePath := CreateGlareRoundRectPath(GlareRect, Border.Corner);
GlareBrush := TGPLinearGradientBrush.Create(GlareRect, MakeColor(75, 255, 255, 255), MakeColor(30, 255, 255, 255), LinearGradientModeVertical);
try
Graphics.FillPath(GlareBrush, GlarePath);
finally
GlarePath.Free;
GlareBrush.Free;
end;
// Draw the border
if(Border.FromColor <> clNone) and (Border.ToColor <> clNone) and (Border.Width > 0) then
begin
// Get the rectangle for the border
BorderRect := MakeRect(MARGIN_FROM_BORDER, MARGIN_FROM_BORDER, Width - (MARGIN_FROM_BORDER * 2), Height - (MARGIN_FROM_BORDER * 2) + 0.0);
// Create the border brush
Brush := TGPLinearGradientBrush.Create(BorderRect, SafeColorRefToARGB(Border.FromColor), SafeColorRefToARGB(Border.ToColor), LinearGradientModeVertical);
// Create the border pen
Pen := TGPPen.Create(Brush, Border.Width);
Pen.SetAlignment(PenAlignmentInset);
// Get the border path
Path := CreateRoundRectPath(BorderRect, Border.Corner);
try
// Draw the border
Graphics.DrawPath(Pen, Path);
finally
// Free the background brush object
Brush.Free;
// Free the background pen object
Pen.Free;
// Free the border path
Path.Free;
end;
end;
finally
Graphics.Free;
end;
end;
//------------------------------------------------------------------------------
// PAINT MATRIX
//------------------------------------------------------------------------------
procedure TOBDMatrixDisplay.PaintMatrix;
procedure PaintCell(CellRect: TRect; Value: Boolean);
begin
with Buffer.Canvas do