-
Notifications
You must be signed in to change notification settings - Fork 3
/
M3 Import M3DataStruct.ms
10867 lines (9941 loc) · 345 KB
/
M3 Import M3DataStruct.ms
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
---------------------------------------------------------------------------
---------------------------------------------------------------------------
--M3G--------------------M3 GLOBAL
--M3S--------------------M3 MAIN STRUCT
--M3SD-------------------M3 DATA STRUCT
--M3F--------------------M3 FUNCTION
--M3P--------------------M3 PANEL
/* Global */
M3G_CustAttributes_Glb = #()
M3G_InfoScene_Glb=#()
M3G_InfoFile_Glb=#()
--Declares------------------------------------------------
struct M3SD_RefAnim
(
iptType, flags, animID, initState, nullState, idx,
fn init d1:0 d2:0 d3:0 d4:-1 s: t: =(),
fn read stream_FP type_FP =()
)
struct M3SD_RefData
(
ref,data,
fn init type_FP d1:0 d2: s: t: =(),
fn readRef stream_FP f:#index =(),
fn readData stream_FP tags_FP f:#null =()
)
fn M3F_TempFunc left right =()
----------------------------------------------------------
/* Helper Functions */
fn M3F_GetGlobalSettings type_FP =
(
local ret
case type_FP of
(
#Cancel: ret = M3G_ImportInfo_Glb.cancelCheck
#GlobalPos: ret = M3G_ImportInfo_Glb.setGPos.value
#GlobalScale: ret = M3G_ImportInfo_Glb.setGScale.value
#TrackEnable: ret = M3G_ImportInfo_Glb.impTrack.value
#SeqEnable: ret = M3G_ImportInfo_Glb.impSeq.value
#AnimEnable: ret = M3G_ImportInfo_Glb.impAnim.value
#EventEnable: ret = M3G_ImportInfo_Glb.impEvt.value
#TurretEnable: ret = M3G_ImportInfo_Glb.impTurt.value
#BillBoardEnable: ret = M3G_ImportInfo_Glb.impBBrd.value
#IKLegEnable: ret = M3G_ImportInfo_Glb.impIK.value
#MatEnable: ret = M3G_ImportInfo_Glb.impMat.value
#BoneEnable: ret = M3G_ImportInfo_Glb.impBone.value
#MeshEnable: ret = M3G_ImportInfo_Glb.impMesh.value
#SkinEnable: ret = M3G_ImportInfo_Glb.impSkin.value
#HitEnable: ret = M3G_ImportInfo_Glb.impHit.value
#VolEnable: ret = M3G_ImportInfo_Glb.impVol.value
#AttEnable: ret = M3G_ImportInfo_Glb.impAttach.value
#BoundEnable: ret = M3G_ImportInfo_Glb.impBound.value
#LightEnable: ret = M3G_ImportInfo_Glb.impLight.value
#CamEnable: ret = M3G_ImportInfo_Glb.impCam.value
#ParEnable: ret = M3G_ImportInfo_Glb.impPart.value
#PhyEnable: ret = M3G_ImportInfo_Glb.impPhy.value
#FrameRate: ret = M3G_ImportInfo_Glb.setFRate.value
#FramesBetweenSeq: ret = M3G_ImportInfo_Glb.setFBSeq.value
#FrameCorrect: ret = M3G_ImportInfo_Glb.setFCorrect.value
#FrameCheckRange: ret = M3G_ImportInfo_Glb.setFCheckR.value
#MeshWeldEnable:
(
case M3G_ImportInfo_Glb.setWeldSmooth.value of
(
3: ret = false
5: ret = false
default: ret = true
)
)
#MeshSmoothEnable:
(
case M3G_ImportInfo_Glb.setWeldSmooth.value of
(
3: ret = false
4: ret = false
default: ret = true
)
)
#MeshWeldType:
(
case M3G_ImportInfo_Glb.setWeldSmooth.value of
(
2: ret = 2
4: ret = 2
default: ret = 1
)
)
#MeshSmoothType:
(
case M3G_ImportInfo_Glb.setWeldSmooth.value of
(
2: ret = M3G_ImportInfo_Glb.setSmoothType.value
5: ret = M3G_ImportInfo_Glb.setSmoothType.value
default: ret = 3
)
)
#MeshSmoothAngle: ret = M3G_ImportInfo_Glb.setSmoothAngle.value
#BoneEntity: ret = M3G_ImportInfo_Glb.setBEntity.value
#BoneSize1: ret = M3G_ImportInfo_Glb.setBSize1.value
#BoneSize2: ret = M3G_ImportInfo_Glb.setBSize2.value
#BoneSize3: ret = M3G_ImportInfo_Glb.setBSize3.value
#BoneAnim: ret = M3G_ImportInfo_Glb.setBAnim.value
#BoneLink: ret = M3G_ImportInfo_Glb.setBLink.value
#BoneFix: ret = M3G_ImportInfo_Glb.setBFix.value
#BonePosCtl:
(
ret = case M3G_ImportInfo_Glb.setBPosCtl.value of
(
1: Position_XYZ
2: bezier_position
default: Position_XYZ
)
)
#BoneRotCtl:
(
ret = case M3G_ImportInfo_Glb.setBRotCtl.value of
(
1: Euler_XYZ
2: bezier_rotation
default: Euler_XYZ
)
)
#BoneScaleCtl:
(
ret = case M3G_ImportInfo_Glb.setBScaleCtl.value of
(
1: ScaleXYZ
2: Bezier_Scale
default: ScaleXYZ
)
)
#AttSize: ret = M3G_ImportInfo_Glb.setAttSize.value
#AttScale: ret = M3G_ImportInfo_Glb.setAttScale.value
#BoundColl: ret = M3G_ImportInfo_Glb.setBoundColl.value
#AttColl: ret = M3G_ImportInfo_Glb.setAttColl.value
#VolColl: ret = M3G_ImportInfo_Glb.setVolColl.value
#HitColl: ret = M3G_ImportInfo_Glb.setHitColl.value
#LightTrans: ret = M3G_ImportInfo_Glb.setLTrans.value
#LightParm: ret = M3G_ImportInfo_Glb.setLPar.value
#CameraTrans: ret = M3G_ImportInfo_Glb.setCTrans.value
#CameraParm: ret = M3G_ImportInfo_Glb.setCPar.value
#PartTrans: ret = M3G_ImportInfo_Glb.setPTrans.value
#PartParm: ret = M3G_ImportInfo_Glb.setPPar.value
)
ret
)
fn M3F_FillProgressLv step:1.0 flag:#null =
(
case flag of
(
#clear:
(
M3G_ImportInfo_Glb.currProgLv = 0.0
M3G_ImportInfo_Glb.progressLv = 0.0
)
#execute:
(
M3G_ImportInfo_Glb.currProgLv += step
local value = (M3G_ImportInfo_Glb.currProgLv / M3G_ImportInfo_Glb.progressLv) * 100.0
if(value > 100)then(value = 100.0)
M3G_ImportInfo_Glb.MainUI.Import_subRoll.rollouts[1].FillProgressLv value
if(M3F_GetGlobalSettings #Cancel)then(throw "Cancel")
)
#current:
(
M3G_ImportInfo_Glb.currProgLv += step
local value = M3G_ImportInfo_Glb.currProgLv
if(value > 100)then(value = 100.0)
M3G_ImportInfo_Glb.MainUI.Import_subRoll.rollouts[1].FillProgressLv value
if(M3F_GetGlobalSettings #Cancel)then(throw "Cancel")
)
#buildfinished:
(
local proportion = M3G_ImportInfo_Glb.currProgLv / 100.0
M3G_ImportInfo_Glb.progressLv = M3G_ImportInfo_Glb.progressLv / (1 - proportion)
M3G_ImportInfo_Glb.currProgLv = M3G_ImportInfo_Glb.progressLv * proportion
)
default:
(
M3G_ImportInfo_Glb.progressLv += step
)
)
windows.processPostedMessages()
setWaitCursor()
)
fn M3F_ShowPhase str_FP =
(
M3G_ImportInfo_Glb.MainUI.Import_subRoll.rollouts[1].ChangePhaseText str_FP
)
fn M3F_ShowLogInfo str_FP type: =
(
M3G_ImportInfo_Glb.DetailsUI.setLogInfo str_FP type:type
)
fn M3F_ShowPhaseInfo str_FP type:#Info =
(
M3F_ShowPhase str_FP
M3F_ShowLogInfo ("***** " + str_FP + " *****") type:type
)
fn M3F_ShowObjectCount str_FP count_FP =
(
local string_temp = M3F_FormatToString "%Count:" #(str_FP)
M3F_ShowLogInfo (string_temp + (count_FP as string))
)
fn M3F_MissingMap str_FP =
(
appendIfUnique M3G_ImportInfo_Glb.missingMap str_FP
)
fn M3F_GetCustAttr type_FP =
(
local copys
case type_FP of
(
#trackset: copys = (startools.behaviors.GetBehaviorDef #TrackSet)
#turret: copys = (startools.behaviors.GetBehaviorDef #Turret_Behavior)
#IKleg: copys = (startools.behaviors.GetBehaviorDef #IK_Leg_Behavior)
#billboard: copys = (startools.behaviors.GetBehaviorDef #Billboard_behavior)
#joint: copys = (startools.behaviors.GetBehaviorDef #PhysicsJoint_Behavior)
#cloth: copys = (startools.behaviors.GetBehaviorDef #PhysicsCloth_Behavior)
)
return copys
)
fn M3F_SkipBytes stream_FP lens_FP =
(
if(lens_FP == 0)then(return undefined)
local ret_pos = fTell stream_FP
fSeek stream_FP (ret_pos+lens_FP) #seek_set
)
fn M3F_Try data_FP init_FP =
(
if data_FP != unsupplied and data_FP != undefined then return data_FP
return init_FP
)
fn M3F_GetSize name_FP f:0 =
(
local ret
ret = case name_FP of
(
"MODL": case f of(0x17: 784; 0x1A: 820; 0x1D: 856)
"SEQS": case f of(0x01: 96; 0x02: 92)
"STC_": case f of(0x04: 204)
"STG_": case f of(0x00: 24)
"STS_": case f of(0x00: 28)
"BONE": case f of(0x01: 160)
"REGN": case f of(0x03: 36; 0x04: 40; 0x05: 48)
"BAT_": case f of(0x01: 14)
"DIV_": case f of(0x02: 52)
"IREF": case f of(0x00: 64)
"ATT_": case f of(0x01: 20)
"LITE": case f of(0x07: 212)
"CAM_": case f of(0x03: 180; 0x05:264)
"MATM": case f of(0x00: 8)
"MAT_": case f of(0x0F: 268; 0x10: 280; 0x11: 280; 0x12: 280; 0x13: 340; 0x14: 352)
"LAYR": case f of(0x16: 356; 0x19: 468; 0x1A: 464)
"DIS_": case f of(0x04: 68)
"CMP_": case f of(0x02: 28)
"TER_": case f of(0x01: 28)
"VOL_": case f of(0x00: 84)
"CREP": case f of(0x01: 28)
"VON_": case f of(0x00: 268)
"STBM": case f of(0x00: 48)
"REF_": case f of(0x02: 156)
"LFLR": case f of(0x02: 80; 0x03: 152)
"PAR_": case f of(0x0C: 1316; 0x12: 1464; 0x13: 1464; 0x15: 1464; 0x16: 1484; 0x17: 1492; 0x18: 1496)
"PARC": case f of(0x00: 40)
"RIB_": case f of(0x06: 748; 0x08: 756; 0x09: 760)
"PROJ": case f of(0x04: 388; 0x05: 388)
"FOR_": case f of(0x01: 104; 0x02: 104)
"WRP_": case f of(0x01: 132)
"PHRB": case f of(0x02: 104; 0x04: 80)
"PHYJ": case f of(0x00: 180)
"PHCL": case f of(0x04: 192)
"TRGD": case f of(0x00: 24)
"PATU": case f of(0x04: 152)
"BBSC": case f of(0x00: 48)
"IKJT": case f of(0x00: 32)
"EVNT": case f of(0x01: 104; 0x02: 108)
"SSGS": case f of(0x01: 108)
"LFSB": case f of(0x02: 56)
"PHSH": case f of(0x01: 132; 0x03: 300)
"DMMN": case f of(0x01: 8)
"PHCC": case f of(0x00: 76)
"PHAC": case f of(0x00: 32)
"DMSE": case f of(0x00: 4)
)
if ret == undefined then ret = 0
ret
)
fn M3F_FindRefType str_FP flag_FP =
(
local ret
ret = case str_FP of
(
"SDEV": "SDXX"
"SD2V": "SDXX"
"SD3V": "SDXX"
"SD4Q": "SDXX"
"SDCC": "SDXX"
"SDR3": "SDXX"
--"SDXX"unknown
"SDS6": "SDXX"
"SDU6": "SDXX"
--"SDXX"unknown
"SDU3": "SDXX"
"SDFG": "SDXX"
"SDMB": "SDXX"
--Array
"U32_": case flag_FP of(#U8: "U8Q"; #U16: "U16D")
"U64_": case flag_FP of(#U16: "U16Q")
)
if ret == undefined then ret = str_FP
return ret
)
fn M3F_FindStart stream_FP tags_FP idx_FP nbr_FP =
(
local size = M3F_GetSize tags_FP.nameStr[idx_FP] f:tags_FP.tags[idx_FP].flag
return (tags_FP.tags[idx_FP].ofsData + (nbr_FP-1)*size)
)
fn M3F_ReadString stream_FP lens_FP f:#tag =
(
local i
local ret = ""
if lens_FP == 4 and f == #tag then
(
for i=1 to 4 do
(
ret = bit.IntAsChar(ReadByte stream_FP) + ret
)
)else
(
if lens_FP > 0 then
(
for i=1 to lens_FP do
(
ret += bit.IntAsChar(ReadByte stream_FP)
)
)
)
return ret
)
fn M3F_CreateRawData d1:0 d2:0 d3:0 d4:0 t:#v3d =
(
local ret
ret = case t of
(
#uint16: d1
#uint32: d1
#float: d1
#v2d: [d1, d2]
#v3d: [d1, d2, d3]
#v4d: [d1, d2, d3, d4]
#quat: quat d1 d2 d3 d4
#bgr: [d1, d2, d3]
#bgra: [d1, d2, d3, d4]
#matrix:
(
#(M3F_CreateRawData d1:1 t:#v4d, M3F_CreateRawData d2:1 t:#v4d,
M3F_CreateRawData d3:1 t:#v4d, M3F_CreateRawData d4:1 t:#v4d)
)
#sphere:
(
#(M3F_CreateRawData(), M3F_CreateRawData(), d1)
)
default: #()
)
return ret
)
fn M3F_ReadRawData stream_FP type_FP =
(
local ret
ret = case type_FP of
(
#uint16: readShort stream_FP #unsigned
#uint32: readLong stream_FP #unsigned
#float: readFloat stream_FP
#v2d: [readFloat stream_FP, readFloat stream_FP]
#v3d: [readFloat stream_FP, readFloat stream_FP, readFloat stream_FP]
#v4d: [readFloat stream_FP, readFloat stream_FP, readFloat stream_FP, readFloat stream_FP]
#quat:(quat (readFloat stream_FP) (readFloat stream_FP) \
(readFloat stream_FP) (readFloat stream_FP))
#bgr: [ ReadByte stream_FP #unsigned, ReadByte stream_FP #unsigned,\
ReadByte stream_FP #unsigned]
#bgra: [ReadByte stream_FP #unsigned, ReadByte stream_FP #unsigned, \
ReadByte stream_FP #unsigned, ReadByte stream_FP #unsigned]
#matrix:
(
#(M3F_ReadRawData stream_FP #v4d, M3F_ReadRawData stream_FP #v4d,
M3F_ReadRawData stream_FP #v4d, M3F_ReadRawData stream_FP #v4d)
)
#sphere:
(
#(M3F_ReadRawData stream_FP #v3d, M3F_ReadRawData stream_FP #v3d, readFloat stream_FP)
)
default: #()
)
return ret
)
/* ---------------------Structs------------------------------------ */
--M3 File Structs---------------------------------------------
struct M3SD_Flag
(
bits = #{},
fn bitSet bit_FP =
(
append this.bits bit_FP
),
fn bitReset bit_FP =
(
deleteItem this.bits bit_FP
),
fn valSet val_FP =
(
local i
this.bits = #{}
for i=1 to 32 do
(
this.bits[i] = bit.get val_FP i
)
),
fn bitGet bit_FP =
(
return this.bits[bit_FP]
),
fn valGet =
(
local i
local value = 0
for i=1 to 32 do
(
value = bit.set value i this.bits[i]
)
return value
)
)
----M3 DATA STRUCT--------------------------------------------
struct M3SD_BndSphere
(
eMin, eMax, rad
)
struct M3SD_TagData
(
ofsData, nbr, flag
)
struct M3SD_VertData
(
pos, weight, boneIdx, normal, uv = #(), vColor
)
struct M3SD_AttachData
(
rfdName = M3SD_RefData(), nbrBone
)
struct M3SD_HitTest
(
bone1, bone2, nbrBone, matrix, type, size0, size1, size2,
rfdVertsPos = M3SD_RefData(), rfdFaces = M3SD_RefData(),
fn init d1:0 d2:0 d3:0 d4:(M3F_CreateRawData t:#matrix) d5:0 d6:0 d7:0 d8:0 s: t: f: =
(
local hit_test
try(hit_test = this)catch(hit_test = M3SD_HitTest())
try(hit_test.read s t f:f)catch
(
hit_test.bone1 = d1
hit_test.bone2 = d2
hit_test.nbrBone = d3
hit_test.matrix = d4
hit_test.type = d5
hit_test.size0 = d6
hit_test.size1 = d7
hit_test.size2 = d8
)
hit_test
),
fn read stream_FP tags_FP f:#normal =
(
if(stream_FP == unsupplied)then(throw "unsupplied")
if f == #attachvol then
(
this.bone1 = readLong stream_FP #unsigned
this.bone2 = readLong stream_FP #unsigned
)
this.type = readLong stream_FP #unsigned
this.nbrBone = readShort stream_FP #unsigned
M3F_SkipBytes stream_FP 2
this.matrix = M3F_ReadRawData stream_FP #matrix
this.rfdVertsPos.readRef stream_FP
this.rfdVertsPos.readData stream_FP tags_FP
this.rfdFaces.readRef stream_FP
this.rfdFaces.readData stream_FP tags_FP
this.size0 = readFloat stream_FP
this.size1 = readFloat stream_FP
this.size2 = readFloat stream_FP
)
)
struct M3SD_Event
(
rfdName = M3SD_RefData(), nbrBone, matrix, type, rfdOptionStr = M3SD_RefData(),
fn init d1:(M3SD_RefData.init "") d2:(M3F_CreateRawData t:#matrix) s: t: i: =
(
local event
try(event = this)catch(event = M3SD_Event())
try(event.read s t i)catch
(
event.rfdName = d1
event.matrix = d2
)
return event
),
fn read stream_FP tags_FP idx_FP =
(
if(stream_FP == unsupplied)then(throw "unsupplied")
this.rfdName.readRef stream_FP
this.rfdName.readData stream_FP tags_FP
M3F_SkipBytes stream_FP 4
this.nbrBone = readShort stream_FP #unsigned
M3F_SkipBytes stream_FP 2
this.matrix = M3F_ReadRawData stream_FP #matrix
this.type = readLong stream_FP #unsigned
this.rfdOptionStr.readRef stream_FP
this.rfdOptionStr.readData stream_FP tags_FP
M3F_SkipBytes stream_FP ((M3F_GetSize "EVNT" f:tags_FP.tags[idx_FP].flag) - 100)
)
)
struct M3SD_AnimBlock
(
rfdFrames = M3SD_RefData(), flags, fEnd, rfdKeys = M3SD_RefData(),
--Build Items
animID,
fn init d1:(M3SD_RefData.init #(0)) d2:0 d3:1 d4:(M3SD_RefData.init #(0)) s: t: =
(
local anim
try(anim = this)catch(anim = M3SD_AnimBlock())
try(anim.read s t)catch
(
anim.rfdFrames = d1
anim.flags = d2
anim.fEnd = d3
anim.rfdKeys = d4
)
return anim
),
fn read stream_FP tags_FP =
(
if(stream_FP == unsupplied)then(throw "unsupplied")
this.rfdFrames.readRef stream_FP
this.rfdFrames.readData stream_FP tags_FP
this.flags = readLong stream_FP #unsigned
this.fEnd = readLong stream_FP #unsigned
this.rfdKeys.readRef stream_FP
this.rfdKeys.readData stream_FP tags_FP
)
)
struct M3SD_Region
(
firstVert, nbrVert, firstFace, nbrFace, firstBonelu, nbrBonelu,
boneWeightPair, boneIdxPair, rootBone, uvwMult, uvwOffset,
--verts, faces, vertsList, facesList, skinBones, maxMesh, maxSkin,-- maxscript holders
fn init d1:0 d2:0 d3:0 d4:0 d5:0 d6:0 d7:0 d8:0 d9:0 d10:(M3F_CreateRawData t:#v2d) s: t: i: =
(
local region
try(region = this)catch(region = M3SD_Region())
try(region.read s t i)catch
(
region.firstVert = d1
region.nbrVert = d2
region.firstFace = d3
region.nbrFace = d4
region.firstBonelu = d5
region.nbrBonelu = d6
region.boneWeightPair = d7
region.boneIdxPair = d8
region.rootBone = d9
region.vec2 = d10
)
return region
),
fn read stream_FP tags_FP idx_FP =
(
if(stream_FP == unsupplied)then(throw "unsupplied")
local flag = tags_FP.tags[idx_FP].flag
M3F_SkipBytes stream_FP 8
this.firstVert = readLong stream_FP #unsigned
this.nbrVert = readLong stream_FP #unsigned
this.firstFace = readLong stream_FP #unsigned
this.nbrFace = readLong stream_FP #unsigned
M3F_SkipBytes stream_FP 2
this.firstBonelu = readShort stream_FP #unsigned
this.nbrBonelu = readShort stream_FP #unsigned
M3F_SkipBytes stream_FP 2
this.boneWeightPair = ReadByte stream_FP #unsigned
this.boneIdxPair = ReadByte stream_FP #unsigned
this.rootBone = readShort stream_FP #unsigned
case flag of
(
4:
(
M3F_SkipBytes stream_FP 4
this.uvwMult = 16.0
this.uvwOffset = 0
)
5:
(
M3F_SkipBytes stream_FP 4
this.uvwMult = readFloat stream_FP
this.uvwOffset = readFloat stream_FP
)
default:
(
this.uvwMult = 16.0
this.uvwOffset = 0
)
)
)
)
struct M3SD_MeshMat
(
meshID, matID, nbrBone,
fn init d1:0 d2:0 d3:0 s: =
(
local meshmat
try(meshmat = this)catch(meshmat = M3SD_MeshMat())
try(meshmat.read s)catch
(
meshmat.meshID = d1
meshmat.matID = d2
meshmat.nbrBone = d3
)
return meshmat
),
fn read stream_FP =
(
if(stream_FP == unsupplied)then(throw "unsupplied")
M3F_SkipBytes stream_FP 4
this.meshID = readShort stream_FP #unsigned
M3F_SkipBytes stream_FP 4
this.matID = readShort stream_FP #unsigned
this.nbrBone = readShort stream_FP #unsigned
)
)
struct M3SD_MapLayer
(
rfdName = M3SD_RefData(),
rfaColor = M3SD_RefAnim(), flags = M3SD_Flag(), mapping, colorType,
rfaRGBmult = M3SD_RefAnim(), rfaRGBadd = M3SD_RefAnim(),
pocTexture, noiseAmp, noiseFreq,
texSource, aviFrameRate, aviStart, aviStop, aviLoop, aviSync,
rfaAVIplay = M3SD_RefAnim(), rfaAVIrestart = M3SD_RefAnim(),
rows, columns, rfaCurFrame = M3SD_RefAnim(),
rfaUVoffset = M3SD_RefAnim(), rfaAngle = M3SD_RefAnim(), rfaUVtill = M3SD_RefAnim(),
rfaWoffset = M3SD_RefAnim(), rfaWtill = M3SD_RefAnim(), rfaMapAlpha = M3SD_RefAnim(),
rfaTriOffset = M3SD_RefAnim(), rfaTriScale = M3SD_RefAnim(),
fresnelMode, fresnelExponent, fresnelMin, fresnelMax, fresnelConst, fresnelMask, fresnelRot,
version,
fn init d1:(M3SD_RefData.init "") s: t: i: =
(
local maplayer
try(maplayer = this)catch(maplayer = M3SD_MapLayer())
try(maplayer.read s t i)catch
(
maplayer.rfdName = d1
maplayer.rfaColor.init t:#bgra
maplayer.flags.valSet 0
maplayer.mapping = 0
maplayer.colorType = 0
maplayer.rfaRGBmult.init t:#float
maplayer.rfaRGBadd.init t:#float
maplayer.pocTexture = 0
maplayer.noiseAmp = 0.8
maplayer.noiseFreq = 0.5
maplayer.texSource = 0
maplayer.aviFrameRate = 0
maplayer.aviStart = 0
maplayer.aviStop = 0
maplayer.aviLoop = 0
maplayer.aviSync = 0
maplayer.rfaAVIplay.init t:#uint32
maplayer.rfaAVIrestart.init t:#uint32
maplayer.rows = 0
maplayer.columns = 0
maplayer.rfaCurFrame.init t:#uint16
maplayer.rfaUVoffset.init t:#v2d
maplayer.rfaAngle.init t:#v3d
maplayer.rfaUVtill.init t:#v2d
maplayer.rfaWoffset.init t:#float
maplayer.rfaWtill.init t:#float
maplayer.rfaMapAlpha.init t:#float
maplayer.rfaTriOffset.init t:#v3d
maplayer.rfaTriScale.init t:#v3d
maplayer.fresnelMode = 0
maplayer.fresnelExponent = 0
maplayer.fresnelMin = 0
maplayer.fresnelMax = 0
maplayer.fresnelMask = M3F_CreateRawData()
maplayer.fresnelRot = M3F_CreateRawData t:#v2d
)
maplayer
),
fn read stream_FP tags_FP idx_FP =
(
if(stream_FP == unsupplied)then(throw "unsupplied")
local flag = tags_FP.tags[idx_FP].flag
this.version = flag
M3F_SkipBytes stream_FP 4
this.rfdName.readRef stream_FP
this.rfdName.readData stream_FP tags_FP
this.rfaColor.read stream_FP #bgra
this.flags.valSet (readLong stream_FP #unsigned)
this.mapping = readLong stream_FP #unsigned
this.colorType = readLong stream_FP #unsigned
this.rfaRGBmult.read stream_FP #float
this.rfaRGBadd.read stream_FP #float
this.pocTexture = readLong stream_FP #unsigned
if(flag == 0x16)then
(
this.noiseAmp = 0
this.noiseFreq = 0
)else
(
this.noiseAmp = readFloat stream_FP
this.noiseFreq = readFloat stream_FP
)
this.texSource = readLong stream_FP #unsigned
this.aviFrameRate = readLong stream_FP #unsigned
this.aviStart = readLong stream_FP #unsigned
this.aviStop = readLong stream_FP #unsigned
this.aviLoop = readLong stream_FP #unsigned
this.aviSync = readLong stream_FP #unsigned
this.rfaAVIplay.read stream_FP #uint32
this.rfaAVIrestart.read stream_FP #uint32
this.rows = readLong stream_FP #unsigned
this.columns = readLong stream_FP #unsigned
this.rfaCurFrame.read stream_FP #uint16
this.rfaUVoffset.read stream_FP #v2d
this.rfaAngle.read stream_FP #v3d
this.rfaUVtill.read stream_FP #v2d
this.rfaWoffset.read stream_FP #float
this.rfaWtill.read stream_FP #float
this.rfaMapAlpha.read stream_FP #float
if(flag == 0x16)then
(
this.rfaTriOffset.init t:#v3d
this.rfaTriScale.init t:#v3d
)else
(
this.rfaTriOffset.read stream_FP #v3d
this.rfaTriScale.read stream_FP #v3d
)
M3F_SkipBytes stream_FP 4
this.fresnelMode = readLong stream_FP #unsigned
this.fresnelExponent = readFloat stream_FP
this.fresnelMin = readFloat stream_FP
this.fresnelMax = readFloat stream_FP
if(flag == 0x16)then
(
this.fresnelConst = 0
this.fresnelMask = M3F_CreateRawData d1:1.0 d2:1.0 d3:1.0 t:#v3d
this.fresnelRot = M3F_CreateRawData t:#v2d
)else
(
M3F_SkipBytes stream_FP 8
this.fresnelConst = readFloat stream_FP
this.fresnelMask = M3F_ReadRawData stream_FP #v3d
this.fresnelRot = M3F_ReadRawData stream_FP #v2d
)
)
)
struct M3SD_CompMaps
(
index, rfaMapMult = M3SD_RefAnim(),
fn init d1:0 d2:(M3SD_RefAnim.init t:#float) s: =
(
local comp_map
try(comp_map = this)catch(comp_map = M3SD_CompMaps())
try(comp_map.read s)catch
(
comp_map.index = d1
comp_map.rfaMapMult = d2
)
return comp_map
),
fn read stream_FP =
(
if(stream_FP == unsupplied)then(throw "unsupplied")
this.index = readLong stream_FP #unsigned
this.rfaMapMult.read stream_FP #float
)
)
struct M3SD_SubFlares
(
index, pos, sizeXY, scaleXY, fadeIn, fadeOut, colorAlpha, faceCenter, offset,
fn init d1:0 d2:1 \
d3:(M3F_CreateRawData t:#v2d) d4:(M3F_CreateRawData t:#v2d) \
d5:(M3F_CreateRawData t:#v2d) d6:(M3F_CreateRawData t:#v2d) \
d7:(M3F_CreateRawData t:#bgra) d8:0 d9:(M3F_CreateRawData t:#v2d) s: =
(
local sub_flare
try(sub_flare = this)catch(sub_flare = M3SD_SubFlares())
try(sub_flare.read s)catch
(
sub_flare.index = d1
sub_flare.pos = d2
sub_flare.sizeXY = d3
sub_flare.scaleXY = d4
sub_flare.fadeIn = d5
sub_flare.fadeOut = d6
sub_flare.colorAlpha = d7
sub_flare.faceCenter = d8
sub_flare.offset = d9
)
return sub_flare
),
fn read stream_FP =
(
if(stream_FP == unsupplied)then(throw "unsupplied")
this.index = readLong stream_FP #unsigned
this.pos = readFloat stream_FP
this.sizeXY = M3F_ReadRawData stream_FP #v2d
this.scaleXY = M3F_ReadRawData stream_FP #v2d
this.fadeIn = M3F_ReadRawData stream_FP #v2d
this.fadeOut = M3F_ReadRawData stream_FP #v2d
this.colorAlpha = M3F_ReadRawData stream_FP #bgra
this.faceCenter = readLong stream_FP #unsigned
this.offset = M3F_ReadRawData stream_FP #v2d
)
)
struct M3SD_SubRibbon
(
ribSpeed, subRibSpeed, nbrBone, yawType, pitchType, speedType,
rfaSpeedMult = M3SD_RefAnim(), rfaSubSpeedMult = M3SD_RefAnim(),
rfaYaw = M3SD_RefAnim(), rfaPitch = M3SD_RefAnim(),
rfaYawAmp = M3SD_RefAnim(), rfaYawFreq = M3SD_RefAnim(),
rfaPitchAmp = M3SD_RefAnim(), rfaPitchFreq = M3SD_RefAnim(),
rfaSpeedAmp = M3SD_RefAnim(), rfaSpeedFreq = M3SD_RefAnim(),
fn init d1:0 d2:0 d3:0 \
d4:(M3SD_RefAnim.init t:#float) d5:(M3SD_RefAnim.init t:#float) s: =
(
local sub_ribbon
try(sub_ribbon = this)catch(sub_ribbon = M3SD_SubRibbon())
try(sub_ribbon.read s)catch
(
sub_ribbon.ribSpeed = d1
sub_ribbon.subRibSpeed = d2
sub_ribbon.nbrBone = d3
sub_ribbon.yawType = 0
sub_ribbon.pitchType = 0
sub_ribbon.speedType = 0
sub_ribbon.rfaYaw = d4
sub_ribbon.rfaPitch = d5
sub_ribbon.rfaYawAmp.init t:#float
sub_ribbon.rfaYawFreq.init t:#float
sub_ribbon.rfaPitchAmp.init t:#float
sub_ribbon.rfaPitchFreq.init t:#float
sub_ribbon.rfaSpeedAmp.init t:#float
sub_ribbon.rfaSpeedFreq.init t:#float
)
return sub_ribbon
),
fn read stream_FP =
(
if(stream_FP == unsupplied)then(throw "unsupplied")
M3F_SkipBytes stream_FP 20
this.ribSpeed = readFloat stream_FP
M3F_SkipBytes stream_FP 8
this.subRibSpeed = readFloat stream_FP
M3F_SkipBytes stream_FP 12
this.nbrBone = readLong stream_FP #unsigned
this.rfaSpeedMult.read stream_FP #float
this.rfaSubSpeedMult.read stream_FP #float
this.yawType = readLong stream_FP #unsigned
this.rfaYawAmp.read stream_FP #float
this.rfaYawFreq.read stream_FP #float
this.pitchType = readLong stream_FP #unsigned
this.rfaPitchAmp.read stream_FP #float
this.rfaPitchFreq.read stream_FP #float
this.speedType = readLong stream_FP #unsigned
this.rfaSpeedAmp.read stream_FP #float
this.rfaSpeedFreq.read stream_FP #float
this.rfaYaw.read stream_FP #float
this.rfaPitch.read stream_FP #float
)
)
struct M3SD_RigedBody
(
matrix, shapeType, size0, size1, size2,
rfdVertPos = M3SD_RefData(), rfdFaceNorm = M3SD_RefData(),
rfdVertFace = M3SD_RefData(), rfdNormIdx = M3SD_RefData(),
vertNbr, faceNbr, pairNbr,
rfdNormMesh = M3SD_RefData(), rfdVertPosMesh = M3SD_RefData(),
rfdFaceMesh = M3SD_RefData(),
meshOffset, meshBoxSize, meshBoxOffset, normMeshNbr, vertMeshNbr, faceMeshNbr,
fn init d1:(M3F_CreateRawData t:#matrix) d2:0 d3:0.25 d4:0.25 d5:0.25 \
d6:(M3SD_RefData.init #()) d7:(M3SD_RefData.init #()) \
d8:(M3SD_RefData.init #()) d9:(M3SD_RefData.init #()) d10:0 d11:0 d12:0 s: t: i: =
(
local riged_body
try(riged_body = this)catch(riged_body = M3SD_RigedBody())
try(riged_body.read s t i)catch
(
riged_body.matrix = d1
riged_body.shapeType = d2
riged_body.size0 = d3
riged_body.size1 = d4
riged_body.size2 = d5
riged_body.rfdVertPos = d6
riged_body.rfdFaceNorm = d7
riged_body.rfdVertFace = d8
riged_body.rfdNormIdx = d9
riged_body.vertNbr = d10
riged_body.faceNbr = d11
riged_body.pairNbr = d12
)
riged_body
),
fn read stream_FP tags_FP idx_FP =
(
if(stream_FP == unsupplied)then(throw "unsupplied")
local flag = tags_FP.tags[idx_FP].flag
this.matrix = M3F_ReadRawData stream_FP #matrix
if(flag == 0x01)then
(
this.vertNbr = 32
M3F_SkipBytes stream_FP 4
this.shapeType = readByte stream_FP #unsigned
M3F_SkipBytes stream_FP 51
this.size0 = readFloat stream_FP
this.size1 = readFloat stream_FP
this.size2 = readFloat stream_FP
)else