-
Notifications
You must be signed in to change notification settings - Fork 2
/
dwread.s
344 lines (317 loc) · 15 KB
/
dwread.s
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
*******************************************************
*
* Copied from HDB-DOS from toolshed.sf.net
* The original code is public domain
*
* DWRead
* Receive a response from the DriveWire server.
* Times out if serial port goes idle for more than 1.4 (0.7) seconds.
* Serial data format: 1-8-N-1
* 4/12/2009 by Darren Atkinson
*
* Entry:
* X = starting address where data is to be stored
* Y = number of bytes expected
*
* Exit:
* CC = carry set on framing error, Z set if all bytes received
* X = starting address of data received
* Y = checksum
* U is preserved. All accumulators are clobbered
*
IFNE ARDUINO
* Note: this is an optimistic routine. It presumes that the server will always be there, and
* has NO timeout fallback. It is also very short and quick.
DWRead clra ; clear Carry (no framing error)
pshs u,x,cc ; preserve registers
leau ,x
ldx #$0000
loop@ tst $FF51 ; check for CA1 bit (1=Arduino has byte ready)
bpl loop@ ; loop if not set
ldb $FF50 ; clear CA1 bit in status register
stb ,u+ ; save off acquired byte
abx ; update checksum
leay ,-y
bne loop@
leay ,x ; return checksum in Y
puls cc,x,u,pc ; restore registers and return
ELSE
IFNE JMCPBCK
* NOTE: There is no timeout currently on here...
DWRead clra ; clear Carry (no framing error)
deca ; clear Z flag, A = timeout msb ($ff)
tfr cc,b
pshs u,x,dp,b,a ; preserve registers, push timeout msb
leau ,x
ldx #$0000
IFEQ NOINTMASK
orcc #IntMasks
ENDC
loop@ ldb $FF4C
bitb #$02
beq loop@
ldb $FF44
stb ,u+
abx
leay ,-y
bne loop@
tfr x,y
ldb #0
lda #3
leas 1,s ; remove timeout msb from stack
inca ; A = status to be returned in C and Z
ora ,s ; place status information into the..
sta ,s ; ..C and Z bits of the preserved CC
leay ,x ; return checksum in Y
puls cc,dp,x,u,pc ; restore registers and return
ELSE
IFNE BECKER
IFNDEF BCKSTAT
BCKSTAT equ $FF41
ENDC
IFNDEF BCKPORT
BCKPORT equ $FF42
ENDC
* NOTE: There is no timeout currently on here...
DWRead pshs dp,x,u ; preserve registers, push timeout msb
ldd #(60*256)+$ff ; A = timeout of 1+ sec, B = new DP
tfr b,dp ; set DP
tfr x,u ; U = data pointer
ldx #$0000 ; X = chksum
IFEQ NOINTMASK
orcc #IntMasks
ENDC
loop@ tst <$ff03 ; test for vsync
bpl a@ ; no vsync continue
tst <$ff02 ; clear vsync flag
deca ; dec timeout
bne a@ ; not timeout continue
;; return w/ timeout!
inca ; A was zero so inc to clear Z (timeout)
puls dp,x,u,pc ; restore return
;; no timeout continue checking for data
a@ ldb <BCKSTAT
bitb #$02
beq loop@
ldb <BCKPORT
stb ,u+
abx
leay ,-y
bne loop@
;; return w/ ok!
tfr x,y ; make y = cksum
clra ; set Z (no timeout), clear carry (no framing errors possible)
puls dp,x,u,pc ; restore registers and return
ENDC
ENDC
ENDC
IFEQ BECKER+JMCPBCK+ARDUINO
IFNE BAUD38400
*******************************************************
* 38400 bps using 6809 code and timimg
*******************************************************
DWRead clra ; clear Carry (no framing error)
deca ; clear Z flag, A = timeout msb ($ff)
tfr cc,b
pshs u,x,dp,b,a ; preserve registers, push timeout msb
IFEQ NOINTMASK
orcc #IntMasks ; mask interrupts
ENDC
tfr a,dp ; set direct page to $FFxx
setdp $ff
leau ,x ; U = storage ptr
ldx #0 ; initialize checksum
adda #2 ; A = $01 (serial in mask), set Carry
* Wait for a start bit or timeout
rx0010 bcc rxExit ; exit if timeout expired
ldb #$ff ; init timeout lsb
rx0020 bita <BBIN ; check for start bit
beq rxByte ; branch if start bit detected
subb #1 ; decrement timeout lsb
bita <BBIN
beq rxByte
bcc rx0020 ; loop until timeout lsb rolls under
bita <BBIN
beq rxByte
addb ,s ; B = timeout msb - 1
bita <BBIN
beq rxByte
stb ,s ; store decremented timeout msb
bita <BBIN
bne rx0010 ; loop if still no start bit
* Read a byte
rxByte leay ,-y ; decrement request count
ldd #$ff80 ; A = timeout msb, B = shift counter
sta ,s ; reset timeout msb for next byte
rx0030 exg a,a
nop
lda <BBIN ; read data bit
lsra ; shift into carry
rorb ; rotate into byte accumulator
lda #$01 ; prep stop bit mask
bcc rx0030 ; loop until all 8 bits read
stb ,u+ ; store received byte to memory
abx ; update checksum
ldb #$ff ; set timeout lsb for next byte
anda <BBIN ; read stop bit
beq rxExit ; exit if framing error
leay ,y ; test request count
bne rx0020 ; loop if another byte wanted
lda #$03 ; setup to return SUCCESS
* Clean up, set status and return
rxExit leas 1,s ; remove timeout msb from stack
inca ; A = status to be returned in C and Z
ora ,s ; place status information into the..
sta ,s ; ..C and Z bits of the preserved CC
leay ,x ; return checksum in Y
puls cc,dp,x,u,pc ; restore registers and return
setdp $00
ELSE
IFNE H6309
*******************************************************
* 57600 (115200) bps using 6309 native mode
*******************************************************
DWRead clrb ; clear Carry (no framing error)
decb ; clear Z flag, B = $FF
pshs u,x,dp,cc ; preserve registers
IFEQ NOINTMASK
orcc #IntMasks ; mask interrupts
ENDC
* ldmd #1 ; requires 6309 native mode
tfr b,dp ; set direct page to $FFxx
setdp $ff
leay -1,y ; adjust request count
leau ,x ; U = storage ptr
tfr 0,x ; initialize checksum
lda #$01 ; A = serial in mask
bra rx0030 ; go wait for start bit
* Read a byte
rxByte sexw ; 4 cycle delay
ldw #$006a ; shift counter and timing flags
clra ; clear carry so next will branch
rx0010 bcc rx0020 ; branch if even bit number (15 cycles)
nop ; extra (16th) cycle
rx0020 lda <BBIN ; read bit
lsra ; move bit into carry
rorb ; rotate bit into byte accumulator
lda #0 ; prep A for 8th data bit
lsrw ; bump shift count, timing bit to carry
bne rx0010 ; loop until 7th data bit has been read
incw ; W = 1 for subtraction from Y
inca ; A = 1 for reading bit 7
anda <BBIN ; read bit 7
lsra ; move bit 7 into carry, A = 0
rorb ; byte is now complete
stb ,u+ ; store received byte to memory
abx ; update checksum
subr w,y ; decrement request count
inca ; A = 1 for reading stop bit
anda <BBIN ; read stop bit
bls rxExit ; exit if completed or framing error
* Wait for a start bit or timeout
rx0030 clrw ; initialize timeout counter
rx0040 bita <BBIN ; check for start bit
beq rxByte ; branch if start bit detected
addw #1 ; bump timeout counter
bita <BBIN
beq rxByte
bcc rx0040 ; loop until timeout rolls over
lda #$03 ; setup to return TIMEOUT status
* Clean up, set status and return
rxExit beq rx0050 ; branch if framing error
eora #$02 ; toggle SUCCESS flag
rx0050 inca ; A = status to be returned in C and Z
ora ,s ; place status information into the..
sta ,s ; ..C and Z bits of the preserved CC
leay ,x ; return checksum in Y
puls cc,dp,x,u,pc ; restore registers and return
setdp $00
ELSE
*******************************************************
* 57600 (115200) bps using 6809 code and timimg
*******************************************************
DWRead clra ; clear Carry (no framing error)
deca ; clear Z flag, A = timeout msb ($ff)
tfr cc,b
pshs u,x,dp,b,a ; preserve registers, push timeout msb
IFEQ NOINTMASK
orcc #IntMasks ; mask interrupts
ENDC
tfr a,dp ; set direct page to $FFxx
;setdp $ff
leau ,x ; U = storage ptr
ldx #0 ; initialize checksum
lda #$01 ; A = serial in mask
bra rx0030 ; go wait for start bit
* Read a byte
rxByte leau 1,u ; bump storage ptr
leay ,-y ; decrement request count
lda <BBIN ; read bit 0
lsra ; move bit 0 into Carry
ldd #$ff20 ; A = timeout msb, B = shift counter
sta ,s ; reset timeout msb for next byte
rorb ; rotate bit 0 into byte accumulator
rx0010 lda <BBIN ; read bit (d1, d3, d5)
lsra
rorb
bita 1,s ; 5 cycle delay
bcs rx0020 ; exit loop after reading bit 5
lda <BBIN ; read bit (d2, d4)
lsra
rorb
leau ,u
bra rx0010
rx0020 lda <BBIN ; read bit 6
lsra
rorb
leay ,y ; test request count
beq rx0050 ; branch if final byte of request
lda <BBIN ; read bit 7
lsra
rorb ; byte is now complete
stb -1,u ; store received byte to memory
abx ; update checksum
lda <BBIN ; read stop bit
anda #$01 ; mask out other bits
beq rxExit ; exit if framing error
* Wait for a start bit or timeout
rx0030 bita <BBIN ; check for start bit
beq rxByte ; branch if start bit detected
bita <BBIN ; again
beq rxByte
ldb #$ff ; init timeout lsb
rx0040 bita <BBIN
beq rxByte
subb #1 ; decrement timeout lsb
bita <BBIN
beq rxByte
bcc rx0040 ; loop until timeout lsb rolls under
bita <BBIN
beq rxByte
addb ,s ; B = timeout msb - 1
bita <BBIN
beq rxByte
stb ,s ; store decremented timeout msb
bita <BBIN
beq rxByte
bcs rx0030 ; loop if timeout hasn't expired
bra rxExit ; exit due to timeout
rx0050 lda <BBIN ; read bit 7 of final byte
lsra
rorb ; byte is now complete
stb -1,u ; store received byte to memory
abx ; calculate final checksum
lda <BBIN ; read stop bit
anda #$01 ; mask out other bits
ora #$02 ; return SUCCESS if no framing error
* Clean up, set status and return
rxExit leas 1,s ; remove timeout msb from stack
inca ; A = status to be returned in C and Z
ora ,s ; place status information into the..
sta ,s ; ..C and Z bits of the preserved CC
leay ,x ; return checksum in Y
puls cc,dp,x,u,pc ; restore registers and return
;setdp $00
ENDC
ENDC
ENDC