-
Notifications
You must be signed in to change notification settings - Fork 74
/
UCalculate.a
488 lines (340 loc) · 7.41 KB
/
UCalculate.a
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
;Photoshop version 1.0.1, file: UCalculate.a
; Computer History Museum, www.computerhistory.org
; This material is (C)Copyright 1990 Adobe Systems Inc.
; It may not be distributed to third parties.
; It is licensed for non-commercial use according to
; www.computerhistory.org/softwarelicense/photoshop/
INCLUDE 'Traps.a'
; **********************************************************************
SEG 'ADoCalculate'
DoCompositeBytes PROC EXPORT
; Calling sequence (Pascal conventions):
;
; PROCEDURE DoCompositeBytes (forePtr: Ptr;
; backPtr: Ptr;
; maskPtr: Ptr;
; count: INTEGER);
;
; Parameter Offsets
@forePtr EQU 18
@backPtr EQU 14
@maskPtr EQU 10
@count EQU 8
; Size of parameters
@params EQU 14
; Save registers
LINK A6,#0
MOVEM.L A2/D3,-(SP)
; Unload addresses
MOVE.L @forePtr(A6),A0
MOVE.L @backPtr(A6),A1
MOVE.L @maskPtr(A6),A2
; Loop through bytes
MOVE.W @count(A6),D0
SUB.W #1,D0
; Composite bytes
@1 CLR.W D1
MOVE.B (A2),D1
CLR.W D2
MOVE.B (A0)+,D2
MULU.W D1,D2
CLR.W D3
MOVE.B (A1)+,D3
NOT.B D1
MULU.W D1,D3
ADD.W D3,D2
; Divide by 255 a fast way
ADD.W #127,D2
MULU.W #257,D2
SWAP D2
MOVE.B D2,(A2)+
; Move to next pixel
DBF D0,@1
; Clean up and exit
MOVEM.L (SP)+,A2/D3
UNLK A6
MOVE.L (SP)+,A0
ADD.W #@params,SP
JMP (A0)
; **********************************************************************
SEG 'ADoCalculate'
DoBlendBytes PROC EXPORT
; Calling sequence (Pascal conventions):
;
; PROCEDURE DoBlendBytes (srcPtr: Ptr;
; dstPtr: Ptr;
; count: INTEGER;
; map1: TLookUpTable;
; map2: TLookUpTable);
;
; Parameter Offsets
@srcPtr EQU 22
@dstPtr EQU 18
@count EQU 16
@map1 EQU 12
@map2 EQU 8
; Size of parameters
@params EQU 18
; Save registers
LINK A6,#0
MOVEM.L A2-A3,-(SP)
; Unload addresses
MOVE.L @srcPtr(A6),A0
MOVE.L @dstPtr(A6),A1
MOVE.L @map1(A6),A2
MOVE.L @map2(A6),A3
; Loop through bytes
MOVE.W @count(A6),D0
SUB.W #1,D0
CLR.W D1
CLR.W D2
; Blend bytes
@1 MOVE.B (A1),D1
MOVE.B (A2,D1.W),D1
MOVE.B (A0)+,D2
MOVE.B (A3,D2.W),D2
ADD.B D2,D1
MOVE.B D1,(A1)+
; Move to next pixel
DBF D0,@1
; Clean up and exit
MOVEM.L (SP)+,A2-A3
UNLK A6
MOVE.L (SP)+,A0
ADD.W #@params,SP
JMP (A0)
; **********************************************************************
SEG 'ADoCalculate'
DoSubtractBytes PROC EXPORT
; Calling sequence (Pascal conventions):
;
; PROCEDURE DoSubtractBytes (srcPtr: Ptr;
; dstPtr: Ptr;
; count: INTEGER;
; scale: INTEGER;
; offset: INTEGER);
;
; Parameter Offsets
@srcPtr EQU 18
@dstPtr EQU 14
@count EQU 12
@scale EQU 10
@offset EQU 8
; Size of parameters
@params EQU 14
; Save registers
LINK A6,#0
MOVEM.L D3-D6,-(SP)
; Unload addresses
MOVE.L @srcPtr(A6),A0
MOVE.L @dstPtr(A6),A1
; Prepare registers
MOVE.W @count(A6),D0
SUB.W #1,D0
MOVE.W @scale(A6),D2
MOVE.W @offset(A6),D3
CLR.W D1
CLR.W D4
MOVE.W #255,D5
MOVE.W #1000,D6
; Loop through bytes
@1 MOVE.B (A1),D1
MOVE.B (A0)+,D4
SUB.W D4,D1
CMP.W D2,D6
BEQ.S @2
MULS.W D6,D1
DIVS.W D2,D1
@2 ADD.W D3,D1
BPL.S @3
CLR.W D1
@3 CMP.W D5,D1
BLE.S @4
MOVE.W D5,D1
@4 MOVE.B D1,(A1)+
DBF D0,@1
; Clean up and exit
MOVEM.L (SP)+,D3-D6
UNLK A6
MOVE.L (SP)+,A0
ADD.W #@params,SP
JMP (A0)
; **********************************************************************
SEG 'ADoCalculate'
DoAddBytes PROC EXPORT
; Calling sequence (Pascal conventions):
;
; PROCEDURE DoAddBytes (srcPtr: Ptr;
; dstPtr: Ptr;
; count: INTEGER;
; scale: INTEGER;
; offset: INTEGER);
;
; Parameter Offsets
@srcPtr EQU 18
@dstPtr EQU 14
@count EQU 12
@scale EQU 10
@offset EQU 8
; Size of parameters
@params EQU 14
; Save registers
LINK A6,#0
MOVEM.L D3-D6,-(SP)
; Unload addresses
MOVE.L @srcPtr(A6),A0
MOVE.L @dstPtr(A6),A1
; Prepare registers
MOVE.W @count(A6),D0
SUB.W #1,D0
MOVE.W @scale(A6),D2
MOVE.W @offset(A6),D3
CLR.W D1
CLR.W D4
MOVE.W #255,D5
MOVE.W #1000,D6
; Loop through bytes
@1 MOVE.B (A1),D1
MOVE.B (A0)+,D4
ADD.W D4,D1
CMP.W D2,D6
BEQ.S @2
MULS.W D6,D1
DIVS.W D2,D1
@2 ADD.W D3,D1
BPL.S @3
CLR.W D1
@3 CMP.W D5,D1
BLE.S @4
MOVE.W D5,D1
@4 MOVE.B D1,(A1)+
DBF D0,@1
; Clean up and exit
MOVEM.L (SP)+,D3-D6
UNLK A6
MOVE.L (SP)+,A0
ADD.W #@params,SP
JMP (A0)
; **********************************************************************
SEG 'ADoCalculate'
DoMultiplyBytes PROC EXPORT
; Calling sequence (Pascal conventions):
;
; PROCEDURE DoMultiplyBytes (srcPtr: Ptr;
; dstPtr: Ptr;
; count: INTEGER);
;
; Parameter Offsets
@srcPtr EQU 14
@dstPtr EQU 10
@count EQU 8
; Size of parameters
@params EQU 10
; Save registers
LINK A6,#0
; Unload addresses
MOVE.L @srcPtr(A6),A0
MOVE.L @dstPtr(A6),A1
; Loop through bytes
MOVE.W @count(A6),D0
SUB.W #1,D0
; Multiply bytes
@1 CLR.W D1
MOVE.B (A1),D1
CLR.W D2
MOVE.B (A0)+,D2
MULU.W D2,D1
; Divide by 255 a fast way
ADD.W #127,D1
MULU.W #257,D1
SWAP D1
; Move to next pixel
MOVE.B D1,(A1)+
DBF D0,@1
; Clean up and exit
UNLK A6
MOVE.L (SP)+,A0
ADD.W #@params,SP
JMP (A0)
; **********************************************************************
SEG 'ADoCalculate'
DoScreenBytes PROC EXPORT
; Calling sequence (Pascal conventions):
;
; PROCEDURE DoScreenBytes (srcPtr: Ptr;
; dstPtr: Ptr;
; count: INTEGER);
;
; Parameter Offsets
@srcPtr EQU 14
@dstPtr EQU 10
@count EQU 8
; Size of parameters
@params EQU 10
; Save registers
LINK A6,#0
; Unload addresses
MOVE.L @srcPtr(A6),A0
MOVE.L @dstPtr(A6),A1
; Loop through bytes
MOVE.W @count(A6),D0
SUB.W #1,D0
; Screen bytes
@1 CLR.W D1
MOVE.B (A1),D1
NOT.B D1
CLR.W D2
MOVE.B (A0)+,D2
NOT.B D2
MULU.W D2,D1
; Divide by 255 a fast way
ADD.W #127,D1
MULU.W #257,D1
SWAP D1
; Move to next pixel
NOT.B D1
MOVE.B D1,(A1)+
DBF D0,@1
; Clean up and exit
UNLK A6
MOVE.L (SP)+,A0
ADD.W #@params,SP
JMP (A0)
; **********************************************************************
SEG 'ADoCalculate'
DoDiffBytes PROC EXPORT
; Calling sequence (Pascal conventions):
;
; PROCEDURE DoDiffBytes (srcPtr: Ptr;
; dstPtr: Ptr;
; count: INTEGER);
;
; Parameter Offsets
@srcPtr EQU 14
@dstPtr EQU 10
@count EQU 8
; Size of parameters
@params EQU 10
; Save registers
LINK A6,#0
; Unload addresses
MOVE.L @srcPtr(A6),A0
MOVE.L @dstPtr(A6),A1
; Loop through bytes
MOVE.W @count(A6),D0
SUB.W #1,D0
; Difference bytes
@1 MOVE.B (A1),D1
SUB.B (A0)+,D1
BCC.S @2
NOT.B D1
@2 MOVE.B D1,(A1)+
; Move to next pixel
DBF D0,@1
; Clean up and exit
UNLK A6
MOVE.L (SP)+,A0
ADD.W #@params,SP
JMP (A0)
; **********************************************************************
END