forked from Dushistov/flapigen-rs
-
Notifications
You must be signed in to change notification settings - Fork 0
/
build.gradle
125 lines (106 loc) · 5.13 KB
/
build.gradle
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
apply plugin: 'com.android.application'
apply from: "./dotenv.gradle"
android {
compileSdkVersion 28
buildToolsVersion "28.0.3"
defaultConfig {
applicationId "net.akaame.myapplication"
minSdkVersion 21
targetSdkVersion 28
versionCode 1
versionName "1.0.1"
testInstrumentationRunner "android.support.test.runner.AndroidJUnitRunner"
}
sourceSets {
main {
jni.srcDirs += []
jniLibs.srcDirs += ['libs']
}
}
buildTypes {
release {
minifyEnabled true
shrinkResources true
proguardFiles getDefaultProguardFile('proguard-android.txt'), 'proguard-rules.pro'
}
}
applicationVariants.all { variant ->
def buildType = variant.buildType.name // Sets the current build type
println("\n============================== buildType : ${buildType} ==============================\n")
// ANCHOR:cargo
def rustBasePath = ".."
def archTriplets = [
'armeabi-v7a': 'armv7-linux-androideabi',
'arm64-v8a' : 'aarch64-linux-android',
'x86_64' : 'x86_64-linux-android',
]
def libName = "mobcore"
buildConfigField("String", "RUST_LIB_NAME", "\"${libName}\"")
archTriplets.each { arch, target ->
// execute cargo metadata and get path to target directory
tasks.create(name: "cargo-output-dir-${arch}-${buildType}", description: "Get cargo metadata") {
new ByteArrayOutputStream().withStream { os ->
exec {
commandLine 'cargo', 'metadata', '--format-version', '1'
workingDir rustBasePath
standardOutput = os
}
def outputAsString = os.toString()
def json = new groovy.json.JsonSlurper().parseText(outputAsString)
logger.info("cargo target directory: ${json.target_directory}")
project.ext.cargo_target_directory = json.target_directory
}
}
// Build with cargo
tasks.create(name: "cargo-build-${arch}-${buildType}", type: Exec, description: "Building core for ${arch}", dependsOn: "cargo-output-dir-${arch}-${buildType}") {
doFirst { println("\n============================== Start Compile Native Lib ==============================\n") }
workingDir rustBasePath
environment("RUSTFLAGS", "-C link-arg=-o -C link-arg=${project.ext.cargo_target_directory}/${target}/${buildType}/lib${libName}.so")
if (buildType.equalsIgnoreCase("release")) {
commandLine 'cargo', 'build', "--color=always", "--target=${target}", '--release'
} else {
commandLine 'cargo', 'build', "--color=always", "--target=${target}"
}
doLast { println("\n============================== Finish Compile Native Lib ==============================\n") }
}
// Sync shared native dependencies
tasks.create(name: "sync-rust-deps-${arch}-${buildType}", type: Sync, dependsOn: "cargo-build-${arch}-${buildType}") {
from "${rustBasePath}/src/libs/${arch}"
include "*.so"
into "src/main/jniLibs/${arch}"
}
// Copy build libs into this app's libs directory
tasks.create(name: "rust-deploy-${arch}-${buildType}", type: Copy, dependsOn: "sync-rust-deps-${arch}-${buildType}", description: "Copy rust libs for (${arch}) to jniLibs") {
from "${project.ext.cargo_target_directory}/${target}/${buildType}"
include "*.so"
into "src/main/jniLibs/${arch}"
}
// Hook up tasks to execute before building java
tasks.withType(JavaCompile) {
compileTask -> compileTask.dependsOn "rust-deploy-${arch}-${buildType}"
}
preBuildProvider.get().dependsOn "rust-deploy-${arch}-${buildType}"
// Hook up clean tasks
tasks.create(name: "clean-${arch}-${buildType}", type: Delete, description: "Deleting built libs for ${arch}", dependsOn: "cargo-output-dir-${arch}-${buildType}") {
delete fileTree("${project.ext.cargo_target_directory}/${target}/${buildType}") {
include '*.so'
}
delete fileTree("${project.projectDir}/src/main/jniLibs/${arch}") {
include '*.so'
}
}
clean.dependsOn "clean-${arch}-${buildType}"
}
// ANCHOR_END:cargo
}
}
dependencies {
implementation fileTree(dir: 'libs', include: ['*.jar'])
androidTestImplementation('com.android.support.test.espresso:espresso-core:2.2.2', {
exclude group: 'com.android.support', module: 'support-annotations'
})
api 'com.android.support:appcompat-v7:28.0.0'
api 'com.android.support.constraint:constraint-layout:1.1.3'
api 'com.android.support:design:28.0.0'
testImplementation 'junit:junit:4.12'
}