diff --git a/icon.svg b/icon.svg
new file mode 100644
index 0000000..87c12a7
--- /dev/null
+++ b/icon.svg
@@ -0,0 +1,4 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<svg width="24px" height="24px" fill="#e8eaed" version="1.1" viewBox="0 -960 960 960" xmlns="http://www.w3.org/2000/svg">
+ <path d="M440-440ZM120-120q-33 0-56.5-23.5T40-200v-480q0-33 23.5-56.5T120-760h126l74-80h240v80H355l-73 80H120v480h640v-360h80v360q0 33-23.5 56.5T760-120H120Zm640-560v-80h-80v-80h80v-80h80v80h80v80h-80v80h-80ZM440-260q75 0 127.5-52.5T620-440q0-75-52.5-127.5T440-620q-75 0-127.5 52.5T260-440q0 75 52.5 127.5T440-260Zm0-80q-42 0-71-29t-29-71q0-42 29-71t71-29q42 0 71 29t29 71q0 42-29 71t-71 29Z" fill="#80cc28"/>
+</svg>
diff --git a/main.qml b/main.qml
new file mode 100644
index 0000000..395a10f
--- /dev/null
+++ b/main.qml
@@ -0,0 +1,110 @@
+import QtQuick
+import QtQuick.Controls
+
+import org.qfield
+import org.qgis
+import Theme
+
+import "qrc:/qml" as QFieldItems
+
+Item {
+  id: plugin
+
+  property var mainWindow: iface.mainWindow()
+  property var positionSource: iface.findItemByObjectName('positionSource')
+  property var dashBoard: iface.findItemByObjectName('dashBoard')
+  property var overlayFeatureFormDrawer: iface.findItemByObjectName('overlayFeatureFormDrawer')
+
+  Component.onCompleted: {
+    iface.addItemToPluginsToolbar(snapButton)
+  }
+
+  Loader {
+    id: cameraLoader
+    active: false
+    sourceComponent: Component {
+      id: cameraComponent
+    
+      QFieldItems.QFieldCamera {
+        id: qfieldCamera
+        visible: false
+    
+        Component.onCompleted: {
+          open()
+        }
+    
+        onFinished: (path) => {
+          close()
+          snap(path)
+        }
+    
+        onCanceled: {
+          close()
+        }
+    
+        onClosed: {
+          cameraLoader.active = false
+        }
+      }
+    }
+  }
+
+  QfToolButton {
+    id: snapButton
+    bgcolor: Theme.darkGray
+    iconSource: Theme.getThemeVectorIcon('ic_camera_photo_black_24dp')
+    iconColor: Theme.mainColor
+    round: true
+
+    onClicked: {
+      dashBoard.ensureEditableLayerSelected()
+
+      if (!positionSource.active || !positionSource.positionInformation.latitudeValid || !positionSource.positionInformation.longitudeValid) {
+        mainWindow.displayToast(qsTr('Snap requires positioning to be active and returning a valid position'))
+        return
+      }
+      
+      if (dashBoard.activeLayer.geometryType() != Qgis.GeometryType.Point) {
+        mainWindow.displayToast(qsTr('Snap requires the active vector layer to be a point geometry'))
+        return
+      }
+      
+      let fieldNames = dashBoard.activeLayer.fields.names
+      if (fieldNames.indexOf('photo') == -1 && fieldNames.indexOf('picture') == -1) {
+        mainWindow.displayToast(qsTr('Snap requires the active vector layer to contain a field named \'photo\' or \'picture\''))
+        return
+      }
+
+      cameraLoader.active = true
+    }
+  }
+
+  function snap(path) {
+    let today = new Date()
+    let relativePath = 'DCIM/' + today.getFullYear()
+                               + (today.getMonth() +1 ).toString().padStart(2,0)
+                               + today.getDate().toString().padStart(2,0)
+                               + today.getHours().toString().padStart(2,0)
+                               + today.getMinutes().toString().padStart(2,0)
+                               + today.getSeconds().toString().padStart(2,0)
+                               + '.' + FileUtils.fileSuffix(path)
+    platformUtilities.renameFile(path, qgisProject.homePath + '/' + relativePath)
+    
+    let pos = positionSource.projectedPosition
+    let wkt = 'POINT(' + pos.x + ' ' + pos.y + ')'
+    
+    let geometry = GeometryUtils.createGeometryFromWkt(wkt)
+    let feature = FeatureUtils.createFeature(dashBoard.activeLayer, geometry)
+        
+    let fieldNames = feature.fields.names
+    if (fieldNames.indexOf('photo') > -1) {
+      feature.setAttribute(fieldNames.indexOf('photo'), relativePath)
+    } else if (fieldNames.indexOf('picture') > -1) {
+      feature.setAttribute(fieldNames.indexOf('picture'), relativePath)
+    }
+
+    overlayFeatureFormDrawer.featureModel.feature = feature
+    overlayFeatureFormDrawer.state = 'Add'
+    overlayFeatureFormDrawer.open()
+  }
+}
diff --git a/metadata.txt b/metadata.txt
new file mode 100644
index 0000000..a541402
--- /dev/null
+++ b/metadata.txt
@@ -0,0 +1,7 @@
+[general]
+name=Snap!
+description=Digitize points through snapping photos
+author=OPENGIS.ch
+icon=icon.svg
+version=1.0
+homepage=https://www.opengis.ch/