-
Notifications
You must be signed in to change notification settings - Fork 13
/
StylesheetEdit.wl
executable file
·1760 lines (1512 loc) · 36.5 KB
/
StylesheetEdit.wl
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
(* ::Package:: *)
(* ::Title:: *)
(*StyleSheetEdit*)
BeginPackage["StyleSheetEdit`"]
StyleSheetCells::usage=
"Gets the cells in the current stylesheet that match a given style.
Styles can be specified by a String, Symbol, or StyleData expression or a list thereof";
StyleSheetEdit::usage=
"Applies the options given to the given cell styles in the given notebook";
StyleSheetNew::usage=
"Creates a new style cell with a given name and optional parent style and options";
StyleSheetDelete::usage="Deletes all matching style cells";
(* ::Subsection:: *)
(*Undocumented*)
BeginPackage["`Undocumented`"];
(* ::Subsubsection::Closed:: *)
(*Styles*)
$StyleSheetTitleCellStyles::usage="The styles that are section-like";
$StyleSheetSectionCellStyles::usage="The styles that are section-like";
$StyleSheetIOCellStyles::usage="The styles that are code-like";
$StyleSheetTextCellStyles::usage="The styles that are text-like";
$StyleSheetCellDisplayStyleOptions::usage=
"A listing of cell style options to make two cells look the same";
(* ::Subsubsection::Closed:: *)
(*New*)
StyleSheetOpen::usage="Opens the style definitions notebook for a given notebook";
StyleSheetTemplate::usage=
"Creates a stylesheet editing template
-Create in the current document by default
-Opens a new one when passed Notebook[<ssname>] as the first argument";
StyleSheetUpdate::usage="StyleSheetDelete + StyleSheetNew";
StyleSheetDefaultStyles::usage="Sets a default styling cascade";
(* ::Subsubsection::Closed:: *)
(*Notebook*)
$DefaultStyleSheetNotebook::usage=
"Default.nb hidden notebook";(*
StyleSheetNotebookFind::usage=
"Finds the notebook for a given stylesheet";*)
StyleSheetNotebookObject::usage=
"The style notebook object for editing a given notebook";
StyleSheetParentNotebook::usage=
"Returns the NotebookObject that stores the styles of a given NotebookObject";
StyleSheetNotebookGet::usage=
"NotebookGets the StyleSheetParentNotebook";
StyleSheetStyles::usage=
"Gets the styles from a stylesheet";
(* ::Subsubsection::Closed:: *)
(*Edit*)
StyleSheetApplyEdits::usage=
"Applies the edits from StyleSheetEdit";
StyleSheetDrop::usage"Drops the options given from the given cell styles in the given notebook";
StyleSheetValue::usage=
"Gets the value of a style option for a cell style";
StyleSheetSync::usage="Copies style options from one style to another";
StyleSheetEditEvents::usage=
"Edits the \[Star]EventActions";
StyleSheetEditAliases::usage=
"Edits the InputAliases";
StyleSheetEditAutoReplacements::usage=
"Edits the InputAutoReplacements";
StyleSheetEditTaggingRules::usage=
"Edits the TaggingRules";
(* ::Subsubsection::Closed:: *)
(*Style Attributes*)
StyleDefinitionsValue::usage="experimental";
(* ::Subsubsection:: *)
(*End Undocumented*)
EndPackage[];
(* ::Section:: *)
(*Private*)
Begin["`Private`"];
(* ::Subsubsection::Closed:: *)
(*frontEndExecuteBlock*)
If[!ValueQ[$frontEndExecuteBlock],
$frontEndExecuteBlock=False;
$frontEndExecuteBlock//Protect
]
frontEndExecuteSow[e_]:=
Sow[e, "FrontEndExecute"];
frontEndExecuteRouter[a_,b_]:=
If[$frontEndExecuteBlock,
frontEndExecuteSow[a],
b
];
frontEndExecuteRouter~SetAttributes~HoldAllComplete;
frontEndExecuteBlock[e_]/;!TrueQ[$frontEndExecuteBlock]:=
Block[{$frontEndExecuteBlock=True},
With[{rd=Reap[e,"FrontEndExecute"]},
Replace[rd[[2]],
{a:{__}}:>
If[MemberQ[a, _Hold],
MathLink`CallFrontEndHeld@@
Append[
Thread[Replace[a, h:Except[_Hold]:>Hold[h]],Hold],
System`FrontEndDump`NoResult
],
MathLink`CallFrontEnd[a, System`FrontEndDump`NoResult]
]
];
rd[[1]]
]
];
frontEndExecuteBlock[e_]/;TrueQ[$frontEndExecuteBlock]:=e;
frontEndExecuteBlock~SetAttributes~HoldAllComplete;
(* ::Subsubsection::Closed:: *)
(*Styles*)
$StyleSheetTitleCellStyles={"Title","Chapter","Subchapter"};
$StyleSheetSectionCellStyles={"Section","Subsection","Subsubsection","Subsubsubsection"};
$StyleSheetIOCellStyles={"Input","Code","Output"};
$StyleSheetTextCellStyles={"Text","Item","ItemParagraph","Subitem","SubitemParagraph"};
$StyleSheetCellTextStyleOptions=
{
FontSize,
FontColor,
FontSlant,
FontWeight,
TabSpacings
};
Off[General::shdw];
System`CellFrameStyle;
System`GroupOpenerColor;
System`GroupOpenerInsideFrame;
On[General::shdw];
$StyleSheetCellFrameStyleOptions=
{
CellFrame,
Background,
CellFrameColor,
System`CellFrameStyle
};
$StyleSheetCellSpacingStyleOptions=
{
CellMargins,
CellFrameMargins
};
$StyleSheetCellDisplayStyleOptions:=
Join[
$StyleSheetCellTextStyleOptions,
$StyleSheetCellFrameStyleOptions,
$StyleSheetCellSpacingStyleOptions
];
(* ::Subsubsection::Closed:: *)
(*StyleSheetNotebookFind*)
ssFENotebooks[f_String?FileExistsQ]:=
List@SelectFirst[FrontEndExecute@FrontEnd`ObjectChildren[$FrontEnd],
Quiet@NotebookFileName@#===f&
];
ssFENotebooks[Optional["*","*"]]:=
FrontEndExecute@FrontEnd`ObjectChildren[$FrontEnd];
ssFENotebooks[pat:Except["*"|_String?FileExistsQ]]:=
Select[FrontEndExecute@FrontEnd`ObjectChildren[$FrontEnd],
Replace[Quiet@NotebookFileName@#,{
s_String:>
StringMatchQ[s,pat],
_->False
}
]||
Replace[Quiet@NotebookFileName@#,{
s_String:>
FileBaseName@StringMatchQ[s,pat],
_->False
}
]||
StringMatchQ[
WindowTitle/.AbsoluteOptions[#,WindowTitle],
pat
]&
]
StyleSheetNotebookFind//Clear
StyleSheetNotebookFind[name:_String|{__String}|_FrontEnd`FileName]:=
Replace[
FrontEndExecute@
FrontEnd`FindFileOnPath[
StringTrim[
Replace[name,
{
l_List:>FileNameJoin[l],
f_FrontEnd`FileName:>ToFileName[f]
}
],
".nb"
]<>".nb",
"StyleSheetPath"
],
{
f_String?FileExistsQ:>
Replace[
ssFENotebooks@f,
{
{}->Missing["NotFound"],
{nb_}:>nb
}
],
_->Missing["FileNotFound"]
}
];
$DefaultStyleSheetNotebook:=
StyleSheetNotebookFind["Default"]
(* ::Subsubsection::Closed:: *)
(*ParentNotebook*)
ssFileName[file_]:=
FrontEndExecute@
FrontEnd`FindFileOnPath[
StringTrim[
Replace[file,
{
l_List:>FileNameJoin[l],
f_FrontEnd`FileName:>ToFileName[f]
}
],
".nb"
]<>".nb",
"StyleSheetPath"
]
ssNotebookInformationNotebook[nb_]:=
Replace[
Lookup[
Replace[NotebookInformation[nb], Except[_?OptionQ]->{}],
"StyleDefinitions"
],
{n_NotebookObject,___}:>n
]
StyleSheetNotebookFileName[nb_NotebookObject]:=
Replace[
CurrentValue[nb,StyleDefinitions],
{
f:_String|_FrontEnd`FileName:>
ssFileName[f],
_Notebook:>
Missing["NotAvailable"]
}
];
If[!AssociationQ@$ssNbObjCache,
$ssNbObjCache=<||>
];
StyleSheetParentNotebook[nb_NotebookObject]:=
Replace[
Replace[ssNotebookInformationNotebook[nb],
Except[_NotebookObject?(NotebookInformation@#===$Failed&)]:>
Lookup[$ssNbObjCache, nb]
],
{
_Missing|_NotebookObject?(NotebookInformation@#===$Failed&):>
Set[$ssNbObjCache[nb],
First@
Lookup[
Replace[NotebookInformation[nb], Except[_?OptionQ]->{}],
"StyleDefinitons",
{
Replace[StyleSheetNotebookFileName[nb],{
f_String:>
Replace[ssFENotebooks[f],{
{}:>Missing["NotFound"],
{n_,___}:>n
}],
_Missing:>
With[{n=CurrentValue[nb,StyleDefinitions]},
SelectFirst[ssFENotebooks[],
NotebookGet@#===n&]
]
}]
}
]
]
}
];
StyleSheetParentNotebook[name:_String|{__String}|_FrontEnd`FileName]:=
Replace[StyleSheetNotebookFind[name],
nb_NotebookObject:>StyleSheetParentNotebook[nb]
]
StyleSheetParentNotebook/:
HoldPattern[Unset[StyleSheetParentNotebook[nb_NotebookObject]]]:=
$ssNbObjCache[nb]=.;
StyleSheetParentNotebook/:
HoldPattern[Unset[StyleSheetParentNotebook[nb:EvaluationNotebook[]|InputNotebook[]]]]:=
With[{n=nb},
Unset[StyleSheetParentNotebook[n]]
];
StyleSheetParentNotebook/:
HoldPattern[Set[StyleSheetParentNotebook[nb_NotebookObject],n_NotebookObject]]:=
$ssNbObjCache[nb]=n;
StyleSheetParentNotebook/:
HoldPattern[
Set[StyleSheetParentNotebook[nb:EvaluationNotebook[]|InputNotebook[]],
n_NotebookObject]
]:=
With[{e=nb},
Set[StyleSheetParentNotebook[e],n]
];
StyleSheetParentNotebook/:
HoldPattern[SetDelayed[StyleSheetParentNotebook[nb_NotebookObject],n_]]:=
$ssNbObjCache[nb]:=n;
StyleSheetParentNotebook/:
HoldPattern[
SetDelayed[StyleSheetParentNotebook[nb:EvaluationNotebook[]|InputNotebook[]],
n_]
]:=
With[{e=nb},
SetDelayed[StyleSheetParentNotebook[e],n]
];
(* ::Subsubsection::Closed:: *)
(*NotebookGet*)
StyleSheetNotebookGet[nb_NotebookObject]:=
NotebookGet@StyleSheetParentNotebook@nb;
StyleSheetNotebookGet[Optional[Automatic,Automatic]]:=
StyleSheetNotebookGet@EvaluationNotebook[];
(* ::Subsubsection::Closed:: *)
(*NotebookObject*)
StyleSheetNotebookObject[nb:_NotebookObject|Automatic:Automatic]:=
With[{e=Replace[nb,Automatic:>EvaluationNotebook[]]},
Replace[CurrentValue[e,StyleDefinitions],{
"StylesheetFormatting.nb"|"PrivateStylesheetFormatting.nb"|
Notebook[{___,
Cell[
StyleData[
StyleDefinitions->
("PrivateStylesheetFormatting.nb"|"StylesheetFormatting.nb")
],
___],
___
},
___
]->e,
s:_String|_FrontEnd`FileName:>
(
SetOptions[e,
StyleDefinitions->
Notebook[{Cell[StyleData[StyleDefinitions->s]]},
StyleDefinitions->
("PrivateStylesheetFormatting.nb")
]
];
$ssNbObjCache[e]=.;
StyleSheetParentNotebook[e]
),
_:>
StyleSheetParentNotebook[e]
}]
];
StyleSheetNotebookObject[name:_String|{__String}|_FrontEnd`FileName]:=
Replace[StyleSheetNotebookFind[name],
nb_NotebookObject:>StyleSheetNotebookObject[nb]
]
(* ::Subsubsection::Closed:: *)
(*StyleSheetTemplate*)
StyleSheetTemplate[newNB:_Notebook|_NotebookObject|None:None,
defaultStyle:_DefaultStyle:DefaultStyle["Default.nb"],
styles:(_String|_Directive)...,
ops:_Rule|_RuleDelayed...
]:=With[{nb=Replace[newNB,{
_Notebook:>
CreateDocument["",
ops,
WindowTitle->First@newNB,
StyleDefinitions->
Notebook[{
Cell[StyleData[StyleDefinitions->"StylesheetFormatting.nb"]],
Cell[StyleData["Notebook"],
Saveable->True,
Editable->True
]
}],
Saveable->True],
None:>Automatic
}]},
StyleSheetNew[nb,defaultStyle,Next];
Do[
StyleSheetNew[nb,##]&@@If[MatchQ[s,_Directive],s,{s}],
{s,{styles}}];
Replace[nb,Automatic:>Null]
];
StyleSheetTemplate[
newNB:_Notebook|_NotebookObject|None:None,
defaultStyle:_DefaultStyle:DefaultStyle["Default.nb"],
Default]:=
StyleSheetTemplate[newNB,defaultStyle,
"Notebook",
"Title","Chapter","Subchapter",
"Section","Subsection","Subsubsection",
"Text","Code","Input",
"Item","ItemParagraph"
];
(* ::Subsubsection::Closed:: *)
(*StyleSheetOpen*)
StyleSheetOpen[nb:_NotebookObject|Automatic:Automatic]:=
With[{notebook=Replace[nb,Automatic:>StyleSheetNotebookObject[]]},
(*FrontEndTokenExecute@"EditStyleDefinitions";*)
Replace[
StyleDefinitions/.Options[notebook,StyleDefinitions],{
s:(_String|_FrontEnd`FileName):>
SystemOpen@s,
n:(_Notebook):>
CreateDocument[n,
WindowTitle->"StyleDefintions for "<>FileNameTake@NotebookFileName[notebook]]
}
]
];
(* ::Subsubsection::Closed:: *)
(*StyleSheetDefaultStyles*)
StyleSheetDefaultStyles[
nb:_NotebookObject|Automatic:Automatic,
styles__String]:=
With[{sList={styles}},
Do[
StyleSheetEdit[nb,sList[[i]],DefaultNewCellStyle->sList[[i+1]]],
{i,Length@sList-1}
]
];
(* ::Subsubsection::Closed:: *)
(*StyleSheetStyleData*)
ssNormalizeStyleName[s_String]:=
Replace[StringSplit[s, "/"],
{
{n_}:>n,
{n__}:>StyleData[n]
}
];
ssNormalizeStyleName[e_]:=e
iStyleSheetStyleData[canonicalStyles_]:=
Replace[
canonicalStyles,
{
(Rule|RuleDelayed)[s_String, p_String]:>
StyleData[s, StyleDefinitions->StyleData[p]],
(Rule|RuleDelayed)[{s__String},p_String]:>
StyleData[s, StyleDefinitions->StyleData[p]],
(Rule|RuleDelayed)[s_String,{p__String}]:>
StyleData[s, StyleDefinitions->StyleData[p]],
(Rule|RuleDelayed)[{s__String}, {p__String}]:>
StyleData[s, StyleDefinitions->StyleData[p]],
e_:>
StyleData[e]
},
1
]//.{
(Rule|RuleDelayed)[name:Except[StyleDefinitions],env_]:>
StyleData@@Flatten@{name,env}
}//.{
DefaultStyle[f__]:>(
StyleDefinitions->
Replace[{f},{
{s_String}:>
StringTrim[s,".nb"]<>".nb",
{path__,name_}:>
FrontEnd`FileName[{path},
Evaluate[StringTrim[name,".nb"]<>".nb"]],
{e_}:>
e
}]
),
StyleData[a___, StyleData[b___], c___]:>
StyleData[a,b,c]
};
StyleSheetStyleData[styleNames_]:=
iStyleSheetStyleData@Flatten@
Replace[
ssNormalizeStyleName/@Flatten[{styleNames}, 1],
{
(h:Rule|RuleDelayed)[s_List,e_]:>
Map[Thread[h[#,e]]&,s],
(h:Rule|RuleDelayed)[s_,e_List]:>
Map[Thread[h[s,#]]&,e]
},
1
];
(* ::Subsubsection::Closed:: *)
(*StyleSheetCells*)
$StyleSheetCellStyleBaseStylePattern=
All|_String|_StyleData|_Verbatim|Default;
$StyleSheetCellStyleSubStylePattern=
$StyleSheetCellStyleBaseStylePattern|{$StyleSheetCellStyleBaseStylePattern..}->
$StyleSheetCellStyleBaseStylePattern|{$StyleSheetCellStyleBaseStylePattern..};
$StyleSheetCellStyleSinglePattern=
$StyleSheetCellStyleBaseStylePattern|
$StyleSheetCellStyleSubStylePattern|
_?StringPattern`StringPatternQ
$StyleSheetCellStylePatterns=
$StyleSheetCellStyleSinglePattern|{$StyleSheetCellStyleSinglePattern..};
cellTypeMatchQ//Clear
cellTypeMatchQ[type:_String|All, types_]:=
Which[
types==={"*"},
True,
types==={},
False,
MatchQ[types, StyleData[_]],
cellTypeMatchQ[type, First@types],
StringPattern`StringPatternQ[type],
StringMatchQ[type,
Alternatives@@
Select[Flatten@List@types, StringPattern`StringPatternQ]
],
True,
MemberQ[
Replace[types,
{s_, "*"..}:>{s},
1
],
type
]
];
cellTypeMatchQ[type_Symbol, "*"]:=True;
cellTypeMatchQ[type:Except[_String],_]:=False;
cellTypeMatchQ[types_][type_]:=cellTypeMatchQ[type,types];
cellStyleMovingMatchQ[s_, types_]:=
With[{styleDatas=
Replace[
Cases[Flatten@{types}, _StyleData|_Verbatim],
{
HoldPattern[Verbatim][d_StyleData]:>
If[Length@d!=Length@s,
Nothing,
List@@d
],
HoldPattern[Verbatim][e_]:>
If[Length@s!=1,
Nothing,
{e}
],
d_StyleData:>
If[Length@d>Length@s,
Nothing,
Join[
List@@d,
ConstantArray["*", Max@{Length@s-Length@d,0}]
]
]
},
1]
},
AnyTrue[
styleDatas,
And@@MapThread[cellTypeMatchQ, {List@@s,#}]&
]
]
cellStyleNameMatchQ[
s_StyleData,
types_
]:=
types=!={}&&
If[Length@s==1,
cellTypeMatchQ[First@s,
First/@Select[types, Length@#==1&]
],
Length@s>0&&
(
cellTypeMatchQ[
First@s,
First/@Select[types, Length@#==1&]
]||
cellStyleMovingMatchQ[s, types]
)
];
cellStyleDataMatchQ[s_StyleData, types_]:=
With[
{
matchData=
DeleteCases[s, Except[_String|_Symbol|_?StringPattern`StringPatternQ]]
},
MatchQ[matchData,
Alternatives@@
Replace[
Flatten@{types},
{
DefaultStyle[d_]:>
StyleData[StyleDefinitions->d],
DefaultStyle[p_List, f_String]:>
StyleData[StyleDefinitions->FrontEnd`FileName[{p},f]],
DefaultStyle[a__,b_]:>
StyleData[StyleDefinitions->StyleData[a,b]]
},
1
]
]||
cellStyleNameMatchQ[matchData, types]
];
cellStyleDataMatchQ[types_][s_]:=
cellStyleDataMatchQ[s, types];
cellMatchQ[cell_, types_, Optional[StyleData,StyleData]]:=
Replace[
cell,
{
Cell[_, _String, ___]:>
False,
Cell[
If[types===Default,
StyleData[StyleDefinitions->_,___],
_StyleData?(cellStyleDataMatchQ[types])
],
___
]:>
True,
Cell[
_?(
MatchQ[
Replace[#,
_BoxData:>ToExpression[#,StandardForm,Hold]
],
If[types===Default,
StyleData[StyleDefinitions->_,___],
_StyleData?(cellStyleDataMatchQ[types])
]
]&
),
___
]:>
True,
_->
False
}
];
cellMatchQ[cell_,types_,Normal]:=
Replace[
cell,
{
Cell[_, _?(cellTypeMatchQ[types]), ___]:>
True,
_:>
False
}
];
cellMatchQ[cell_,types_,_]:=False
stylesheetNotebook[nb_,file_String?FileExistsQ]:=Get@file;
stylesheetNotebook[nb_,file_FrontEnd`FileName]:=Get@ToFileName@file;
stylesheetNotebook[nb_NotebookObject,file_String]:=
stylesheetNotebook[NotebookGet@nb,Quiet@NotebookDirectory@nb,file];
stylesheetNotebook[
nb_Notebook,
dir:(_String?DirectoryQ|Automatic|$Failed):Automatic,
file_String]:=
With[{testDir=
Replace[Quiet@NotebookDirectory@nb,
_NotebookDirectory|$Failed:>
Replace[dir,$Failed|Automatic:>$UserDocumentsDirectory]
]},
If[FileExistsQ@FileNameJoin@{testDir,file},
Get@FileNameJoin@{testDir,file},
Replace[Cases[Flatten@Table[
FileNames["*",FileNameJoin@{d,"FrontEnd","Stylesheets"}],
{d,
FileNames["*",{
FileNameJoin@{$UserBaseDirectory,"Applications"},
$InstallationDirectory
}]
}],
s_?(FileNameTake@#===file&):>s],
{
{}:>$Failed,
{s_,___}:>Get@s
}
]
]
];
ssMakeEnvDatas[typeData_]:=
Replace[
ssNormalizeStyleName/@Flatten@List@typeData,
(a_->b_):>
StyleData[
Sequence@@Flatten@{a},
StyleDefinitions->
StyleData[Sequence@@Flatten@{b}]
],
1
];
StyleSheetCells//Clear
Options[StyleSheetCells]={
"MakeCell"->False,
"SelectMode"->StyleData,
"DetectStylesheet"->True
};
StyleSheetCells[
nb:_Notebook|_NotebookObject|Automatic:Automatic,
typeData:$StyleSheetCellStylePatterns|{},
ops:OptionsPattern[]
]:=
With[{
make=TrueQ@OptionValue["MakeCell"],
mode=
Replace[
OptionValue["SelectMode"],
Except[Normal|StyleData]->StyleData
],
types=
DeleteCases[#, _Rule]&/@StyleSheetStyleData[typeData]
},
Replace[
Select[
(* get the CellObjects against which to match *)
Replace[
If[TrueQ@OptionValue["DetectStylesheet"],
StyleSheetNotebookObject[nb],
Replace[nb, Automatic:>EvaluationNotebook[]]
],
{
n_NotebookObject:>Cells[n],
n_Notebook:>(First@NotebookTools`FlattenCellGroups[n])
}
],
cellMatchQ[Replace[#,c_CellObject:>NotebookRead@c], types, mode]&
],
{
l_List:>
If[mode===StyleData&&make,
(* if there were styles that weren't found, make them *)
With[
{missingStyles=
Select[
Cases[Flatten[{types},1], _StyleData|_String],
With[{c=NotebookRead/@l},
With[{s=#},
Not@AnyTrue[c, cellMatchQ[#, s, StyleData]&]
]&
]
]
},
StyleSheetNew[nb, missingStyles];
Join[
StyleSheetCells[nb,
missingStyles,
"MakeCell"->False,
ops
],
l
]
],
l]
}
]
];
(* ::Subsubsection::Closed:: *)
(*StyleSheetNew*)
$StyleSheetNewCellStyles=
$StyleSheetCellStylePatterns;
$StyleSheetNewParentStyles=
_FrontEnd`FileName|_String|_StyleData|None|
{(_FrontEnd`FileName|_String|_StyleData|None)..};
Options[StyleSheetNew]=
DeleteDuplicatesBy[
Join[
Options[Cell],
Options[Notebook],
Options[NotebookWrite],
{
"DetectStylesheet"->True
}
],
First];
StyleSheetNew[
nb:_NotebookObject|Automatic:Automatic,
type:$StyleSheetNewCellStyles,
placement:Next|First|Last|Automatic:Automatic,
ops:OptionsPattern[]
]:=
With[{
ec=EvaluationCell[],
notebook=
If[TrueQ@OptionValue["DetectStylesheet"],
StyleSheetNotebookObject[nb],
Replace[nb, Automatic:>EvaluationNotebook[]]
],
position=
Replace[placement,
Automatic:>Replace[type,{_DefaultStyle->First,_->Next}]],
styleDecs=
StyleSheetStyleData[type]
},
Switch[position,
First,SelectionMove[notebook,Before,Notebook],
Next,SelectionMove[notebook,After,Cell],
Last,SelectionMove[notebook,After,Notebook]
];
NotebookWrite[notebook,
Cell[#,
Sequence@@FilterRules[{ops},
Except[Alternatives@@Map[First,Options[NotebookWrite]]]
]
],
Sequence@@FilterRules[{ops},Options@NotebookWrite]
]&/@styleDecs;
];
(* ::Subsubsection::Closed:: *)
(*StyleSheetDelete*)
StyleSheetDelete[
nb:_NotebookObject|Automatic:Automatic,
type:_String|_List|_DefaultStyle]:=
Replace[StyleSheetCells[nb,type],{
c:{__CellObject}:>
NotebookDelete@c
}];
(* ::Subsubsection::Closed:: *)
(*StylesheetNotebook*)
StylesheetNotebook[nb:_Notebook|_NotebookObject|Automatic:Automatic]:=
With[{n=Replace[nb,Automatic:>StyleSheetNotebookObject[]]},
Module[{styleDefs=StyleDefinitions/.Options[n,StyleDefinitions],
parentNB,extraStyles},
parentNB=
Replace[styleDefs,
sd_Notebook:>
Replace[StyleSheetCells[sd,Default],
{
{___,c_}:>Last@First@First@c,
{}->Notebook[{}]
}]
];
extraStyles=
Replace[styleDefs,{
sd_Notebook:>StyleSheetCells[sd],
_:>{}
}];
If[MatchQ[parentNB,_String|_FrontEnd`FileName],
parentNB=
Replace[
stylesheetNotebook[n,parentNB],
s_String:>Get@s
];
parentNB
];
Replace[
NotebookTools`FlattenCellGroups@parentNB,{
Notebook[cells_List,o___]:>
With[{styleNB=Notebook[Flatten@{cells,extraStyles}]},
Notebook[Join[
StyleSheetCells[styleNB,Default],
StyleSheetCells[styleNB]],
o]
],
_->parentNB
}
]
]
];
(* ::Subsubsection::Closed:: *)
(*Styles*)
StyleSheetStyles[nb:_Notebook|_NotebookObject|Automatic:Automatic]:=
Module[
{defaultCells=StyleSheetCells[nb,Default]},
{
With[{n=StylesheetNotebook@nb},
defaultCells={
defaultCells,
If[n=!=$Failed,StyleSheetCells[n,Default],{}]};
Cases[
If[n=!=$Failed,
StyleSheetCells[n],
{}],